Обеспечить перестановку слов в списке в обратном порядке

program Project1;
 
type
  (*Типы для описания списка.*)
 
  (*Тип данных - определяет данные, которые будет содержать каждый элемент списка.*)
  TData = String;
  (*Тип, описывающий элемент списка.*)
  TPElem = ^TElem;
  TElem = record
    Data : TData;
    PNext : TPElem;
    PPrev : TPElem;
  end;
  (*Тип, описывающий список.*)
  TList = record
    PFirst : TPElem;
    PLast : TPElem;
  end;
 
(*Процедуры для работы со списком.*)
 
(*Удаление всего списка из памяти и инициализация.*)
procedure ListFree(var aList : TList);
var
  PNext, PDel : TPElem;
begin
  if aList.PFirst = nil then Exit;
 
  PNext := aList.PFirst;
  while PNext <> nil do begin
    PDel := PNext;
    PNext := PNext^.PNext;
    Dispose(PDel);
  end;
 
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
(*Добавление элемента в конец списка.*)
procedure AddL(var aList : TList; const aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  aPElem^.PNext := nil;
  aPElem^.PPrev := nil;
  if aList.PFirst = nil then begin
    aList.PFirst := aPElem;
    aList.PLast := aPElem;
  end else begin
    aList.PLast^.PNext := aPElem;
    aPElem^.PPrev := aList.PLast;
    aList.PLast := aPElem;
  end;
end;
 
const
  Fn1 = 'file1.txt';
var
  F1 : Text;
  List : TList;
  PElem : TPElem;
  S : String;
  i : Integer;
begin
  Assign(F1, Fn1);
  Rewrite(F1);
  i := 0;
  repeat
    Writeln('Введите слово. Прервать цикл ввода - пустая строка.');
    Readln(S);
    if S <> '' then begin
      if i = 0 then Inc(i)
      else Writeln(F1);
      Write(F1, S);
    end;
  until S = '';
  Flush(F1);
 
  (*Читаем из файла слова и помещаем их в список.
  Одновременно выполняем распечатку.*)
  Writeln('Исходный список слов:');
  List.PFirst := nil;
  List.PLast := nil;
  Reset(F1);
  i := 0;
  while not Eof(F1) do begin
    New(PElem);
    Readln(F1, PElem^.Data);
    AddL(List, PElem);
    if i > 0 then Write(', ');
    Write(PElem^.Data);
    Inc(i);
  end;
  Writeln;
 
  (*Закрываем файл.*)
  Close(F1);
 
  (*Показываем список слов в обратном порядке.*)
  Writeln('Список слов в обратном порядке:');
  PElem := List.PLast;
  i := 0;
  while PElem <> nil do begin
    if i > 0 then Write(', ');
    Write(PElem^.Data);
    PElem := PElem.PPrev;
    Inc(i);
  end;
  Writeln;
 
  (*Удаляем список из памяти.*)
  ListFree(List);
 
  Readln;
end.

Flush(F1);