Форум программистов, компьютерный форум, киберфорум
Наши страницы
Visual Basic .NET
Войти
Регистрация
Восстановить пароль
 
 
Рейтинг 4.77/118: Рейтинг темы: голосов - 118, средняя оценка - 4.77
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
1

Технология клиент-сервер. Классы клиента и сервера. Обсуждение

16.10.2011, 16:02. Просмотров 21613. Ответов 102
Метки нет (Все метки)

В данном теме выкладываю свои классы клиента и сервера, а так же простеньких примеров реализованных на этих классах. Жду конструктивной критики, идей, предложений по улучшению, оптимизации и прочего.
Так же прошу поправлять меня, если комментарии в коде не соответствуют реальной действительности. Комментировал то как я это понимаю.
P.S. с орфографией тоже туговато, так что исправляем


Класс СЕРВЕРА.
vb.net
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
Imports System.Net.Sockets
 
Public Class Class_Server
    Public Delegate Sub StatusInvoker(ByVal t As String) ' делегат для синхронизации при выводе сообщений
 
 
    Private port As Integer = 13000 ' порт сервера на котором он работает
    Private server_name As String ' название сервера. Например: Game, Authorization server . Просто для удобства
    Private flag As Byte ' в текущий версии не используется. В будущем планируется клиентов с другим флагом сразу отключать, что бы только "правильные" клиенты могли подключаться к серверу.
 
    Private server_Listener As TcpListener ' Сам TcpListener который и прослушивает нужный порт
    Private clientsList As New Hashtable ' Список клиентов. (Уникальный индификатор ID,сам класс клиента)
 
    Public Event OnRead(ByVal _client As handleClinet, ByVal _data As String) ' Событие вызываемое при получении данных от клиентов
    Public Event Connect(ByVal _client As handleClinet) ' Событие вызываемое при подключении клиента
    Public Event Disconnect(ByVal _client As handleClinet, ByVal _reson As String) ' Событие вызываемое при отключении клиента
    Public Event messege(ByVal text As String) ' событие вызываемое, когда нужно передать информацию из класса
 
    Public Sub New(ByVal _Port As Integer, ByVal _Name As String, ByVal _Flag As Byte) ' инициализация класса. Порт, название, флаг
        port = _Port
        server_name = _Name
        flag = _Flag
    End Sub
 
    Public Sub start() ' Запуск сервера.
        Dim server_Thread As Threading.Thread = New Threading.Thread(AddressOf startServ)
        server_Thread.Start() ' Запуск отдельного потока на прослушивание порта и подключений к серверу
    End Sub
 
    Public Sub stop_server() ' Процедура для закрытия сервера. 
        Dim Item As DictionaryEntry
        Dim list As Hashtable = clientsList
        For Each Item In list ' Перебор всех клиентов в списке
            CType(Item.Value, handleClinet).closeClient() ' Закрываем каждого клиента, что бы поток клиента завершился.
        Next
 
        server_Listener.Stop() ' Остановка прослушивания порта
    End Sub
 
    Public ReadOnly Property User_List() As Hashtable ' Возращаем список клиентов в виде хэш таблицы.
        Get
            Return clientsList
        End Get
    End Property
 
    Private Sub Client_OnRead(ByVal client As handleClinet, ByVal data As String) ' Процедура, вызываемая при получении сервером данных от клиента
        RaiseEvent OnRead(client, data) ' вызываем событие сервера, что клиент прислал данные
    End Sub
    Private Sub Client_Disconnect(ByVal client As handleClinet, ByVal reson As String) ' Процедура, вызываемая при отключении клиента
        clientsList.Remove(client.ID) ' удаляем клиента из списка клиентов
        RaiseEvent Disconnect(client, reson) ' вызываем событие сервера, что отключился клиент
    End Sub
 
    Public Sub Send_user(ByVal client As handleClinet, ByVal data As String) ' Процедура отправки данных нужному клиенту
        Dim tcp As TcpClient = client.TCP() ' получаем TcpClient нужный для получения потока записи
        Dim stream As NetworkStream = tcp.GetStream ' получение потока записи
 
        Dim mess() As Byte = System.Text.Encoding.UTF8.GetBytes(data) ' преобразование сообщения в байты для потока
 
        stream.Write(mess, 0, mess.Length) ' отсылка данных в виде байт
        stream.Flush() ' честно не знаю, что это делает. Работает и с этим и без, но в большинстве примеров есть, поэтому оставил.
    End Sub
    Public Sub Send_all(ByVal data As String) ' Процедура посылки сообщения всем клиентам
        Dim Item As DictionaryEntry
        Dim list As Hashtable = clientsList
 
        For Each Item In list ' Перебор всех клиентов и рассылка через Send_user
            Send_user(CType(Item.Value, handleClinet), data)
        Next
    End Sub
 
 
    Private Sub startServ() ' процедура служащая для прослушивания порта и подключении клиентов
        Dim client As TcpClient
        Dim count As Integer ' Кол-во подключений
 
        Try
            server_Listener = New TcpListener(port)
            server_Listener.Start() ' Начинаем прослушивать порт
            msg("=========Сервер " & Me.server_name & " запущен...=========")
 
 
            While True ' Бесконечный цикл, что бы клиенты могли подключаться всегда
                count += 1 ' Новое подключение, значит счетчик +1
 
                client = server_Listener.AcceptTcpClient() ' Ждем подключения. Когда клиент подключается, запоминаем его в client
 
                Dim temp_client As New handleClinet(client, count) ' Создаем новый класс клиента и передаем ему подключившегося клиента и его номер подключения
                temp_client.startClient(Me) ' Запускаем клиента и прослушивание входящих сообщений. Ссылку на класс сервера передаем, что бы клиент мог добавить своё событие на Client_OnRead
                clientsList.Add(temp_client.ID, temp_client) ' Добавляем клиента в список клиентов
 
                RaiseEvent Connect(temp_client) ' Вызываем событие, что клиент подключился
            End While
        Catch ex As Exception
            msg("=========Ошибка сервера " & Me.server_name & ". Причина: " & ex.Message) ' Сообщаем об ошибке
        End Try
 
        ' Так как сюда попасть можно, только после ошибки, значит сервер остановлен. Сообщаем об этом.
        msg("=========Сервер " & Me.server_name & " остановлен!=========")
 
    End Sub
 
    Public Sub msg(ByVal t As String) ' Процедура отправки сообщения
        Try
            RaiseEvent messege(t) ' Вызываем событие о новом сообщении
        Catch ex As Exception
            MsgBox(ex.Message, , "Msg Сервера")
        End Try
    End Sub
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
    Public Class handleClinet ' Класс клиента в сервере. Нужен для индификации и базовых дейсвий с клиентом 
        Public Event OnRead(ByVal _client As handleClinet, ByVal _data As String) ' Событие, что текущий клиент получил данные
        Public Event Disconnect(ByVal _client As handleClinet, ByVal _reson As String) ' Событие при отключении текущего клиента
 
        Private mgID As Guid = Guid.NewGuid ' Получаем уникальный индификатор клиента для хэш таблицы списка клиентов
        Private clientSocket As TcpClient ' Сокет клиента
        Private stream As NetworkStream ' Поток данных клиента
        Private clNo As String ' Номер клиента
        ' Private serv As Class_Server
        Private myIP As String ' Храним тут ип этого клиента
 
        Public Sub New(ByVal inClientSocket As TcpClient, ByVal count As Integer) ' Инициализация клиента
            Me.clientSocket = inClientSocket
            Me.stream = clientSocket.GetStream()
            Me.clNo = count
        End Sub
 
        Public ReadOnly Property IP() As String ' Получение IP
            Get
                If myIP = "" Then myIP = clientSocket.Client.RemoteEndPoint.ToString
                Return myIP
            End Get
        End Property
 
        Public ReadOnly Property ID() As String ' Получение ID
            Get
                Return mgID.ToString
            End Get
        End Property
        Public ReadOnly Property Number() As String ' Получение номера клиента 
            Get
                Return clNo.ToString
            End Get
        End Property
        Public ReadOnly Property TCP() As TcpClient ' Получение TcpClient клиента 
            Get
                Return clientSocket
            End Get
        End Property
        Public Sub closeClient() ' Процедура принудительного закрытия подключения клиента
            stream.Close()
            clientSocket.Close()
        End Sub
 
        Public Sub startClient(ByVal _serv As Class_Server) ' Процедура запуска клиента
            Dim client_Thread As Threading.Thread = New Threading.Thread(AddressOf doListen)
            client_Thread.Start() ' Запуск прослушивания новых данных текущим клиентом в отедьном потоке
 
            AddHandler Me.OnRead, AddressOf _serv.Client_OnRead ' При срабатывании события OnRead в клиенте, вызываем процедуру Client_OnRead на самом сервере
            AddHandler Me.Disconnect, AddressOf _serv.Client_Disconnect ' При срабатывании события Disconnect в клиенте, вызываем процедуру Client_Disconnect на самом сервере
        End Sub
        Private Sub doListen()
            Dim bytes(1048576) As Byte ' 1мб буфер, что бы данные не дробились.
            Dim data As String
            Dim i As Int32
 
            Try
                i = stream.Read(bytes, 0, bytes.Length) ' Ждем новых данных от клиентского приложения. При получении заносим данные в буфер bytes и длину данных в i
                While (i <> 0) ' Цикл бесконечный, пока длина считанных данных не окажется=0, что ознает, что клиент оключился.
                    data = System.Text.Encoding.UTF8.GetString(bytes, 0, i) ' Переводим байты в текст
                    RaiseEvent OnRead(Me, data) ' Вызываем событие о получении новых данных
 
                    i = stream.Read(bytes, 0, bytes.Length) ' Ждем новых данных от клиентского приложения. При получении заносим данные в буфер bytes и длину данных в i
                End While
                closeClient() ' Так как вышли из цикла, то клиентское приложение закрыло соединение. Следовательно закрываем и мы.
                RaiseEvent Disconnect(Me, "Клиент решил отключиться от сервера.") ' Вызываем событие, что клиент отключился и передаем причину.
 
            Catch ex As Exception
                closeClient() ' Ошибка, значит отключаем клиента.
                RaiseEvent Disconnect(Me, "Проблема соединения: " & ex.Message) ' Вызываем событие, что клиент отключился и передаем причину.
 
            End Try
 
        End Sub
    End Class
