Переформатирование таблицы с данными

@Евгений Жуков · Регистрация: 01.03.2015

Author24 — интернет-сервис помощи студентам

Добрый день, коллеги.

Нужна Ваша помощь в решении следующей задачи: имеется исходная таблица отчета по продажам, которая выгружается из 1С. Вы можете найти ее в файле на листе "Как есть".

Обычно, в ручном режиме происходит перенос данных с формата "Как есть" в формат, который Вы можете найти на листе "Как нужно".

Ввиду того, что объем данных становится все больше (на данный момент, в день количество строк с данными доходит до 1 000), соответственно процесс по их трансформации также удлиняется.

Напишите пожалуйста, каким образом, можно осуществить трансформацию данных в формат, который находится на листе "Как нужно"?

Буду признателен Вам за любую помощь.

С уважением,

Евгений

@KoGG · 12.01.2017, 12:15

Visual Basic

Sub Преобразовать_чистые_продажи()
    Dim i&, j&, k&, LastRow&, Region, Manager, A, B
    Cells.UnMerge
    Cells.ClearFormats
    [b7] = "Код"
    [C7] = "Номенклатура"
    [D7] = "Единица имерения"
    [F7] = "Менеджер"
    Columns("A:A").Delete
    Rows(8).Delete
    Rows("1:6").Delete
    Columns("A:L").ColumnWidth = 32.5
    LastRow = Cells(Rows.Count, 1).End(xlUp).Row
    A = Range("A1:L" & LastRow).Value
    ReDim B(1 To LastRow, 1 To 12)
    For j = 1 To 12
        B(1, j) = A(1, j)
    Next
    k = 1
    For i = 2 To LastRow - 1
        If Trim(A(i, 1)) = "" Then
            If Trim(A(i, 4)) <> "" Then Region = A(i, 4)
            If Trim(A(i, 5)) <> "" Then Manager = A(i, 5)
        Else
            k = k + 1
            For j = 1 To 12
                B(k, j) = A(i, j)
            Next
            B(k, 4) = Region
            B(k, 5) = Manager
        End If
    Next
    Range("A1:L" & LastRow).Value = B
    Rows(1).Font.Bold = True
End Sub

@Евгений Жуков · 12.01.2017, 13:15 **[ТС]**

Уважаемый KoGG,

Большое Вам спасибо, что откликнулись на эту тему.

Напишите пожалуйста, а можно также вставлять наименование контрагента в отдельный столбец, как показано на листе "Как нужно", столбец D?
Возможно, Вы скачали первую версию файла (где я запамятовал указать этот столбец).

С уважением,

Евгений

@KoGG · 12.01.2017, 13:59

Под новый файл:

Visual Basic

Sub Преобразовать_чистые_продажи_2()
    Dim i&, j&, k&, LastRow&, Kontragent, Region, Manager, A, B
    Cells.UnMerge
    Cells.ClearFormats
    Rows(8).Delete
    Rows("1:6").Delete
    Columns("A:M").ColumnWidth = 32.5
    LastRow = Cells(Rows.Count, 2).End(xlUp).Row
    Range("A1:C" & LastRow).Value = Range("B1:D" & LastRow).Value
    Columns("D").ClearContents
    [A1] = "Код"
    [b1] = "Номенклатура"
    [C1] = "Единица имерения"
    [f1] = "Менеджер"
    [d1] = "Контрагент"
    A = Range("A1:M" & LastRow).Value
    ReDim B(1 To LastRow, 1 To 13)
    For j = 1 To 13
        B(1, j) = A(1, j)
    Next
    k = 1
    For i = 2 To LastRow - 1
        If Trim(A(i, 1)) = "" Then
            If Trim(A(i, 2)) <> "" Then Kontragent = A(i, 2)
            If Trim(A(i, 5)) <> "" Then Region = A(i, 5)
            If Trim(A(i, 6)) <> "" Then Manager = A(i, 6)
        Else
            k = k + 1
            For j = 1 To 13
                B(k, j) = A(i, j)
            Next
            B(k, 4) = Kontragent
            B(k, 5) = Region
            B(k, 6) = Manager
        End If
    Next
    Range("A1:M" & LastRow).Value = B
    Rows(1).Font.Bold = True
End Sub

@Евгений Жуков 0 / 0 / 0 Регистрация: 01.03.2015 Сообщений: 21
	12.01.2017, 13:15 [ТС]	3
	Уважаемый KoGG, Большое Вам спасибо, что откликнулись на эту тему. Напишите пожалуйста, а можно также вставлять наименование контрагента в отдельный столбец, как показано на листе "Как нужно", столбец D? Возможно, Вы скачали первую версию файла (где я запамятовал указать этот столбец). С уважением, Евгений 0

	12.01.2017, 13:59

Переформатирование таблицы с данными

Решение