Поиск слова по шаблону

Public Class Form1
 
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        If (LastName1.Text = "" Or BookName.Text = "") Then
            MsgBox("Введены некоректные данные")
            Return
        End If
 
        Dim Name As String
        Name += LastName1.Text + Space(15 - Len(LastName1.Text))
        Name += LastName2.Text + Space(15 - Len(LastName2.Text))
        FileOpen(1, "LastName.dat", OpenMode.Random, , , 34)
        FilePutObject(1, Name, 1 + LOF(1) / 34)
        FileClose(1)
 
        Dim Name2 As String
        Name2 += BookName.Text + Space(15 - Len(BookName.Text))
        FileOpen(2, "BookName.dat", OpenMode.Random, , , 34)
        FilePutObject(2, Name2, 1 + LOF(2) / 34)
        FileClose(2)
 
        LastName1.Text = ""
        LastName2.Text = ""
        BookName.Text = ""
    End Sub
 
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        If (CardNumber.Text = "") Then
            MsgBox("Запрос неверный")
            Return
        End If
 
        Dim Name As String
        FileOpen(1, "LastName.dat", OpenMode.Random, , , 34)
        FileGetObject(1, Name, Val(CardNumber.Text))
        FileClose(1)
 
        Label6.Text = Mid(Name, 1, 15)
        Label12.Text = Mid(Name, 16, 15)
 
        Dim Name2 As String
        FileOpen(2, "BookName.dat", OpenMode.Random, , , 34)
        FileGetObject(2, Name2, Val(CardNumber.Text))
        FileClose(2)
        Label7.Text = Mid(Name2, 1, 15)
 
    End Sub
 
End Class

Dim Name As String
Name += LastName1.Text + Space(15 - Len(LastName1.Text))
Name += LastName2.Text + Space(15 - Len(LastName2.Text))

Dim fix As Integer = 15
Dim Name As String = String.Empty
Name &= LastName1.Text.PadRight(fix) & LastName2.Text.PadRight(fix)

