Подскажите способ установки QBasic на WIN 7

MP_Graphics3D(640,480,0,3) ; Erstelle ein WindowsFenster mit 3D Funktion #Window = 0
SetWindowTitle(0, "Rotiere Textur auf Wьrfel") ; Setzt einen Fensternamen
 
camera=MP_CreateCamera() ; Kamera erstellen
 
light=MP_CreateLight(2) ; Es werde Licht
 
Mesh=MP_CreateCube() ; Und jetzt eine Wьrfel
Mesh2=MP_CreateCube() ; Und jetzt eine Wьrfel
 
MP_PositionEntity(Mesh,-1,0,4) ; Position des Wьrfels
MP_PositionEntity(Mesh2,1,0,4) ; Position des Wьrfels
 
 
; Hier einfach mal die Textur remarken um den Unterschied zum Textures und Untextured Lightsourcing zu sehen
Texture =  MP_LoadTexture("Geebee2.bmp") : MP_EntitySetTexture(Mesh, Texture) 
   MP_MaterialDiffuseColor(Texture,255,128,128,128)
   MP_MaterialAmbientColor(Texture, 255, 155 , 255, 255) ; 
   MP_MaterialEmissiveColor(Texture,155,15,25,25) ; 
   MP_MaterialSpecularColor(Texture, 255, 255 ,255, 255,20) ;
   
MP_AmbientSetLight(RGB(55,34,167)) 
 
