Создать диалог выбора папки для VBA (SolidWorks 2013)

Type BROWSEINFO
    hwndOwner As Long   'Указатель на родительское окно.
    pidlRoot As Long    'Идентификатор папки, с которой начинается просмотр. Если опущен,
                        'то просмотр начинается с корня всей иерархии папок локального ПК.
    pszDisplayName As String    'Указатель на буфер, который будет хранить отображемое имя
                                'папки, выбранной пользователем (без пути к папке!).
                                'Предполагается, что размер буфера равен константе MAX_PATH,
                                'определенной в заголовочном файле windows.h.
    lpszTitle As String 'Указатель на строку с завершающим нулевым символом, которая
                        'будет выведена над деревом папок в диалоговом окне. Вы можете
                        'использовать ее в качестве заголовка, или описать в ней
                        'краткую инструкцию для пользователя.
    ulFlags As Long     'Совокупность битовых флагов, задающих опции диалогового окна.
                        'Опции выражены константами, список которых приведен чуть ниже.
    lpfn As Long        'Указатель на определяемую приложением функцию обратного вызова.
    lParam As Long      'Значение, передаваемое диалоговым окном в функцию обратного вызова.
    iImage As Integer   'Целочисленное значение, хранящее системный индекс изображения,
                        'ассоциированного c выбранной папкой.
End Type
Const BIF_RETURNONLYFSDIRS As Long = &H1&   'Позволяет выбирать папки только в рамках
                                            'файловой системы локального компьютера.
Const BIF_DONTGOBELOWDOMAIN As Long = &H2&  'Позволяет не показывать сетевые папки,
                                            'находящиеся по уровню ниже определенного домена.
Const BIF_STATUSTEXT As Long = &H4&     'Добавляет окно статуса, в которое вы можете выводить
                                        'сообщения с помощью функции обратного вызова. Опция
                                        'несовместима с далоговыми окнами нового типа (т. е.
                                        'с константой BIF_NEWDIALOGSTYLE)
Const BIF_RETURNFSANCESTORS As Long = &H8&  'Позволяет выбирать только предки заданной
                                            'корневой папки в файловой системе
                                            'локального компьютера.
Const BIF_EDITBOX As Long = &H10&   'Добавить поле, в котором пользователь может ввести свое
                                    'имя папки.
Const BIF_VALIDATE As Long = &H20&  'Проверять коректность имени, введенного пользователем
                                    'в текстовое поле. При ошибке ввода вызывается функция
                                    'обратного вызова.
Const BIF_NEWDIALOGSTYLE As Long = &H40&    'Позволяет использовать новый интерфейс
                                            'дилогового окна. Несовместимо с константой
                                            'BIF_STATUSTEXT и с использованием
                                            'многопоточной системы компонентных объектов.
Const BIF_USENEWUI = BIF_EDITBOX Or BIF_NEWDIALOGSTYLE
Const BIF_BROWSEINCLUDEURLS As Long = &H80& 'Позволяет отображать в окне выбора папок
                                            'универсальный локатор ресурса (URL). Для
                                            'корректной работы данной опции должны быть
                                            'установлены также флаги BIF_USENEWUI и
                                            'BIF_BROWSEINCLUDEFILES.
Const BIF_UAHINT As Long = &H100&   'В совокупности с константой BIF_NEWDIALOGSTYLE
                                    'отображает подсказки по использованию окна. Подсказки
                                    'отображаются на месте текстового поля, поэтому опция
                                    'несовместима с константой BIF_EDITBOX.
Const BIF_NONEWFOLDERBUTTON As Long = &H200&    'Не включать в диалог опцию создания
                                                'новой папки.
Const BIF_NOTRANSLATETARGETS As Long = &H400&   'При выборе ярлыка возвращать идентификатор
                                                'ярлыка вместо идентификатора папки, на которую
                                                'он указывает.
Const BIF_BROWSEFORCOMPUTER As Long = &H1000&   'Позволяет указывать в окне выбора папки
                                                'только компьютеры.
Const BIF_BROWSEFORPRINTER As Long = &H2000&    'Позволяет указывать в окне выбора папки
                                                'только принтеры.
Const BIF_BROWSEINCLUDEFILES As Long = &H4000&  'Диалоговое окно просмотра отображает файлы.
Const BIF_SHAREABLE As Long = &H8000&           'Диалоговое окно просмотра может отображать
                                                'общие ресурсы удаленных компьютеров.
Const BIF_BROWSEFILEJUNCTIONS As Long = &H10000 'Позволяет просматривать "ложные" папки вроде
                                                '.zip-файлов или библиотек Windows 7.
'Функция для вызова диалога просмотра папок.
Declare Function SHBrowseForFolder Lib "shell32" Alias "SHBrowseForFolderA" (ByRef bif As BROWSEINFO) As Long
'Функция для перевода идентификатора папки в путь к папке.
Declare Function SHGetPathFromIDList Lib "shell32" Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Boolean
'Функция-"обертка" диалога просмотра папок.
Function MyBrowseForFolder() As String
    Const MAX_PATH = 260 'Определение взято из windows.h.
    Dim MyBIF As BROWSEINFO, retVal As Long, success As Boolean
    Dim buffer As String, instructions As String * 47
    buffer = String(MAX_PATH, 0)
    instructions = "Пожалуйста, выберите папку, которая вам нужна." & Chr(0)
    MyBIF.pszDisplayName = buffer 'Выделяем память для хранения отображаемого имени папки.
    MyBIF.lpszTitle = instructions
    'MyBIF.ulFlags = ... 'Если хотите изменить внешний вид и/или поведение диалогового окна,
    'можете поиграться с флагами. При использовани нескольких флагов они объединяются
    'с помощью побитового ИЛИ (в VBA его функцию выполняет оператор Or).
    retVal = SHBrowseForFolder(MyBIF) 'Начинаем просмотр папок. После того, как пользователь
    'нажмет кнопку "Ок" или "Отмена", в переменную retVal будет передан уникальный системный
    'идентификатор папки, выбранной пользователем, или значение, равное нулю, в случае, если
    'пользователь ничего не выбрал.
    If retVal Then
        buffer = String(32000, 0)
        success = SHGetPathFromIDList(retVal, buffer) 'По идентификатору находим путь к папке.
        If success Then
            buffer = Left(buffer, InStr(buffer, Chr(0)) - 1) 'Отбрасываем нулевые символы.
            MyBrowseForFolder = buffer 'Возвращаем результат.
        Else
            Err.Raise vbObjectError + 2, "MyBrowseForFolder()", "Не удалось получить путь к папке по идентификатору."
        End If
    Else
        Err.Raise vbObjectError + 1, "MyBrowseForFolder()", "Выбор папки отменен пользователем."
    End If
End Function
'Пример использования функции для запуска диалога выбора папки.
Sub TellChosenFolderAndPath()
    Dim s As String
    On Error GoTo ErrHandle
    s = MyBrowseForFolder
    On Error GoTo 0
    MsgBox "Вы выбрали папку: " & s, vbInformation, "Ваш выбор"
    Exit Sub
 
ErrHandle:
    Select Case Err.Number
        Case vbObjectError + 1
            MsgBox Err.Description, vbInformation, "Операция прервана"
        Case vbObjectError + 2
            MsgBox Err.Description, vbExclamation, "Неудача"
        Case Else
            MsgBox Err.Number & vbCr & Err.Description, vbCritical
    End Select
End Sub