End Class



Класс КЛИЕНТА
vb.net
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
Imports System.Net.Sockets
 
Public Class Class_client
    Public Delegate Sub StatusInvoker(ByVal t As String) ' делегат для синхронизации при выводе сообщений
 
    Dim client As TcpClient ' Текущий TcpClient связывающий клиента и сервер
    Dim stream As NetworkStream ' Поток данных связывающий клиента и сервер
    Dim flag As Byte ' Пока не используется. Нужен для индификации сервером "правильного" клиента
 
    Dim connection As Boolean = False ' Состояние подключения
 
 
    Public Event OnRead(ByVal _data As String) ' Событие, при получении данных от сервера
    Public Event Disconnected(ByVal _reson As String)  ' Событие, при отключении от сервера
    Public Event messege(ByVal text As String)  ' Событие, при необходимости передать сообщение из класса
    Dim s As Object
 
    Public Function Connect(ByVal server As String, ByVal port As Integer, ByVal _Flag As Byte) As Boolean ' Функция подключения клиента к серверу. Вернет True в случае удачи и False при ошибке.
        If connection = False Then ' Проверка не подключены ли мы уже?
            Try
                Me.client = New TcpClient(server, port)
                Me.stream = client.GetStream()
                Me.flag = _Flag
                Dim client_Thread As Threading.Thread = New Threading.Thread(AddressOf Me.doListen)
                client_Thread.Start() ' Запуск отдельного потока на прослушивание данных с сервера.
                connection = True ' Состояние=Подключен
                Return True
            Catch ex As Exception
                msg(ex.Message) ' Сообщаем об ошибке
                Return False
            End Try
        Else
            Return False ' Если уже подключены, тогда новое подключение не удалось
        End If
    End Function
 
    Public Sub Disconnect(Optional ByVal s As String = "") ' Процедура отключения от сервера. Возможно указать коментарий.
        If connection Then
            connection = False ' Состояние=Отключен
            stream.Close()
            client.Close()
            If s = "" Then
                RaiseEvent Disconnected("Отключен") ' Вызываем событие отключения с коментарием "по умолчанию"
            Else
                RaiseEvent Disconnected(s) ' Вызываем событие отключения с коментарием указанным при вызове текущей процедуры
            End If
 
        End If
    End Sub
 
    Public Function Send(ByVal data As String) As Boolean ' Функция отправки сообщения серверу. Вернет True, если посылка удалась или False в обратном случаее
        If connection Then
            Try
                Dim databyte() As Byte = System.Text.Encoding.UTF8.GetBytes(data) ' Создаем массив байтов для отправки из Data
                stream.Write(databyte, 0, databyte.Length) ' Отправляем наш массив байт.
                stream.Flush() ' честно не знаю, что это делает. Работает и с этим и без, но в большинстве примеров есть, поэтому оставил.
                Return True ' Говорим, что посылка удалась
            Catch ex As Exception
                msg(ex.Message) ' Сообщаем об ошибке
                Disconnect("Проблема при отправке.") ' Отключаемся
                Return False
            End Try
        Else
            Return False ' Если не подключены, то отправка не удалась.
        End If
    End Function
 
 
    Private Sub doListen() ' Процедура прослушки сообщений от сервера
 
 
        Dim bytes(1048576) As Byte ' 1мб буфер, чтобы данные не дробились.
        Dim data As String
        Dim i As Int32
 
        Try
            i = stream.Read(bytes, 0, bytes.Length) ' Ждем новых данных от сервера. При получении заносим данные в буфер bytes и длину данных в i
            While (i <> 0) ' Цикл бесконечный, пока длина считанных данных не окажется=0, что ознает, что соединение с сервером прекращенно.
                data = System.Text.Encoding.UTF8.GetString(bytes, 0, i) ' Переводим байты в текст
                RaiseEvent OnRead(data) ' Вызываем событие о получении новых данных
 
                i = stream.Read(bytes, 0, bytes.Length) ' Ждем новых данных от сервера. При получении заносим данные в буфер bytes и длину данных в i
            End While
            Disconnect() ' Так как вышли из цикла, то сервер закрыло соединение. Следовательно отключаемся.
        Catch ex As Exception
            Disconnect(ex.Message) ' Ошибка, значит отключаемся, указав причину.
        End Try
 
    End Sub
 
 
 
    Public Sub msg(ByVal t As String) ' Процедура отправки сообщения
        Try
            RaiseEvent messege(t)  ' Вызываем событие о новом сообщении
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
End Class


