Гиперссылка для добавления новой строки

@ksenia0510 · Регистрация: 13.01.2017

Author24 — интернет-сервис помощи студентам

Добрый день!
От бывшего работника достался файл. Вижу хорошую формулу, но не могу понять, что это за формул и как она работает. Суть в следующем, последняя строка таблицы (красным выделен текст - добавить) содержит гиперссылку для добавления новой строки, при нажатии добавляется новая строка и в ней можно из раскрывающего списка выбрать профессии. С раскрывающимся списком все понятно, но как добавляется новая строка понять не могу.
Помогите, пожалуйста. Файл прикладываю)

@Vlad999 · 09.10.2017, 11:11

начальный файл xlsx? У меня строчка не добавляется.
Подозреваю в оригинале прописан макрос на переход по гиперссылке.

@ksenia0510 · 09.10.2017, 11:26 **[ТС]**

Да, извиняюсь. Прикладываю полный файл.

@Dinoxromniy · 09.10.2017, 13:46

Сообщение от ksenia0510

но как добавляется новая строка понять не могу.

ksenia0510, если зайти в vba редактор, то ожидаемо окажется, что в листе "Таблица профессий" есть код, выполняющийся после нажатия на гиперссылку (ячейка с надписью "Добавить").

Visual Basic

Private Sub Worksheet_FollowHyperlink(ByVal target As Hyperlink)
    
    Application.EnableCancelKey = xlDisabled
    On Error GoTo errhandler
    
    target.Range.Worksheet.Rows(target.Range.Row - 1).Select
    Selection.Copy
    Selection.Insert Shift:=xlDown
    Application.CutCopyMode = False
    
    Exit Sub
errhandler:
    MsgBox Err.Description, vbOKOnly, ActiveSheet.Name
End Sub

@pashulka · 09.10.2017, 17:09

Тоже самое, но без лишних символов :

Visual Basic

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
    On Error GoTo ErrHandler
 
    Target.Range.EntireRow(0).Copy
    Target.Range.Insert
    Application.CutCopyMode = False
    Exit Sub
 
ErrHandler:
    MsgBox Err.Description, , Name
End Sub

@Dinoxromniy · 09.10.2017, 17:34

Еще логично проверять, что нажата именно ссылка с надписью "Добавить", иначе код будет добавлять строку перед любой гиперссылкой, находящейся на листе "Таблица профессий". Хотя, полагаю, вопрос у ТС был больше риторический.

Visual Basic

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
    On Error GoTo ErrHandler
    If Target.Range.Value = "Добавить" Then
        Target.Range.EntireRow(0).Copy
        Target.Range.Insert
        Application.CutCopyMode = False
    End If
    
    Exit Sub
    
ErrHandler:
    MsgBox Err.Description, , Name
End Sub

@pashulka · 09.10.2017, 17:54

Если в этом листе необходимы и другие гиперссылки, то можно обойти и без посредника - гиперссылки. Проще говоря, можно создать кнопку, назначить ей макрос, "привязать" кнопку к ячейке(строке) <Перемещать объект вместе с ячейками> и при необходимости, снять флажок <Выводить объект на печать>

@Vlad999 3897 / 2302 / 776 Регистрация: 02.11.2012 Сообщений: 6,119
	09.10.2017, 11:11	2
	начальный файл xlsx? У меня строчка не добавляется. Подозреваю в оригинале прописан макрос на переход по гиперссылке. 0

@pashulka 4134 / 2238 / 940 Регистрация: 01.12.2010 Сообщений: 4,624
	09.10.2017, 17:54	7
	Если в этом листе необходимы и другие гиперссылки, то можно обойти и без посредника - гиперссылки. Проще говоря, можно создать кнопку, назначить ей макрос, "привязать" кнопку к ячейке(строке) <Перемещать объект вместе с ячейками> и при необходимости, снять флажок <Выводить объект на печать> 0