Не работает поиск даты через функцию Find

    Cells.Find(What:="07.07*", After:=ActiveCell, LookIn:=xlFormulas, LookAt _
        :=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:= _
        False, SearchFormat:=False).Activate

    Application.FindFormat.NumberFormat = "dd/mm;@"
    Cells.Find(What:="07.07", After:=ActiveCell, LookIn:=xlFormulas, LookAt _
        :=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
        False, SearchFormat:=True).Activate

Sub FindDate()
    Dim mth As Integer, day As Integer, d As Date, rng As Range
    Dim shablon As String, notFoundMsg As String, firstfindAddr As String
    mth = 7: day = 7
    'Внутреннее представление даты в VBA - #[месяц]/[день]/[год]#, с наклонной чертой
    'в качестве разделителя. Следовательно, для поиска 7 июля задаем шаблон 7/7/.
    d = DateSerial(1900, mth, day)
    shablon = Format(d, "m\/d\/")
    Set rng = Cells.Find(What:=shablon, After:=ActiveCell, LookIn:=xlFormulas, LookAt:=xlPart, _
    SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
    'После выполнения операции Find надо обязательно проверить, не вернула ли она пустую ссылку.
    'Это может произойти, если на листе нет ни одной удовлетворяющей критериям поиска ячейки.
    notFoundMsg = "Дата " & Format(d, "dd/mm/XXXX") & " не найдена."
    If rng Is Nothing Then
        MsgBox notFoundMsg
        Exit Sub
    End If
    'Если окажется, что найденное значение - не дата, а хитро составленная злоумышленником строка,
    'например, "777/7/foo" - ищем дальше, пока не найдем дату или не переберем все подходящие ячейки.
    firstfindAddr = rng.Address
    While TypeName(rng.Value) <> "Date"
        Set rng = Cells.Find(What:=shablon, After:=rng, LookIn:=xlFormulas, LookAt:=xlPart, _
        SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
        If rng.Address = firstfindAddr Then
            MsgBox notFoundMsg
            Exit Sub
        End If
    Wend
    rng.Activate
End Sub