Сообщение в разработке. Примеры будут чуть позже.
33
Надоела реклама? Зарегистрируйтесь и она исчезнет полностью.
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
16.10.2011, 16:02
Ответы с готовыми решениями:

Как вызвать Disconnect клиента (Технология Клиент-Сервер)
Как на сервере вызвать дисконнект клиента на пример когда произойдет тик...

Чат "Сервер-клиент". На сервер не могу отправить сообщение с клиента
Не могу понять как сделать, чтоб сервер ещё прослушивал и сообщения... Нет ли...

Заполнение БД через сервер - чата от клиента
создал (скопировал) чат клиент-сервер по ссылке. теперь нужно что бы при...

Нужен пример клиент-сервера
Подскажите как в visual basic 2010 написать приложение типа клиент-сервер для...

Клиент-сервер
Здравствуйте! У меня вот такая проблемма: Надо написать сервер, он будет...

102
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
16.10.2011, 16:54  [ТС] 2
Лучший ответ Сообщение было отмечено как решение

Решение

Пример СЕРВЕРА

Создаем новый проект Windows Form
На форму кидаем 2 Textbox и 3 button.
Их свойства установятся в Form1_load

Код класса формы1:

vb.net
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
Public Class Form1
    Public SERVER As Class_Server
 
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ' Блок установки свойств контролов на форме. Нужны 2 Textbox и 3 Button
        With Me
            .Size = New Size(641, 417)
            .Text = "СЕРВЕР"
        End With
 
        With TextBox1
            .Multiline = True
            .ForeColor = Color.Lime
            .BackColor = Color.Black
            .Location = New Point(12, 12)
            .Anchor = 15
            .Size = New Size(601, 300)
        End With
 
        With TextBox2
            .Location = New Point(174, 318)
            .Anchor = 14
            .Size = New Size(439, 20)
        End With
 
        With Button1
            .Size = New Size(75, 49)
            .Location = New Point(12, 318)
            .Text = "Запустить сервер"
            .Anchor = 6
        End With
 
        With Button2
            .Size = New Size(75, 49)
            .Location = New Point(93, 318)
            .Text = "Остановить сервер"
            .Anchor = 6
            .Enabled = False
        End With
 
        With Button3
            .Size = New Size(114, 23)
            .Location = New Point(499, 344)
            .Text = "Отправить всем"
            .Anchor = 10
            .Enabled = False
        End With
 
    End Sub
 
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        ' Запуск сервера по клику на кнопке Button1
 
 
        SERVER = New Class_Server(13000, "Game", AscW("+")) ' Инициализация сервера
        ' Установка событий класса нужным процедурам. Описание событий в классе.
        AddHandler SERVER.OnRead, AddressOf Me.OnRead
        AddHandler SERVER.Connect, AddressOf Me.Connect
        AddHandler SERVER.Disconnect, AddressOf Me.Disconnect
        AddHandler SERVER.messege, AddressOf Me.msg
 
        SERVER.start() ' Запуск сервера(прослушивание порта)
 
        Button1.Enabled = False ' Блокируем кнопку запуска сервера
        Button2.Enabled = True ' Разблокируем кнопку остановки сервера
        Button3.Enabled = True ' Разблокируем кнопку отправки сообщения
    End Sub
 
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        ' Остановка сервера по клику на кнопке Button2
        SERVER.stop_server()
 
        Button1.Enabled = True ' Разблокируем кнопку запуска сервера
        Button2.Enabled = False ' Блокируем кнопку остановки сервера
        Button3.Enabled = False ' Блокируем кнопку отправки сообщения
    End Sub
 
    Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        SERVER.Send_all(TextBox1.Text) ' Отправка сообщения из TextBox1 всем клиентам.
    End Sub
 
    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
        SERVER.stop_server() ' При закрытии формы, останавливаем сервер
    End Sub
 
 
    Public Sub Connect(ByVal client As Class_Server.handleClinet) ' Процедура вызываемая при подключении нового клиента
        msg("Клиент №" & client.Number & " подключен." & " IP:" & client.IP) ' Выводим сообщение о подключении клиента, а так же выводим его номер и IP
    End Sub
    Public Sub Disconnect(ByVal client As Class_Server.handleClinet, ByVal reson As String) ' Процедура вызываемая при отключении клиента
        msg("Клиент №" & client.Number & " отключен. Причина: " & reson) ' Выводим сообщение об отключении клиента, а так же выводим его номер и причину.
    End Sub
    Public Sub OnRead(ByVal client As Class_Server.handleClinet, ByVal data As String) ' Процедура вызываемая при получении сервером данных от клиента
        msg("Клиент №" & client.Number & " : " & data) ' Выводим какой клиент и какие данные передал
 
        If data = "PING TEST;" Then ' Если клиент прислал пакет проверки пинга, то отсылаем его обратно.
            SERVER.Send_user(client, data) ' Отправка сообщения от сервера конкретному клиенту
        Else
            ' Отправим обратно клиенту присланные данные, но в верхнем регистре
            SERVER.Send_all(data.ToUpper) ' Отправка сообщения от сервера всем клиентам
            msg("Сервер всем: " & data.ToUpper) ' Вывод этого на экран
        End If
    End Sub
 
 
 
    Private Sub UpdateStatus(ByVal t As String) ' Процедура вывода сообщений в консоль
        Try
            TextBox1.AppendText(vbCrLf & Now & " >> " + t)
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
 
    Public Sub msg(ByVal t As String) ' Процедура выполняемая для вывода сообщения в консоль с синхронизацией потоков
        Try
            If Me.IsHandleCreated Then
                Me.Invoke(New Class_Server.StatusInvoker(AddressOf Me.UpdateStatus), t)
            End If
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
 
