Окрашивание текста в ячейке в зависимости от самого первого символа в этой строке

@lixar21 · Регистрация: 02.01.2017

Author24 — интернет-сервис помощи студентам

Здравствуйте, господа программисты.
Помогите решить проблему.

На листе в табличке - определенным символам - присвоен свой уникальный цвет.
Ниже - находится диапазон, в котором приведен различный текст в ячейках.

Как заставить макрос - при условии что ключевой символ - является первым символом строки - окрашивать весь текст в ячейке - данным цветом ?

(То есть - если ячейка в диапазоне C15:K38 - начинается с символа " - то весь текст этой ячейки окрашивается в тот цвет, который имеет шрифт в ячейке J6 (в данном случае - Красный))

@Narimanych · 20.09.2017, 11:07

lixar21,
Тут можно и без макросов .
Попробуйте "Условное форматирование"( "Conditional formatting")

@lixar21 · 20.09.2017, 11:25 **[ТС]**

Narimanych , вы не поняли.
Макрос должен сперва присвоить символу цвет шрифта - из ячейки напротив ключевого символа.

@Vlad999 · 20.09.2017, 11:35

Сообщение от lixar21

должен сперва присвоить символу цвет шрифта - из ячейки напротив

обязательно?
вариант без присвоения, с пропиской в коде.

Visual Basic

For Each r In Range("C15:K38").SpecialCells(xlCellTypeConstants, 23)
      n = InStr(1, ";""$#^", Left(r, 1))
      r.Font.Color = Choose(n, -11489280, vbRed, -6279056, vbBlue, -16727809)
Next

@lixar21 · 20.09.2017, 11:46 **[ТС]**

Vlad999 , понимаете в чем дело.
Вот вы написали Font.Color = Choose(n, -11489280, vbRed, -6279056, vbBlue, -16727809)
Я узнал, что это - зеленый цвет, только введя этот код.

Но я ведь не знаю эти численные комбинации цветов в стиле RGB.
А там есть - оранжевый, фиолетовый.

toiai · 20.09.2017, 12:11

Как вариант:

Visual Basic

Sub pr()
    Dim r As Range, s$
    With CreateObject("scripting.dictionary")
        For Each r In Range("i5:i9")
            .Item(r.Value) = r.Offset(, 1).Font.Color
        Next
        For Each r In Range("C15:K38").SpecialCells(xlCellTypeConstants, 23)
              s = Left(r, 1)
              If .exists(s) Then r.Font.Color = .Item(s)
        Next
    End With
End Sub

@lixar21 · 20.09.2017, 12:21 **[ТС]**

toiai , вот это - самое подходящее решение.
Большое спасибо за помощь.

@pashulka · 20.09.2017, 14:53

Ещё один вариант

правда по сути, просто скрещивание двух предыдущих, но без словаря

Visual Basic

Private Sub Test()
    Dim c As New Collection, r As Range, n&, t$
    For Each r In [J5:J9]
        c.Add r.Font.Color: t = t & r(1, 0)
    Next
    For Each r In [C15:K38].SpecialCells(xlConstants, xlTextValues)
        n = InStr(t, Left(r, 1))
        If n > 0 Then r.Font.Color = c(n)
    Next
End Sub

@Narimanych 2724 / 1701 / 776 Регистрация: 23.03.2015 Сообщений: 5,388
	20.09.2017, 11:07	2
	lixar21, Тут можно и без макросов . Попробуйте "Условное форматирование"( "Conditional formatting") 0

@lixar21 0 / 0 / 0 Регистрация: 02.01.2017 Сообщений: 123
	20.09.2017, 11:25 [ТС]	3
	Narimanych , вы не поняли. Макрос должен сперва присвоить символу цвет шрифта - из ячейки напротив ключевого символа. 0

@lixar21 0 / 0 / 0 Регистрация: 02.01.2017 Сообщений: 123
	20.09.2017, 11:46 [ТС]	5
	Vlad999 , понимаете в чем дело. Вот вы написали Font.Color = Choose(n, -11489280, vbRed, -6279056, vbBlue, -16727809) Я узнал, что это - зеленый цвет, только введя этот код. Но я ведь не знаю эти численные комбинации цветов в стиле RGB. А там есть - оранжевый, фиолетовый. 0

@lixar21 0 / 0 / 0 Регистрация: 02.01.2017 Сообщений: 123
	20.09.2017, 12:21 [ТС]	7
	toiai , вот это - самое подходящее решение. Большое спасибо за помощь. 0

	20.09.2017, 14:53