Найти определитель NxN - ой матрицы, затем это число умножить на каждый элемент матрицы, затем транспонировать матрицу

uses crt;
const nmax=6; { макс. размерность матрицы }
type matr=array[1..nmax,1..nmax] of integer;
procedure PrintMatr(m:matr;n:integer);
{ процедура вывода матрицы на экран }
var i,j:integer;
begin
for i:=1 to n do
 begin
  for j:=1 to n do
  write(m[i,j]:7);
  writeln;
  end;
end;
procedure GetMatr(a:matr; var b:matr; m,i,j:integer);
{ Вычеркивание из матрицы строки и столбца }
var ki,kj,di,dj:integer;
begin
di:=0;
for ki:=1 to m-1 do
 begin
  if (ki=i) then di:=1;
  dj:=0;
  for kj:=1 to m-1 do
   begin
    if (kj=j) then dj:=1;
    b[ki,kj]:=a[ki+di,kj+dj];
   end;
 end;
end;
Function Determinant(a:matr;n:integer):longint;
{ Вычисление определителя матрицы(рекурсивное) }
var i,j,d,k:longint;
    b:matr;
begin
d:=0; k:=1;
if n=1 then d:=a[1,1]
else if n=2 then d:=a[1,1]*a[2,2]-a[2,1]*a[1,2]
else { n>2 }
 for i:=1 to n do
  begin
   GetMatr(a,b,n,i,1);
   d:=d+k*a[i,1]*Determinant(b,n-1);
   k:=-k;
  end;
Determinant:=d;
end;
procedure Umnozenie(var a:matr;n,d:integer);
var i,j:integer;
begin
for i:=1 to n do
for j:=1 to n do
a[i,j]:=a[i,j]*d
end;
procedure Trans(var a:matr;n:integer);
var i,j,x:integer;
begin
for i:=2 to n do
for j:=1 to i-1 do
 begin
  x:=a[i,j];
  a[i,j]:=a[j,i];
  a[j,i]:=x;
 end
end;
var a:matr;
    n,i,j,dt:integer;
begin
clrscr;
randomize;
{ Заполнение матрицы случайными числами }
repeat
write('Размер матрицы до ',nmax,' n=');
readln(n)
until n in [1..nmax];
for i:=1 to n do
for j:=1 to n do
a[i,j]:=-5+random(11);
{ Печать исходной матрицы }
writeln('Исходная матрица:');
PrintMatr(a,n);
{ Вычисление и вывод определителя }
dt:=Determinant(a,n);
writeln('Определитель=',dt);
Umnozenie(a,n,dt);
writeln('Умножение на определитель:');
PrintMatr(a,n);
Trans(a,n);
writeln('Транспонирование:');
PrintMatr(a,n);
readln
end.