End Class
Ну и конечно добавляем класс СЕРВЕРА к этому проекту.
Скриншот полученного сервера прилагается.
10
Миниатюры
Технология клиент-сервер. Классы клиента и сервера. Обсуждение  
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
16.10.2011, 17:39  [ТС] 3
Лучший ответ Сообщение было отмечено как решение

Решение

Исправление для примера выше
vb.net
1
2
3
    Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        SERVER.Send_all(TextBox2.Text & ";") ' Отправка сообщения из TextBox2 всем клиентам.
    End Sub
Пример КЛИЕНТА

Создаем новый проект Windows Form
На форму кидаем 3 Textbox и 4 button.
Их свойства установятся в Form1_load

Код класса формы1:
vb.net
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
Public Class Form1
 
    Public CLIENT As Class_client
    Dim st As New Stopwatch ' Стоп вотчер для замера пинга
 
 
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ' Блок установки свойств контролов на форме. Нужны 3 Textbox и 4 Button
        With Me
            .Size = New Size(641, 417)
            .Text = "КЛИЕНТ"
        End With
 
        With TextBox1
            .Multiline = True
            .ForeColor = Color.PaleTurquoise
            .BackColor = Color.Black
            .Location = New Point(12, 12)
            .Anchor = 15
            .Size = New Size(601, 300)
        End With
 
        With TextBox2
            .Location = New Point(12, 347)
            .Anchor = 14
            .Size = New Size(520, 20)
        End With
 
        With TextBox3
            .Location = New Point(12, 321)
            .Anchor = 6
            .Size = New Size(134, 20)
        End With
 
        With Button1
            .Size = New Size(93, 23)
            .Location = New Point(152, 318)
            .Text = "Подключится"
            .Anchor = 6
        End With
 
        With Button2
            .Size = New Size(93, 23)
            .Location = New Point(251, 318)
            .Text = "Отключиться"
            .Anchor = 6
            .Enabled = False
        End With
 
        With Button3
            .Location = New Point(538, 344)
            .Text = "Отправить"
            .Anchor = 10
            .Enabled = False
        End With
 
        With Button4
            .Location = New Point(538, 315)
            .Text = "Пинг"
            .Anchor = 10
            .Enabled = False
        End With
 
        CLIENT = New Class_client ' Инициализируем класс клиента. Иначе форма не закроется, если не подключится хотя бы раз.
    End Sub
 
    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
        CLIENT.Disconnect() ' При закрытии формы, отключаемся
    End Sub
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        ' Подключение к серверу по нажатию кнопки Button1
 
        CLIENT = New Class_client ' Инициализируем класс клиента
        ' Установка событий класса нужным процедурам. Описание событий в классе.
        AddHandler CLIENT.OnRead, AddressOf Me.OnRead_Invoke
        AddHandler CLIENT.Disconnected, AddressOf Me.Disconnect_Invoke
        AddHandler CLIENT.messege, AddressOf Me.msg_Invoke
 
        If CLIENT.Connect(TextBox3.Text, 13000, AscW("+")) Then ' Если подключение удачное выводим сообщение и разблокируем нужные кнопки на форме
            msg("Подключение установленно!")
            Button1.Enabled = False
            Button2.Enabled = True
            Button3.Enabled = True
            Button4.Enabled = True
        Else
            msg("Не удалось установить подключение!") ' Если подключение не удалось, выводим это.
        End If
    End Sub
 
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        ' Отключение от сервера по нажатию кнопки Button2
 
        CLIENT.Disconnect()
        Button1.Enabled = True
        Button2.Enabled = False
        Button3.Enabled = False
        Button4.Enabled = False
    End Sub
 
    Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        ' Отправка сообщения по нажатию кнопки Button3
        If CLIENT.Send(TextBox2.Text & ";") Then msg("Клиент: " & TextBox2.Text) ' Если посылка сообщения удалась, выводим это
    End Sub
 
    Private Sub Button4_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button4.Click
        ' Проверка пинга до сервера по нажатию кнопки Button4
        st.Reset()
        st.Start()
        CLIENT.Send("PING TEST;")
    End Sub
 
    Private Sub OnRead(ByVal data As String)
        ' Процедура расшифровки принятых данных
        Dim d() As String
        ' Каждый отдельный пакет должен заканчиваться ";",
        ' что бы была возможность в случаее сильной нагрузки на канал,
        ' принимать по нескольку пакетов одновременно
 
        d = Split(data, ";") ' Разбиваем сообщение по ";"
        For x = 0 To d.Length - 1 ' Перебираем все полученные пакеты
            If d(x) <> "" Then ' Если пакет не пустой делаем его обработку
                If Mid(d(x), 1, 9) = "PING TEST" Then ' Если пакет проверки пинга,  
                    st.Stop() 'то останавливаем стопвотчер
                    msg("Пинг: " & st.ElapsedMilliseconds) 'и выводим пинг в милисекундах
                Else ' Иначе
                    msg("Сервер: " & d(x)) ' просто выводим сообщение с сервера
                End If
            End If
        Next
 
    End Sub
    Private Sub OnRead_Invoke(ByVal data As String) ' Процедура получения данных с сервера с синхронизацией потоков
        Try
            If Me.IsHandleCreated Then
                Me.Invoke(New Class_client.StatusInvoker(AddressOf Me.OnRead), data)
            End If
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
 
 
    Private Sub Disconnect(ByVal reson As String)
        ' Процедура при отключении клиента
        msg("Подключение разорванно! Причина: " & reson)
        Button1.Enabled = True
        Button2.Enabled = False
        Button3.Enabled = False
        Button4.Enabled = False
    End Sub
    Private Sub Disconnect_Invoke(ByVal t As String) ' Процедура отключения от сервера с синхронизацией потоков
        Try
            If Me.IsHandleCreated Then
                Me.Invoke(New Class_client.StatusInvoker(AddressOf Me.Disconnect), t)
            End If
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
 
 
    Private Sub msg(ByVal t As String) ' Процедура вывода сообщений в консоль
        TextBox1.AppendText(vbCrLf & Now & " >> " + t)
    End Sub
    Private Sub msg_Invoke(ByVal t As String) ' Процедура выполняемая для вывода сообщения в консоль с синхронизацией потоков
        Try
            If Me.IsHandleCreated Then
                Me.Invoke(New Class_client.StatusInvoker(AddressOf Me.msg), t)
            End If
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
 
 
End Class
Ну и конечно добавляем класс КЛИЕНТА к этому проекту.
Скриншот полученного клиента прилагается.


