Форум программистов, компьютерный форум, киберфорум
Наши страницы
Turbo Pascal
Войти
Регистрация
Восстановить пароль
 
Рейтинг 4.60/5: Рейтинг темы: голосов - 5, средняя оценка - 4.60
bodybuilding
0 / 0 / 0
Регистрация: 15.01.2013
Сообщений: 22
1

Удалить из списка L элементы, расположенные непосредственно за элементами со значением Е

27.01.2013, 14:25. Просмотров 917. Ответов 1
Метки нет (Все метки)

Составить программу,которая удаляет из списка L за каждым вхождением элемента Е,если таковы имеются.
 Комментарий модератора 
Правила форума п. 5.5: Запрещено размещать тему в нескольких разделах одновременно (кросспостинг), а также дублировать тему в одном разделе.
0
Лучшие ответы (1)
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
27.01.2013, 14:25
Ответы с готовыми решениями:

Удалить элементы расположенные между максимальным и минимальным элементами массива Х. Элементы массива Х вычисляются по формуле Xi=((-1)^i)*((i^2)-3*i), где i=1,2,...,10.
Удалить элементы расположенные между максимальным и минимальным элементами...

Удалить из одномерного массива все элементы расположенные между максимальным и минимальным элементами массива
Удалить из одномерного массива все элементы расположенные между максимальным и...

Переставить в обратном порядке элементы массива, расположенные между заданными элементами, включая эти элементы
Дан массив А размера N и целые числа K и L (K≤L≤N). Переставить в обратном...

Переставить в обратном порядке элементы массива, расположенные между заданными элементами, не включая эти элементы
Дан массив А размера N и целые числа K и L (K≤L≤N). Переставить в обратном...

Однонаправленные списки.Написать подпрограмму,которая добавляет в конец списка А1 элементы списка А2 со значением больше за 3
Однонаправленные списки. Дано: 2-а списка .А1-первое поле-отрицательное число...

1
Mawrat
12833 / 5741 / 1700
Регистрация: 19.09.2009
Сообщений: 8,807
28.01.2013, 17:09 2
Лучший ответ Сообщение было отмечено bodybuilding как решение

Решение

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
program Project1;
 
type
  {Тип основных данных списка.}
  TData = Integer;
  {Тип указателя на элемент списка.}
  TPElem = ^TElem;
  {Тип элемента списка.}
  TElem = record
    Data : TData; {Основные данные элемента.}
    PNext : TPElem; {Указатель на следующий элемент списка.}
  end;
  {Тип, описывающий однонаправленный список.}
  TDList = record
    PFirst, PLast : TPElem; {Указатели на первый и последний элементы списка.}
  end;
 
{Инициализация списка. Внимание! Эту процедуру можно выполнять только
в отношении пустого списка. Иначе - будут утечки памяти.}
procedure Init(var aList : TDList);
begin
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
{Добавление элемента в конец однонаправленного списка.}
procedure Add(var aList : TDList; const aData : TData);
var
  PElem : TPElem;
begin
  New(PElem);
  PElem^.Data := aData;
  PElem^.PNext := nil;
  if aList.PFirst = nil then
    aList.PFirst := PElem
  else
    aList.PLast^.PNext := PElem;
  aList.PLast := PElem;
end;
 
{Освобождение памяти, занятой под список и инициализация списка.}
procedure Free(var aList : TDList);
var
  PNext, PDel : TPElem;
begin
  PNext := aList.PFirst;
  while PNext <> nil do begin
    PDel := PNext;
    PNext := PNext^.PNext;
    Dispose(PDel);
  end;
  Init(aList);
end;
 
{Распечатка однонаправленного списка.}
procedure WritelnList(const aList : TDList);
var
  PElem : TPElem;
begin
  if aList.PFirst = nil then begin
    Writeln('Список пуст.');
    Exit;
  end;
 
  PElem := aList.PFirst;
  while PElem <> nil do begin
    if PElem <> aList.PFirst then Write(', ');
    Write(PElem^.Data);
    PElem := PElem^.PNext;
  end;
  Writeln;
end;
 
var
  L : TDList;
  PElem, PPrev, PDel : TPElem;
  Data, E : TData;
  i, Code : Integer;
  S : String;
begin
  repeat
    {Создание списока.}
    Writeln('Создание списка.');
    Writeln('Прекратить ввод - пустая строка + Enter.');
    i := 0;
    repeat
      Write('Элемент ', i + 1, ': ');
      Readln(S);
      if S <> '' then begin
        Val(S, Data, Code);
        if Code = 0 then begin
          Inc(i);
          Add(L, Data);
        end else
          Writeln('Неверный ввод. Повторите.');
      end;
    until S = '';
    Writeln('Составлен список:');
    WritelnList(L);
 
    repeat
      Write('Задайте значение искомого элемента (E): ');
      Readln(S);
      Val(S, E, Code);
      if Code <> 0 then
        Writeln('Неверный ввод. Повторите.');
    until Code = 0;
 
    {Удаляем из списка каждый элемент, стоящий непосредственно за элементом
    со значением E.}
    i := 0;
    if L.PFirst <> nil then begin
      PPrev := L.PFirst; {Предыдущий элемент.}
      PElem := PPrev^.PNext; {Текущий элемент.}
      while PElem <> nil do
        if PPrev^.Data = E then begin
          {Указатель на удаляемый элемент.}
          PDel := PElem;
          {Исключаем текущий элемент из списка.}
          PPrev^.PNext := PElem^.PNext;
          {Переход к следующей паре элементов.}
          if PElem = L.PLast then begin {Если удаляется последний элемент в списке.}
            L.PLast := PPrev;
            PElem := nil;
          end else begin {Если удаляется непоследний элемент в списке.}
            PPrev := PPrev^.PNext;
            PElem := PPrev^.PNext;
          end;
          Dispose(PDel); {Освобождение памяти, занятой под элемент.}
          Inc(i);
        end else begin
          {Переход к следующему элементу.}
          PPrev := PElem;
          PElem := PElem^.PNext;
        end;
    end;
 
    Writeln('Удалено элементов: ', i);
    Writeln('Список после обработки:');
    WritelnList(L);
 
    {Освобождение памяти, занятой под список.}
    Free(L);
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.
1
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
28.01.2013, 17:09

Вывести элементы массива, расположенные между минимальным и максимальным элементами
№1.вычислить y=cos(x)+cos(0.2x)+cos(0.4x)+.+cos(10x) var x,y,k:real; ...

Переставить в обратном порядке: элементы, расположенные между k-м и s-м элементами массива
Дан одномерный массив из 15 элементов. Переставить в обратном порядке:...

В массиве найти элементы, расположенные между минимальным и максимальным элементами
я нашел индексы элементов между min и max элементами, а вот сами элементы...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
2
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.
Рейтинг@Mail.ru