На плоскости имееться круг и n точек

uses crt;
const nmax=100;
type point=record
           x,y:real;
           end;
     mas=array[1..nmax] of point;
var c:point;{центр круга}
    t,t1:mas;{массивы точек}
    r,v:real;{радиус круга}
    n,m:byte;{размеры массивов}
    i,j,k:byte;{счетчики циклов}
    mn,imn,jmn,lv,pr:byte;{мин. разн., номера точек с мин. раз.
                           кол. слева и справа для минимальной разности}
    l1,p1:byte;{кол. слева и справа для всех прямых}
begin
clrscr;
{создание массива точек}
repeat
write('Количество точек до ',nmax,' n=');
readln(n);
until n in [1..nmax];
for i:=1 to n do
 begin
  t[i].x:=-9+random(19);
  t[i].y:=-9+random(19);
 end;
writeln('Исходный массив точек:');
for i:=1 to n do
write('(',t[i].x:5:2,';',t[i].y:5:2,')   ');
writeln;
writeln('Введите координаты центра круга и его радиус:');
readln(c.x,c.y,r);
{выбор точек, которые попадают в круг}
m:=0;
for i:=1 to n do
if sqr(t[i].x-c.x)+sqr(t[i].y-c.y)<=r*r then
 begin
  m:=m+1;
  t1[m]:=t[i];
 end;
if m=0 then
 begin
  write('Точек в круге нет, работа программы завершена');
  readln;
  exit;
 end;