Не по теме:


Ну вроде всё. Теперь, если не сложно, это всё нужно объединить в 1 пост и исправить код сервера

11
Миниатюры
Технология клиент-сервер. Классы клиента и сервера. Обсуждение  
tomaticus
48 / 48 / 5
Регистрация: 02.01.2011
Сообщений: 505
16.10.2011, 17:40 4
Эта система работает в среде lan ?
или по самому интернету?
0
nanshakov
Студент :)
891 / 324 / 12
Регистрация: 29.01.2011
Сообщений: 1,680
16.10.2011, 17:43 5
KingManiya, Можно будет дораьботать под себя,и изменять?
0
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
16.10.2011, 17:49  [ТС] 6
Лучший ответ Сообщение было отмечено как решение

Решение

Можно дорабатывать.
Эта система работает в среде lan ?
или по самому интернету?
По интернету работает, сам на себя работает. В лане должно работать ибо слушается любой порт.
8
tomaticus
48 / 48 / 5
Регистрация: 02.01.2011
Сообщений: 505
16.10.2011, 17:52 7
KingManiya, тогда хорошо..перепишу свой клиент под такой как у тебя.
1
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
16.10.2011, 18:13  [ТС] 8
Лучший ответ Сообщение было отмечено как решение

Решение

любой порт.
Любой ип

