Как сделать скриншот ограниченный формой окна?

Public Class Form1
    Dim GripWidth = 8   'ширина границы для растягивания
    Private Sub Form1_Paint(ByVal sender As System.Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles MyBase.Paint
        Dim OutLineColor As Color = Color.Black
        Dim InnerLineColor As Color = Color.Black
        Me.ResizeRedraw = True 'перерисовка формы при растягивании
        Dim Caption As String = ClientArea.Width & "x" & ClientArea.Height
 
        'Закрашиваем фон заголовка формы (чтобы текст рисовался красиво)
        e.Graphics.FillRectangle(New SolidBrush(Me.BackColor), 1, 1, Me.Width - 2, 28)
 
 
        'Обводим границу Форму
        e.Graphics.DrawRectangle(New Pen(OutLineColor), 0, 0, Me.Width - 1, Me.Height - 1)
        'Обводим границу клиентской области
        e.Graphics.DrawRectangle(New Pen(InnerLineColor), GripWidth, 30, Me.Width - (GripWidth * 2) - 1, Me.Height - (GripWidth + 30) - 1)
 
        'Рисуем родную Иконку в левом верхнем углу
        e.Graphics.DrawImage(New Bitmap(Me.Icon.ToBitmap, 16, 16), New Point(GripWidth, GripWidth))
 
        'Рисуем тень для заголовка формы
        e.Graphics.DrawString(Caption, New Font("Segoe UI", 12, Me.Font.Style), New SolidBrush(Color.FromArgb(75, Me.ForeColor)), New Point(GripWidth + (GripWidth / 2) + 17, 6))
        'Рисуем текст заголовока формы
        e.Graphics.DrawString(Caption, New Font("Segoe UI", 12, Me.Font.Style), New SolidBrush(Me.ForeColor), New Point(GripWidth + (GripWidth / 2) + 16, 5))
    End Sub
 
    Protected Overrides Sub WndProc(ByRef m As Message)
        Const WM_NCHITTEST As UInt32 = &H84
 
        Const HTCAPTION = &H2 'ЗАГОЛОВОК ФОРМЫ
        Const HTLEFT As UInt32 = 10 'растягиваем за левый край
        Const HTRIGHT As UInt32 = 11 'растягиваем за правый край
        Const HTBOTTOMRIGHT As UInt32 = 17 'растягиваем за право-низ
        Const HTBOTTOM As UInt32 = 15 'растягиваем за нижний край
        Const HTBOTTOMLEFT As UInt32 = 16 'растягиваем за лево-низ
        Const HTTOP As UInt32 = 12 'растягиваем за верхний край
        Const HTTOPLEFT As UInt32 = 13 'растягиваем за лево-верх
        Const HTTOPRIGHT As UInt32 = 14 'растягиваем за право-верх
 
        Dim handled As Boolean = False
 
        'перехват сообщения, чтобы вернуть системе измененный параметр растягивания HT
        If m.Msg = WM_NCHITTEST Then
 
            'курсор мыши в координатах относительно левого угла формы
            Dim clientPoint As Point = Me.PointToClient(New Point(m.LParam.ToInt32()))
 
            'Создаем прямоугольные области на форме и присваиваем им нужные параметры HT
            Dim boxes As New Dictionary(Of UInt32, Rectangle)
            boxes.Add(HTBOTTOMLEFT, New Rectangle(0, Me.Height - GripWidth, GripWidth, GripWidth))
            boxes.Add(HTBOTTOM, New Rectangle(GripWidth, Me.Height - GripWidth, Me.Width - 2 * GripWidth, GripWidth))
            boxes.Add(HTBOTTOMRIGHT, New Rectangle(Me.Width - GripWidth, Me.Height - GripWidth, GripWidth, GripWidth))
            boxes.Add(HTRIGHT, New Rectangle(Me.Width - GripWidth, GripWidth, GripWidth, Me.Height - 2 * GripWidth))
            boxes.Add(HTTOPRIGHT, New Rectangle(Me.Width - GripWidth, 0, GripWidth, GripWidth))
            boxes.Add(HTTOP, New Rectangle(GripWidth, 0, Me.Width - 2 * GripWidth, GripWidth))
            boxes.Add(HTTOPLEFT, New Rectangle(0, 0, GripWidth, GripWidth))
            boxes.Add(HTLEFT, New Rectangle(0, GripWidth, GripWidth, Me.Height - 2 * GripWidth))
            boxes.Add(HTCAPTION, New Rectangle(GripWidth, GripWidth, Me.Width - GripWidth, 30 - GripWidth))
 
            'возврат HT-параметра, выбранного в зависимости от того, в каком фрагменте окна находился курсор
            For Each hitbox In boxes
                If hitbox.Value.Contains(clientPoint) Then
                    m.Result = hitbox.Key
                    handled = True
                    Exit For
                End If
            Next
        End If
 
        'Посылаем комманду форме если курсор в созданных нами прямоугольных областях
        If Not handled Then
            MyBase.WndProc(m)
        End If
    End Sub
 
    Private Sub ctlBoxCLOSE_Click(sender As Object, e As EventArgs) Handles ctlBoxCLOSE.Click
        Me.Close()
    End Sub
 
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim file As String = String.Format("{0}\ClientAreaCapture {1}x{2}.bmp", My.Computer.FileSystem.SpecialDirectories.Desktop, ClientArea.Width, ClientArea.Height)
        Dim bmp As New Bitmap(ClientArea.Width, ClientArea.Height)
        Using g = Graphics.FromImage(bmp)
            g.CopyFromScreen(New Point(Me.Left + ClientArea.Left, Me.Top + ClientArea.Top), New Point(0, 0), ClientArea.Size)
            bmp.Save(file, Imaging.ImageFormat.Bmp)
        End Using
        bmp.Dispose()
        MsgBox("Saved to " & file)
    End Sub
End Class