writeln('Массив точек в круге:');
for i:=1 to m do
write('(',t1[i].x:5:2,';',t1[i].y:5:2,')   ');
writeln;
mn:=m;
imn:=1;
jmn:=2;
lv:=0;
pr:=0;
for i:=1 to n-1 do
for j:=i+1 to n do
 begin
  l1:=0;p1:=0;
  for k:=1 to m do
   begin
    {вектороное произведение [t[i],t[j]*[t[i],c]}
    v:=(t[j].x-t[i].x)*(t1[k].y-t[i].y)-(t[j].y-t[i].y)*(t1[k].x-t[i].x);
    if v>0 then inc(l1){если +, слева}
    else if v<0 then inc(p1);{если -, справа}
   end;
  if abs(l1-p1)<mn then
   begin
    mn:=abs(l1-p1);
    imn:=i;
    jmn:=j;
    lv:=l1;
    pr:=p1;
   end;
 end;
write('Прямая проходит через точки ');
write(imn,'(',t[imn].x:0:2,';',t[imn].y:0:2,') и ');
writeln(jmn,'(',t[jmn].x:0:2,';',t[jmn].y:0:2,')');
write('Точек слева=',lv,' справа=',pr);
readln
end.

uses crt,graph;
const nmax=100;
type point=record
           x,y:real;
           end;
     mas=array[1..nmax] of point;
var c:point;{центр круга}
    t,t1:mas;{массивы точек}
    r,v:real;{радиус круга}
    n,m:byte;{размеры массивов}
    i,j,k:byte;{счетчики циклов}
    mn,imn,jmn,lv,pr:byte;{мин. разн., номера точек с мин. раз.
                           кол. слева и справа для минимальной разности}
    l1,p1:integer;{кол. слева и справа для каждой прямой}
    xc,yc:integer;{начало координат и экранные координаты всех точек}
    min,max,ms:real;{минимум, максимум координат и масштаб для вывода на экран}
    x1,y1,x2,y2:integer;{экранные координаты точек}
    x,y,b,k1:real;{точки прямой и ее коэффициенты}
    s:string;
begin
clrscr;
{создание массива точек}
repeat
write('Количество точек до ',nmax,' n=');
readln(n);
until n in [1..nmax];
for i:=1 to n do
 begin
  t[i].x:=-9+random(19);
  t[i].y:=-9+random(19);
 end;
writeln('Исходный массив точек:');
for i:=1 to n do
write('(',t[i].x:5:2,';',t[i].y:5:2,')   ');
writeln;
writeln('Введите координаты центра круга и его радиус:');
readln(c.x,c.y,r);
{выбор точек, которые попадают в круг}
m:=0;
for i:=1 to n do
if sqr(t[i].x-c.x)+sqr(t[i].y-c.y)<=r*r then
 begin
  m:=m+1;
  t1[m]:=t[i];
 end;
if m=0 then
 begin
  write('Точек в круге нет, работа программы завершена');
  readln;
  exit;
 end;
writeln('Массив точек в круге:');
for i:=1 to m do
write('(',t1[i].x:5:2,';',t1[i].y:5:2,')   ');
writeln;
mn:=m;
imn:=1;
jmn:=2;
lv:=0;
pr:=0;
for i:=1 to n-1 do
for j:=i+1 to n do
 begin
  l1:=0;p1:=0;
  for k:=1 to m do
   begin
    v:=(t[j].x-t[i].x)*(t1[k].y-t[i].y)-(t[j].y-t[i].y)*(t1[k].x-t[i].x);
    if v>0 then inc(l1)
    else if v<0 then inc(p1);
   end;
  if abs(l1-p1)<mn then
   begin
    mn:=abs(l1-p1);
    imn:=i;
    jmn:=j;
    lv:=l1;
    pr:=p1;
   end;
 end;
write('Прямая проходит через точки ');
write(imn,'(',t[imn].x:0:2,';',t[imn].y:0:2,') и ');
writeln(jmn,'(',t[jmn].x:0:2,';',t[jmn].y:0:2,')');
write('Точек слева=',lv,' справа=',pr);
readln;
xc:=0;
initgraph(xc,yc,'');
xc:=getmaxX div 2;
yc:=getmaxY div 2;
if c.x<c.y then min:=c.x-r else min:=c.y-r;
if c.x>c.y then max:=c.x+r else max:=c.y+r;
for i:=1 to n do
 begin
  if t[i].x<min then min:=t[i].x;
  if t[i].y<min then min:=t[i].y;
  if t[i].x>max then max:=t[i].x;
  if t[i].y>max then max:=t[i].y;
 end;
if max>abs(min) then ms:=(yc-40)/max
else ms:=(yc-40)/abs(min);
{окружность}
setcolor(9);
circle(xc+round(c.x*ms),yc-round(c.y*ms),round(r*ms));
{построение прямой}
x1:=xc+round(t[imn].x*ms);
y1:=yc-round(t[imn].y*ms);
x2:=xc+round(t[jmn].x*ms);
y2:=yc-round(t[jmn].y*ms);
{вертикальная}
if x1=x2 then
 begin
  x:=x1;
  y:=0;
  while y<getmaxY do
   begin
    putpixel(round(x),round(y),11);
    y:=y+0.1;
   end
 end
{горизонтальная}
else if y1=y2 then
 begin
  x:=0;
  y:=y1;
  while x<getmaxX do
   begin
    putpixel(round(x),round(y),11);
    x:=x+0.1;
   end
 end
{остальные}
else
 begin
  x:=0;
  k1:=(y1-y2)/(x2-x1);
  b:=y2+x2*k1;
  while x<=getmaxX do
   begin
    y:=-round(k1*x-b);
    if(y>0)and(y<getmaxY) then putpixel(round(x),round(y),11);
    x:=x+0.1;
   end;
 end;
{все точки}
for i:=1 to n do
 begin
  x1:=xc+round(t[i].x*ms);
  y1:=yc-round(t[i].y*ms);
  str(i,s);
  setcolor(12);
  setlinestyle(0,0,3);
  circle(x1,y1,1);
  setcolor(15);
  outtextXY(x1+5,y1,s);
 end;
{точки в круге}
for k:=1 to m do
 begin
  x1:=xc+round(t1[k].x*ms);
  y1:=yc-round(t1[k].y*ms);
  v:=(t[jmn].x-t[imn].x)*(t1[k].y-t[imn].y)-(t[jmn].y-t[imn].y)*(t1[k].x-t[imn].x);
  if v>0 then setcolor(10)
  else if v<0 then setcolor(14);
  setlinestyle(0,0,3);
  if v<>0 then circle(x1,y1,1);
 end;
{точки на линии}
setcolor(11);
x1:=xc+round(t[imn].x*ms);
y1:=yc-round(t[imn].y*ms);
circle(x1,y1,2);
x1:=xc+round(t[jmn].x*ms);
y1:=yc-round(t[jmn].y*ms);
circle(x1,y1,2);
readln
end.