тогда хорошо..перепишу свой клиент под такой как у тебя.
Переписывай, для этого и выложил.
6
Treals
29 / 29 / 3
Регистрация: 25.05.2011
Сообщений: 308
16.10.2011, 20:07 9
Спасибо ... Теперь будет много пищи для изучения клиент-сервер технологии )
1
nanshakov
Студент :)
891 / 324 / 12
Регистрация: 29.01.2011
Сообщений: 1,680
16.10.2011, 20:44 10
Ага,я уже внутрисерверные команды начал делать(а-ля судо в линукс.)
0
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
17.10.2011, 08:36  [ТС] 11
Спасибо ... Теперь будет много пищи для изучения клиент-сервер технологии )
А я думал это мне тут скажут, как лучше делать и меня научат
Ага,я уже внутрисерверные команды начал делать(а-ля судо в линукс.)
У меня друг сервер подключил напрямую к судо, а я через клиент отправлял запросы и получал результат)
Узнал и о компе друга и о пользователях, создал своего пользователя, создал в нем файлы и т.д)

vb.net
1
 stream.Flush() ' честно не знаю, что это делает. Работает и с этим и без, но в большинстве примеров есть, поэтому оставил.
Знает кто, для чего это? Только русским языком, а не из мсдн отрывок.
1
Eugene22
_
2351 / 1224 / 78
Регистрация: 28.10.2009
Сообщений: 4,331
17.10.2011, 10:46 12
Лучший ответ Сообщение было отмечено как решение