Imports System.IO
Public Class Form6
    Private fldStr As Integer = 25 'размеры полей
    Private fldId As Integer = 5
    Private lstA As List(Of atBook) 'списки авторов, книг, связей
    Private lstB As List(Of atBook)
    Private lstID As List(Of ID2)
    'структура для авторов, книг
    Private Structure atBook
        Public ID As Integer
        Public Name As String
        Public Sub New(ByVal ii As Integer, ByVal nm As String)
            ID = ii
            Name = nm
        End Sub
    End Structure
    'структура для связей
    Private Structure ID2
        Public IDa As Integer
        Public IDb As Integer
        Public Sub New(ByVal ii1 As Integer, ByVal ii2 As Integer)
            IDa = ii1
            IDb = ii2
        End Sub
    End Structure
    Private Sub Form6_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        'загрузка файлов
        If File.Exists("author.dat") Then
            lstA = readFile("author.dat")
        Else
            lstA = New List(Of atBook)
        End If
        If File.Exists("book.dat") Then
            lstB = readFile("book.dat")
        Else
            lstB = New List(Of atBook)
        End If
        If File.Exists("relation.dat") Then
            lstID = readFileID("relation.dat")
        Else
            lstID = New List(Of ID2)
        End If
    End Sub
    ''' <summary>
    ''' чтение файла данных
    ''' </summary>
    Private Function readFile(ByVal fName As String) As List(Of atBook)
        Dim lst As New List(Of atBook)
        Using Reader As New FileIO.TextFieldParser(fName)
            Reader.TextFieldType = FileIO.FieldType.FixedWidth
            Reader.SetFieldWidths(fldId, fldStr)
            Dim currentRow As String()
            While Not Reader.EndOfData
                Try
                    currentRow = Reader.ReadFields()
                    lst.Add(New atBook(CInt(currentRow(0)), currentRow(1)))
                Catch ex As FileIO.MalformedLineException
                    MsgBox("Запись " & ex.Message & " испорчена и будет пропущена.")
                End Try
            End While
        End Using
        Return lst
    End Function
    ''' <summary>
    ''' чтение файла индексов
    ''' </summary>
    Private Function readFileID(ByVal fName As String) As List(Of ID2)
        Dim lst As New List(Of ID2)
        Using Reader As New FileIO.TextFieldParser(fName)
            Reader.TextFieldType = FileIO.FieldType.FixedWidth
            Reader.SetFieldWidths(fldId, fldId)
            Dim currentRow As String()
            While Not Reader.EndOfData
                Try
                    currentRow = Reader.ReadFields()
                    lst.Add(New ID2(CInt(currentRow(0)), CInt(currentRow(1))))
                Catch ex As FileIO.MalformedLineException
                    MsgBox("Запись " & ex.Message & " испорчена и будет пропущена.")
                End Try
            End While
        End Using
        Return lst
    End Function
    ''' <summary>
    ''' сохранение файла данных
    ''' </summary>
    Private Sub writeFileID(ByVal fName As String, ByVal lst As List(Of ID2))
        Dim file As System.IO.StreamWriter = My.Computer.FileSystem.OpenTextFileWriter(fName, False, System.Text.Encoding.Default)
        For Each ln As ID2 In lst
            Dim s As String = ln.IDa.ToString.PadRight(fldId) & ln.IDb.ToString.PadRight(fldId)
            file.WriteLine(s)
        Next
        file.Close()
    End Sub
    ''' <summary>
    ''' сохранение файла индексов
    ''' </summary>
    Private Sub writeFile(ByVal fName As String, ByVal lst As List(Of atBook))
        Dim file As System.IO.StreamWriter = My.Computer.FileSystem.OpenTextFileWriter(fName, False, System.Text.Encoding.Default)
        For Each ln As atBook In lst
            Dim s As String = ln.ID.ToString.PadRight(fldId) & ln.Name.PadRight(fldStr)
            file.WriteLine(s)
        Next
        file.Close()
    End Sub
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        If FIO.Text.Length = 0 OrElse bookName.Text.Length = 0 Then
            MsgBox("Введены некоректные данные")
            Return
        End If
        Dim aName As String = FIO.Text
        Dim isA As Boolean
        Dim indA As Integer = isExistName(aName, lstA)
        If indA < 0 Then
            If lstA.Count = 0 Then
                indA = 1
            Else
                Dim mx = (From r As atBook In lstA Select r.ID).ToArray.Max
                indA = mx + 1
            End If
            lstA.Add(New atBook(indA, aName))
            isA = True
        End If
        Dim bName As String = bookName.Text
        Dim indB As Integer = isExistName(bName, lstB)
        If indB < 0 Then
            If lstB.Count = 0 Then
                indB = 1
            Else
                Dim mx = (From r As atBook In lstB Select r.ID).ToArray.Max
                indB = mx + 1
            End If
            lstB.Add(New atBook(indB, bName))
            lstID.Add(New ID2(indA, indB))
        Else
            If isA Then
                lstID.Add(New ID2(indA, indB))
            Else
                Dim ii As New ID2(indA, indB)
                If Not lstID.Contains(ii) Then lstID.Add(ii)
            End If
        End If
    End Sub
    Private Function isExistName(ByVal ss As String, ByVal lst As List(Of atBook)) As Integer
        Dim ii As Integer = -1
        Dim rr = From r In lst Where r.Name = ss Select r.ID
        If rr.Count > 0 Then ii = rr(0)
        Return ii
    End Function
    ''' <summary>
    ''' сохранить базу
    ''' </summary>
    Private Sub Button3_Click(sender As System.Object, e As System.EventArgs) Handles Button3.Click
        writeFile("author.dat", lstA)
        writeFile("book.dat", lstB)
        writeFileID("relation.dat", lstID)
    End Sub
    Private Sub Button2_Click(sender As System.Object, e As System.EventArgs) Handles Button2.Click
        If authorName.Text.Length = 0 Then Exit Sub
        Dim nm As String = authorName.Text
        ListBox1.Items.Clear()
        Dim iiA As Integer = isExistName(nm, lstA)
        If iiA < 0 Then
            MsgBox("Автор не найден!")
            Exit Sub
        End If
        Dim sb = (From bi As ID2 In lstID Where bi.IDa = iiA Select bi.IDb).ToArray
        If sb.Length = 0 Then
            MsgBox("Книги не найдены!")
            Exit Sub
        End If
        Dim bnm = (From nn As atBook In lstB Where sb.Contains(nn.ID) Select nn.Name).ToArray
        For Each ss As String In bnm
            ListBox1.Items.Add(ss)
        Next
    End Sub
End Class

Private Function findA(ByVal str As String) As List(Of String)
    Dim lst As New List(Of String)
    For Each aa As atBook In lstA
        If aa.Name.StartsWith(str, StringComparison.CurrentCultureIgnoreCase) Then
            lst.Add(aa.Name)
        End If
    Next
    Return lst
End Function