Меню, как на стартовой странице Visual Studio

Public Class Form1
    Dim TS As ToolStrip
    Dim TSB As ToolStripButton
    Dim StartTSB As ToolStripButton
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ' создаем новый элемент ToolTip
        TS = New ToolStrip
        With TS
            .Dock = DockStyle.None
            .Anchor = AnchorStyles.Left Or AnchorStyles.Top
            .Location = New Point(0, 0)
            .AutoSize = True
            .LayoutStyle = ToolStripLayoutStyle.Table
            .GripStyle = ToolStripGripStyle.Hidden
            .ImageScalingSize = New Size(24, 24)
            .RenderMode = ToolStripRenderMode.System
        End With
        ' и вешаем его на форму
        Me.Controls.Add(TS)
        ' теперь стартовую группу
        Me.CreateStartGroup()
        ' ну тут немного украшательства :)
        Me.AutoSizeMode = Windows.Forms.AutoSizeMode.GrowAndShrink
        Me.AutoSize = True
        Me.MaximizeBox = False
    End Sub
 
    Private Sub CreateStartGroup()
        ' опишем начальную кнопку и повесим ее на TS
        StartTSB = New ToolStripButton
        With StartTSB
            .DisplayStyle = ToolStripItemDisplayStyle.Text  ' покажем текст
            .Text = "Создать список"
            .ToolTipText = "Выбрать папку для создания списка"
            .Margin = New System.Windows.Forms.Padding(0, 0, 0, 5) ' отделим ее немного от других кнопок
            AddHandler StartTSB.Click, AddressOf StartTSB_Click ' прицепляем процедуру StartTSB_Click к обработчику события Click
        End With
        ' добавляем кнопку на созданный нами ToolTip
        Me.TS.Items.Add(StartTSB)
    End Sub
 
    Private Sub CreateButton(ByVal path As String)
        ' создаем новый ToolStripButton и задаем его свойства, нужные нам
        TSB = New ToolStripButton
        With TSB
            .DisplayStyle = ToolStripItemDisplayStyle.ImageAndText ' покажем и картинку и текст
            .TextImageRelation = TextImageRelation.ImageBeforeText ' картинку перед текстом
            .Text = IO.Path.GetFileNameWithoutExtension(path) ' текстом будет имя файла без расширения
            .ToolTipText = path ' подсказкой полный путь к файлу
            .Image = Icon.ExtractAssociatedIcon(path).ToBitmap ' картинка - получаем из иконки файла
            AddHandler TSB.Click, AddressOf TSB_Click ' прицепляем процедуру TSB_Click к обработчику события Click
        End With
        ' добавляем кнопку на созданный нами ToolTip
        Me.TS.Items.Add(TSB)
    End Sub
 
    Private Sub TSB_Click(ByVal sender As ToolStripButton, ByVal e As System.EventArgs)
        ' по клику на кнопку будет запускаться файл, который с ней ассоциирован
        Process.Start(sender.ToolTipText)
    End Sub
 
    Private Sub StartTSB_Click(ByVal sender As ToolStripButton, ByVal e As System.EventArgs)
        ' теперь насоздаем кнопок списка. Пусть каждая кнопка открывает некоторый файл.
        Dim fbd As New FolderBrowserDialog
        With fbd
            .Description = "Выберите папку для получения списка файлов"
            .RootFolder = Environment.SpecialFolder.Desktop
        End With
        If fbd.ShowDialog = Windows.Forms.DialogResult.OK Then
            ' сначала почистим список (удалим все, а потом восстановим стартовую группу)
            Me.TS.Items.Clear()
            Me.CreateStartGroup()
            ' тут начинаем лепить кнопки
            For Each FN As String In IO.Directory.GetFiles(fbd.SelectedPath, "*", IO.SearchOption.TopDirectoryOnly)
                ' собственно, процедура создания кнопки
                Me.CreateButton(FN)
            Next
        End If
    End Sub
 
End Class