Решение

Цитата Сообщение от KingManiya Посмотреть сообщение
Знает кто, для чего это?
сбрасывает все буферизированные данные в потом. Иногда в этом методе и нет необходимости, но лучше его вызывать, убедился на своем опыте, потому что если его не вызвать, то поток может закрыться, не успев в поток записать финальную часть данных.
3
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
17.10.2011, 11:35  [ТС] 13
сбрасывает все буферизированные данные в потом. Иногда в этом методе и нет необходимости, но лучше его вызывать, убедился на своем опыте, потому что если его не вызвать, то поток может закрыться, не успев в поток записать финальную часть данных.
Его именно всегда после записи использовать? Или перед тоже?
stream.flush
stream.write(...)
stream.flush

До чтения или после чтения нужно использовать?
0
Eugene22
_
2351 / 1224 / 78
Регистрация: 28.10.2009
Сообщений: 4,331
17.10.2011, 11:46 14
Лучший ответ Сообщение было отмечено как решение

Решение

KingManiya, перед записью, то есть перед stream.write()
3
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
17.10.2011, 12:21  [ТС] 15
Лучший ответ Сообщение было отмечено как решение

Решение

Класс сервера:
Меняем это:
vb.net
1
2
3
4
5
6
7
8
9
Public Sub Send_user(ByVal client As handleClinet, ByVal data As String) ' Процедура отправки данных нужному клиенту
        Dim tcp As TcpClient = client.TCP() ' получаем TcpClient нужный для получения потока записи
        Dim stream As NetworkStream = tcp.GetStream ' получение потока записи
 
        Dim mess() As Byte = System.Text.Encoding.UTF8.GetBytes(data) ' преобразование сообщения в байты для потока
 
        stream.Write(mess, 0, mess.Length) ' отсылка данных в виде байт
        stream.Flush() ' честно не знаю, что это делает. Работает и с этим и без, но в большинстве примеров есть, поэтому оставил.
    End Sub