While Not MP_KeyDown(#PB_Key_Escape) And Not WindowEvent() = #PB_Event_CloseWindow; Esc abfrage oder Windows Schliessen
 
    Angle.f + 0.5
    ;MP_RotateTexture(Texture , Angle)
 
    MP_TurnEntity(Mesh,0.3,0.4,0.5) ; dreh den Wьrfel
    MP_TurnEntity(Mesh2,0.3,0.4,0.5) ; dreh den Wьrfel
    
    MP_RenderWorld() ; Erstelle die Welt
    MP_Flip() ; Stelle Sie dar
 
Wend

; Автор: kvitaliy 2011, PBv5.11
; Были в наличии исходники на С++ и Делфи, я портировал на PureBasic
 
If InitSprite() = 0
    MessageRequester("Error", "Can't open screen & sprite enviroment!", 0)
    End
  EndIf
  
  Global WinW=700
  Global WinH=450
  
  If OpenWindow(0, 0, 0, WinW, WinH, "3D Вращение точек", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    
    If OpenWindowedScreen(WindowID(0), 0, 0, WinW, WinH, 0, 0, 0)
     
    Else
      MessageRequester("Error", "Can't open windowed screen!", 0)
      End
    EndIf
  EndIf
  
  #Alpha       = 0.01;   //  Угол поворота точек
  #rPoint      = 3;      //  Радиус точек
  #PointsCount = 1000;   //  Кол-во генерируемых точек
  
  ;   // Структура описывающая точку в пространстве
 
 Structure TPoint3D 
    X.d
    Y.d 
    Z.d 
  EndStructure;
  
   Global Dim Points3D.TPoint3D (#PointsCount)  ; // Массив трехмерных точек
 
 
;   // Процедура рисования точек
   Procedure DrawPoints();
   tX.d
   tY.d
   tZ.d
 
   Sum.d
   
   CosA.d = Cos(#Alpha)
    SinA.d = Sin(#Alpha)
 
    D.i = (WinW+WinH) / 2   ;   // Параметр влияющий на коэффициент угла обзора проекции
    Ofs.i =D;   // Расстояние от центра координат
 
    oX=WinW/2
    oY=WinH/2
 
    Direct.b= #True; #False      ;  // Направление вращения точек
 
   
    For I = 1 To #PointsCount 
      
 
       If Direct
 
; // Крутим точки по оси YZ
                  tY = Points3D(I)\Y * CosA - Points3D(I)\Z * SinA;
                  tZ = Points3D(I)\Y * SinA + Points3D(I)\Z * CosA;
                  Points3D(I)\Y = tY;
                  Points3D(I)\Z = tZ;
 
      Else
  
;    Крутим точки по оси XZ
                  tX = Points3D(I)\X * CosA - Points3D(I)\Z * SinA;
                  tZ = Points3D(I)\X * SinA + Points3D(I)\Z * CosA;
                  Points3D(I)\X = tX;
                  Points3D(I)\Z = tZ;
 
      EndIf
 
; 
;       {------ Вот они! Волшебные формулы превращения 3D в 2D! ------}
; 
                SUM = D / (POINTS3D(I)\Z + Ofs);
                X = oX + Round(POINTS3D(I)\X * SUM,0);
                Y = oY + Round(POINTS3D(I)\Y * SUM,0);
; 
;       {-------------------------------------------------------------}
 
;       // Точки будем рисовать красным цветом
; 
; 
           Ellipse(X,Y, #rPoint,#rPoint,RGB(255,0,0));
 
     Next
 
 
   EndProcedure;
   
   
   ; // Координаты центра экрана
 
    oX=WinW/2
    oY=WinH/2
; 
;   // Генерация трехмерных точек
; 
   For I = 1 To #PointsCount 
     Points3D(I)\X = Random(WinW) - oX;
     Points3D(I)\Y = Random(WinH) - oY;
     Points3D(I)\Z = Random(WinW) - oX ;
   Next
 
 
  Repeat
    
    Repeat
      Event = WindowEvent()
       Select Event 
          Case #PB_Event_CloseWindow
          End 
      EndSelect
    Until Event = 0
  
    FlipBuffers() 
    ;ClearScreen(RGB(0, 0, 0))
    StartDrawing(ScreenOutput())
    
    Box(0, 0, WinW,WinH, RGB(0,0,0))
    DrawPoints()
          
    StopDrawing()
    
    ;Delay(1)
  ForEver

; Автор:   MadPsychoCell [ Вт июл 17, 2007 1:41 pm ]
; КодеАрхив от MadPsychoCell
;
;               Z
;               ^
;                |
;                |
;                |
;                |
;                |        
;X <--------*Y
;
#PIDiv180 = 0.017453292519943295; Pi / 180
 
Structure TXYZ;структура 3D координат
  X.d
  Y.d
  Z.d
EndStructure
 
Structure TXY
  X.d
  Y.d
EndStructure
 
;преобразование 3D координат объекта в 2D в  перспективе
Procedure Perspective(X.d,Y.d,Z.d,Height.d,Basis.d,*XP,*YP)
  Protected Den.d,XP.d,YP.d
  Den = Y + Basis
  If Abs(Den)<1e-100 : Den=1e-100 : EndIf
  XP=Basis*X/Den
  YP=(Basis*Z+Height*Y)/Den
  PokeD(*XP,XP) : PokeD(*YP,YP)
EndProcedure
 
;вращение точки в 3D пространстве вокруг точки
Procedure Rotate(Rx.d,Ry.d,Rz.d,x.d,y.d,z.d,*Nx,*Ny,*Nz)
  Protected TempX.d,TempY.d,TempZ.d
  Protected SinX.d,SinY.d,SinZ.d
  Protected CosX.d,CosY.d,CosZ.d
  Protected XRadAng.d,YRadAng.d,ZRadAng.d
  Protected Nx.d,Ny.d,Nz.d
  
  XRadAng = Rx * #PIDiv180
  YRadAng = Ry * #PIDiv180
  ZRadAng = Rz * #PIDiv180
 
  SinX = Sin(XRadAng)
  SinY = Sin(YRadAng)
  SinZ = Sin(ZRadAng)
 
  CosX = Cos(XRadAng)
  CosY = Cos(YRadAng)
  CosZ = Cos(ZRadAng)
 
  Tempy = y * CosY - z * SinY
  Tempz = y * SinY + z * CosY
  Tempx = x * CosX - Tempz * SinX
 
  Nz = x * SinX + Tempz * CosX
  Nx = Tempx * CosZ - TempY * SinZ
  Ny = Tempx * SinZ + TempY * CosZ
    
  PokeD(*Nx,Nx) : PokeD(*Ny,Ny) : PokeD(*Nz,Nz)
EndProcedure
 
;демонстрация процедур вращения куба в 3D пространстве вокруг точки и отображение 3D объекта
;на 2D плоскость
;
                 
 
Dim Cube3D.TXYZ(9);8 точек c 3D координатами куба
Dim Cube2D.TXY (9);8 точек c 2D координатами куба
Movement.TXYZ     ;точка вокруг которой производить вращение
 
Cube3D(1)\X = 400 : Cube3D(1)\Y = 200 : Cube3D(1)\Z = 200
Cube3D(2)\X = 400 : Cube3D(2)\Y = 200 : Cube3D(2)\Z = 400
Cube3D(3)\X = 200 : Cube3D(3)\Y = 200 : Cube3D(3)\Z = 400
Cube3D(4)\X = 200 : Cube3D(4)\Y = 200 : Cube3D(4)\Z = 200
Cube3D(5)\X = 400 : Cube3D(5)\Y = 400 : Cube3D(5)\Z = 200
Cube3D(6)\X = 400 : Cube3D(6)\Y = 400 : Cube3D(6)\Z = 400
Cube3D(7)\X = 200 : Cube3D(7)\Y = 400 : Cube3D(7)\Z = 400
Cube3D(8)\X = 200 : Cube3D(8)\Y = 400 : Cube3D(8)\Z = 200
  
 
Movement\X = Cube3D(4)\X / 1000
Movement\Y = Cube3D(4)\Y / 1000
Movement\Z = Cube3D(4)\Z / 1000
  
 
OpenWindow(0,0,0,800,600,"Rotate 3D",#PB_Window_ScreenCentered|#PB_Window_SystemMenu)
  
While WindowEvent() <> #WM_CLOSE
  
  For i = 1 To 8
    Rotate(Movement\X ,Movement\Y,Movement\Z,Cube3D(i)\X,Cube3D(i)\Y,Cube3D(i)\Z,@Cube3D(i)\X,@Cube3D(i)\Y,@Cube3D(i)\Z)
    ;Cube3D(i)\X + 10
    ;Cube3D(i)\Y ;+ 10
    ;Cube3D(i)\Z - 15
    Perspective(Cube3D(i)\X,Cube3D(i)\Y,Cube3D(i)\Z,400,400,@Cube2D(i)\X,@Cube2D(i)\Y)
  Next
  
  Movement\X = Cube3D(4)\X / 1000
  Movement\Y = Cube3D(4)\Y / 1000
  Movement\Z = Cube3D(4)\Z / 1000
  
  
  StartDrawing(WindowOutput(0))
    Box(0,0,800,600,$000000)
    
    FrontColor($00FF00)
    
    LineXY(Cube2D(8)\X,Cube2D(8)\Y,Cube2D(7)\X,Cube2D(7)\Y)
    LineXY(Cube2D(7)\X,Cube2D(7)\Y,Cube2D(6)\X,Cube2D(6)\Y)
    LineXY(Cube2D(6)\X,Cube2D(6)\Y,Cube2D(5)\X,Cube2D(5)\Y)
    LineXY(Cube2D(5)\X,Cube2D(5)\Y,Cube2D(8)\X,Cube2D(8)\Y)
    
    LineXY(Cube2D(8)\X,Cube2D(8)\Y,Cube2D(4)\X,Cube2D(4)\Y)
    LineXY(Cube2D(7)\X,Cube2D(7)\Y,Cube2D(3)\X,Cube2D(3)\Y)
    LineXY(Cube2D(6)\X,Cube2D(6)\Y,Cube2D(2)\X,Cube2D(2)\Y)
    LineXY(Cube2D(5)\X,Cube2D(5)\Y,Cube2D(1)\X,Cube2D(1)\Y)
    
    LineXY(Cube2D(1)\X,Cube2D(1)\Y,Cube2D(2)\X,Cube2D(2)\Y)
    LineXY(Cube2D(2)\X,Cube2D(2)\Y,Cube2D(3)\X,Cube2D(3)\Y)
    LineXY(Cube2D(3)\X,Cube2D(3)\Y,Cube2D(4)\X,Cube2D(4)\Y)
    LineXY(Cube2D(4)\X,Cube2D(4)\Y,Cube2D(1)\X,Cube2D(1)\Y)
  StopDrawing()
  
  Delay(10)
Wend
 
CloseWindow(0)
 
End