Словарь с несколькими элементами

@kwadrad · Регистрация: 10.11.2015

Author24 — интернет-сервис помощи студентам

Здравствуйте!

Вопрос такой: может ли быть Dictionary с несколькими Item, там Item1, Item2, Item3

ну в примеру: key ="Вася", Item1="Блондин", Item2="Шофер", Item3="Женат"
key ="Петя", Item1="Брунет", Item2="Олигарх", Item3="Гуляет"

ну и т.д.

т.е. по сути, может ли словарь быть с несколькими элементами под один ключ

@Hugo121 · 21.11.2016, 16:02

Может.
Но итем может быть только один.
Но зато может быть массивом, или удобно когда оно коллекция.
Или другой словарь.

Добавлено через 1 минуту
Примеры:

Visual Basic

Sub PereborFailov() 'коллекция в словаре
    Dim a, i&, t$, Dic As Object
    Dim el, col
    
    a = Range("C3", Cells(Rows.Count, "A").End(xlUp)).Value
    Set Dic = CreateObject("Scripting.Dictionary")
    With Dic
        .CompareMode = 1
        For i = 1 To UBound(a)
            t = a(i, 1)
            If Not .exists(t) Then .Add t, New Collection
            .Item(t).Add a(i, 2) & "|" & a(i, 3) & "|" & i
        Next
    End With
    
    For Each el In Dic.keys
        Debug.Print "Открываем файл " & el
        For Each col In Dic.Item(el)
            Debug.Print "Ищем данные " & col
        Next
        Debug.Print "Закрываем файл " & el
    Next
 
End Sub
 
Sub PereborFailov2() ' словарь в словаре
    Dim a, i&, t$, Dic As Object, Dic2 As Object
    Dim el, col
    
    a = Range("C3", Cells(Rows.Count, "A").End(xlUp)).Value
    Set Dic = CreateObject("Scripting.Dictionary")
    With Dic
        .CompareMode = 1
        For i = 1 To UBound(a)
            t = a(i, 1)
            If Not .exists(t) Then .Add t, CreateObject("Scripting.Dictionary")
            .Item(t).Item(a(i, 2) & "|" & a(i, 3) & "|" & i) = 0&
            
        Next
    End With
    
    For Each el In Dic.keys
        Debug.Print "Открываем файл " & el
        Set Dic2 = Dic.Item(el)
        For Each col In Dic2.keys
            Debug.Print "Ищем данные " & col '& "|" & Dic2.Item(col)
        Next
        Debug.Print "Закрываем файл " & el
    Next
 
End Sub

@kwadrad · 21.11.2016, 16:23 **[ТС]**

Спасибо, понял

Жаль не то что хотелось

думалось что смогу использовать как переменную

@Hugo121 · 21.11.2016, 16:27

Ну собирайте в массив и используйте.

Добавлено через 1 минуту
Да и к колекции ведь тоже можно обратиться по индексу.

@kwadrad · 21.11.2016, 16:38 **[ТС]**

коллекция тоже выдаст одно значение по индексу

а неудобство массива в том что надо искать нужный элемент, и только потом можно его использовать

@Hugo121 · 21.11.2016, 16:42

Используйте словарь в словаре - там искать не нужно.
Вообще может Вы всё усложняете?

@kwadrad · 21.11.2016, 16:45 **[ТС]**

не исключено

показалось что нашел универсальный инструмент, оказалось нет

@Hugo121 · 21.11.2016, 16:53

Ну по крайней мере запросу по теме словарь соответствует.

Добавлено через 3 минуты

Visual Basic

With CreateObject("Scripting.Dictionary")
    .Item("Вася") = Array("Блондин", "Шофер", "Женат")
    For i = 1 To 3
        MsgBox .Item("Вася")(i - 1)
    Next
End With

@Казанский · 21.11.2016, 16:59

Сообщение от kwadrad

неудобство массива в том что надо искать нужный элемент, и только потом можно его использовать

Вы наверно не поняли.

Visual Basic

1 2	Dic.Add "Вася", Array("Блондин", "Шофер","Женат") Dic.Add "Петя", Array("Брунет", "Олигарх", "Гуляет")

Читать из словаря:
Dic("Вася")(0) - масть, Dic("Вася")(1) - профессия, Dic("Вася")(2) - окольцованность.
Но записывать отдельные элементы массива, находящегося в словаре, не получится - только формировать новый массив и присваивать элементу словаря целиком.

@Hugo121 · 21.11.2016, 17:12

Чтоб изменить элемент массива - выгружаете массив в внешний массив, меняете элемент, грузите весь массив назад.

Добавлено через 3 минуты

Visual Basic

Sub tt()
 
With CreateObject("Scripting.Dictionary")
 
    .Item("Вася") = Array("Блондин", "Шофер", "Женат")
    
    For i = 1 To 3
        MsgBox .Item("Вася")(i - 1)
    Next
    
    Arr = .Item("Вася")
    Arr(0) = "Блондин, но крашеный"
    Arr(2) = "Холост"
    .Item("Вася") = Arr
    
     For i = 1 To 3
        MsgBox .Item("Вася")(i - 1)
    Next
   
End With
 
End Sub

@kwadrad 0 / 0 / 0 Регистрация: 10.11.2015 Сообщений: 24
		1
	Словарь с несколькими элементами 21.11.2016, 15:59. Показов 6246. Ответов 9 Метки нет (Все метки) Здравствуйте! Вопрос такой: может ли быть Dictionary с несколькими Item, там Item1, Item2, Item3 ну в примеру: key ="Вася", Item1="Блондин", Item2="Шофер", Item3="Женат" key ="Петя", Item1="Брунет", Item2="Олигарх", Item3="Гуляет" ну и т.д. т.е. по сути, может ли словарь быть с несколькими элементами под один ключ 0

@kwadrad 0 / 0 / 0 Регистрация: 10.11.2015 Сообщений: 24
	21.11.2016, 16:23 [ТС]	3
	Спасибо, понял Жаль не то что хотелось думалось что смогу использовать как переменную 0

@Hugo121 6922 / 2832 / 543 Регистрация: 19.10.2012 Сообщений: 8,645
	21.11.2016, 16:27	4
	Ну собирайте в массив и используйте. Добавлено через 1 минуту Да и к колекции ведь тоже можно обратиться по индексу. 0

@kwadrad 0 / 0 / 0 Регистрация: 10.11.2015 Сообщений: 24
	21.11.2016, 16:38 [ТС]	5
	коллекция тоже выдаст одно значение по индексу а неудобство массива в том что надо искать нужный элемент, и только потом можно его использовать 0

@Hugo121 6922 / 2832 / 543 Регистрация: 19.10.2012 Сообщений: 8,645
	21.11.2016, 16:42	6
	Используйте словарь в словаре - там искать не нужно. Вообще может Вы всё усложняете? 0

@kwadrad 0 / 0 / 0 Регистрация: 10.11.2015 Сообщений: 24
	21.11.2016, 16:45 [ТС]	7
	не исключено показалось что нашел универсальный инструмент, оказалось нет 0

	21.11.2016, 17:12