На это:
vb.net
1
2
3
4
5
6
7
8
Public Sub Send_user(ByVal client As handleClinet, ByVal data As String) ' Процедура отправки данных нужному клиенту
        Dim tcp As TcpClient = client.TCP() ' получаем TcpClient нужный для получения потока записи
        Dim stream As NetworkStream = tcp.GetStream ' получение потока записи
 
        Dim mess() As Byte = System.Text.Encoding.UTF8.GetBytes(data) ' преобразование сообщения в байты для потока
        stream.Flush()
        stream.Write(mess, 0, mess.Length) ' отсылка данных в виде байт
    End Sub
Класс клиента, меняем это:
vb.net
1
2
3
4
5
6
7
 Public Function Send(ByVal data As String) As Boolean ' Функция отправки сообщения серверу. Вернет True, если посылка удалась или False в обратном случаее
        If connection Then
            Try
                Dim databyte() As Byte = System.Text.Encoding.UTF8.GetBytes(data) ' Создаем массив байтов для отправки из Data
                stream.Write(databyte, 0, databyte.Length) ' Отправляем наш массив байт.
                stream.Flush() ' честно не знаю, что это делает. Работает и с этим и без, но в большинстве примеров есть, поэтому оставил.
                Return True ' Говорим, что посылка удалась
На это
vb.net
1
2
3
4
5
6
7
 Public Function Send(ByVal data As String) As Boolean ' Функция отправки сообщения серверу. Вернет True, если посылка удалась или False в обратном случаее
        If connection Then
            Try
                Dim databyte() As Byte = System.Text.Encoding.UTF8.GetBytes(data) ' Создаем массив байтов для отправки из Data
                stream.Flush()
                stream.Write(databyte, 0, databyte.Length) ' Отправляем наш массив байт.
                Return True ' Говорим, что посылка удалась

Не по теме:

Как же не удобно, что нельзя редактировать свои посты после 10 минут(



Памирыч:
Выкладывай исправленный вариант, с пометкой вместо чего должно быть - я переправлю
3
eJ_Studio
167 / 147 / 14
Регистрация: 13.07.2011
Сообщений: 477
17.10.2011, 18:32 16
Цитата Сообщение от Eugene22 Посмотреть сообщение
перед записью, то есть перед stream.write()
А разве не после????????????????
0
Eugene22
_
2351 / 1224 / 78
Регистрация: 28.10.2009
Сообщений: 4,331
17.10.2011, 18:39 17
Цитата Сообщение от eJ_Studio Посмотреть сообщение
А разве не после????????????????
ну да после, я перепутал write и close, видимо, переработался.
Правильная последователность
vb.net
1
2
3
stream.Flush()
 stream.Write()
stream.Close()
0
Treals
29 / 29 / 3
Регистрация: 25.05.2011
Сообщений: 308
17.10.2011, 18:57 18
Я что то не могу найти где указывается в сервере IP О_о
0
KingManiya
198 / 198 / 13
Регистрация: 14.10.2011
Сообщений: 227
17.10.2011, 19:06  [ТС] 19
Я что то не могу найти где указывается в сервере IP
А для чего на сервере указывать какой то ип?
Запустив сервер, он начинает слушать какой либо порт, нам том ип на котором он запущен(внеший или локальный без разницы).
А вот что бы клиенту подключиться, нужно знать ип сервера и порт на сервере.

ну да после, я перепутал write и close, видимо, переработался.
Правильная последователность

vb.net
1
2
3
1 stream.Flush()
2 stream.Write()
3 stream.Close()
Походу опять ошибся) Раз говоришь, что ошибся с flush перед write
vb.net
1
2
  stream.Write(mess, 0, mess.Length) ' отсылка данных в виде байт
        stream.Flush()
У меня вот так. Это правильно?
1
Treals
29 / 29 / 3
Регистрация: 25.05.2011
Сообщений: 308
17.10.2011, 19:07 20
Т.е без перенастройки сервера могут зайти как с локалки так и с внешки?
0
17.10.2011, 19:07
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
17.10.2011, 19:07

Клиент-сервер
Мне нужно сделать две программы - простейший клиент и сервер. Я находил очень...

Как сделать так, чтобы при закрытии клиента закрывался и сервер?
Допустим есть две программы... Одна из них сервер вторая клиент... Первая...

Маленький клиент-сервер
Ну ни как не получается у меня создать маленький клиент-сервер. Пишу на VB2010....


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
20
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.
Рейтинг@Mail.ru