Дан текст из строчных латинских буков, за которыми следует точка. напечатать все буквы, входящие в текст ровно три раза.

program Project1;
 
const
  //Множество букв.
  D = [
    'А'..'П', 'Р'..'Я', 'Ё',
    'а'..'п', 'р'..'я', 'ё',
    'A'..'Z', 'a'..'z'
  ];
var
  S : String;
  Ch : Char;
  i, Len : Integer;
  (*Это тоже самое что и: ArrStat : array[#0..#255] of Integer;*)
  ArrStat : array[Char] of Integer;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    (*Обнуляем элементы массива статистики.*)
    for Ch := #0 to #255 do ArrStat[Ch] := 0;
 
    (*Собираем статистику по всем символам до первой точки, либо до
    конца строки, если в тексте нет точек.*)
    Len := Length(S);
    i := 1;
    while (i <= Len) and (S[i] <> '.') do begin
      Inc(ArrStat[S[i]]);
      Inc(i);
    end;
 
    (*Показываем результат.*)
    Writeln(
      'Рассматривается текст, который идёт до первой точки'
      + ' либо до конца строки, если точки нет.'
    );
    Writeln('Буквы, которые встречаются только 3 раза:');
    i := 0;
    for Ch := #0 to #255 do begin
      if (Ch in D) and (ArrStat[Ch] = 3) then begin;
        Inc(i);
        if i > 1 then Write(', ');
        Write(Ch);
      end;
    end;
    Writeln;
    if i = 0 then Writeln('Нет ни одной буквы, которая бы удовлетворяла условию.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.