Консольная графика. Наривовать елки по заданным параметрам

Module Module1
 
    Sub Main()
        Dim M, N, K As Integer
        Console.Write("Введите количество строк: ")
        M = Integer.Parse(Console.ReadLine())
        Console.Write("Введите количество столбцов: ")
        N = Integer.Parse(Console.ReadLine())
        Console.Write("Введите количество строк в ёлке: ")
        K = Integer.Parse(Console.ReadLine())
        Console.Clear()
        Console.WriteLine("======= {0} =======", "Программа ЁЛЫ")
        Console.WriteLine("M={0}{3}N={1}{3}K={2}", M, N, K, vbNewLine)
        For i As Integer = 1 To M
            Console.ForegroundColor = ConsoleColor.DarkGreen
            Console.WriteLine(DrawTrees(N, K))
            Console.ForegroundColor = ConsoleColor.Gray
            Console.WriteLine(DrawTrunks(N, K))
            Console.WriteLine()
        Next
        Console.ReadLine()
 
    End Sub
 
    ''' <summary>
    ''' Рисование дерева
    ''' </summary>
    ''' <param name="N">Количество деревьев</param>
    ''' <param name="K">Количество "веток" в дереве</param>
    Private Function DrawTrees(ByVal N As Integer, ByVal K As Integer) As String
        Dim result As New System.Text.StringBuilder
        Dim row As String
        For i As Integer = 1 To K
            row = New String("#", 2 * i - 1)
            For j As Integer = 1 To N
                result.Append(row.PadLeft(K + i - 1).PadRight(2 * K))
            Next
            If i <> K Then result.AppendLine()
        Next
        Return result.ToString()
    End Function
 
    ''' <summary>
    ''' Рисование ствола
    ''' </summary>
    ''' <param name="N">Количество стволов</param>
    ''' <param name="K">Количество "веток" у дерева</param>
    Private Function DrawTrunks(ByVal N As Integer, ByVal K As Integer) As String
        Dim result As New System.Text.StringBuilder
        For j As Integer = 1 To N
            result.Append("#".PadLeft(K).PadRight(2 * K))
        Next
        Return result.ToString()
    End Function
End Module