Вставка данных из словаря по условию

@Makroshka · Регистрация: 26.09.2016

Author24 — интернет-сервис помощи студентам

Прошу помощи, так как код выдает ошибку и я не понимаю что надо исправить. По задумке в словарь попадают ключи и элементы, которые если ключ совпадают, добавляются через запятую. Потом эти склеиные элементы надо выгрузить в файл по совпадению ключа и данных из столбика А. Написала код:

Visual Basic

Dim dicDom 'переменная словаря
Dim keyNum As Variant 'переменная для договора
  A = ActiveSheet.UsedRange
  Set dicDom = CreateObject("Scripting.Dictionary")
  With Sheets("èñõ")
    For i = 1 To UBound(A)
        keyNum = CStr(.Cells(i, 1).Value) 'получаем ключ
        dicDom(keyNum) = dicDom(keyNum) & ", " & CStr(.Cells(i, 3).Value) 'добавляем значение элемента
    Next i
    For i = 1 To UBound(A) 'выгружаем элементы из словаря по условию
    If dicDom.Keys(keyNum) = .Cells(i, 1) Then
    .Cells(i, 4) = dicDom.Items(keyNum)
    End If
    Next i
  End With

Выдает ошибку на строке:

Visual Basic

1	If dicDom.Keys(keyNum) = .Cells(i, 1) Then

У меня есть подозрение, что это из-за того что нет параллельного цикла по словарю, но как это сделать не знаю.

@Казанский · 02.07.2018, 16:49

Makroshka, файл-пример приложите

@Makroshka · 02.07.2018, 17:19 **[ТС]**

Прикладываю файл пример. В реальном документе 200 тыс+ строк. Поэтому скорость тоже имеет немалое значение.

@Hugo121 · 02.07.2018, 19:23

Чуть недокрутили... но принципиально.

Visual Basic

        For i = 1 To UBound(A)    'выгружаем элементы из словаря по условию
            keyNum = CStr(.Cells(i, 1).Value)    'получаем ключ
            If dicDom.exists(keyNum) Then
                .Cells(i, 4) = dicDom.Item(keyNum)
            End If
        Next i

Добавлено через 1 минуту
А вообще под это дело давно есть UDF, например я такую написал и применяю:

Visual Basic

1	=VLOOKUPCOUPLE(A:C;1;A2;3;", ")

код где-то здесь на форуме есть.
Вот нашёл: Поиск и сохранение данных на другой лист разделенных "; "

@Казанский · 02.07.2018, 19:29

Сообщение от Makroshka

Поэтому скорость тоже имеет немалое значение

Поэтому не надо обращаться в цикле к ячейкам, ведь все данные уже в массиве:

Visual Basic

Sub gg()
Dim dicDom 'переменная словаря
Dim keyNum As Variant 'переменная для договора
Dim A(), i&
  Set dicDom = CreateObject("Scripting.Dictionary")
  A = ActiveSheet.UsedRange.Value
  For i = 1 To UBound(A)
      keyNum = CStr(A(i, 1)) 'получаем ключ
      dicDom(keyNum) = dicDom(keyNum) & ", " & A(i, 3) 'добавляем значение элемента
  Next i
  ReDim B$(1 To UBound(A), 1 To 1)
  For i = 1 To UBound(A) 'выгружаем элементы из словаря по условию
    B(i, 1) = Mid$(dicDom(CStr(A(i, 1))), 3)
  Next i
  Range("D1").Resize(UBound(B)).Value = B
End Sub

@Hugo121 · 02.07.2018, 19:37

Да, на 200 тыс. строк конечно такую UDF применять нет смысла, долго... Но можно например написать массивную - только заносить её будет трудно

P.S. не обратил внимания что там ячейки перебираются

Но если там 200000 строк, то вся usedrange может не поместиться в память (вдруг там правее ещё есть данные), берите только нужные столбцы. И ещё - не всегда usedrange начинается с первой строки листа, и тут тоже в таком коде может ожидать подвох

@Makroshka · 03.07.2018, 11:21 **[ТС]**

Казанский, спасибо, использовала ваш вариант. Не могли бы вы пояснить откуда берутся переменные Mid$ и CStr. Они нигде не назначаются, значит вписаны непосредственно в алгоритм словаря. Где об этом можно поподробнее почитать, а то я этой инфы нигде не находила.

Hugo121, я прислала конечную таблицу, поэтому использование только нужных столбцов не критично. Но на будущее хотелось бы для себя прояснить вопрос: если только определенные столбца, то я завожу такую строку кода:

Visual Basic

1	A = ActiveSheet.Range("A:A","C:C").Value

Правильно?

~~Остап Бонд~~ · 03.07.2018, 12:02

Makroshka, ВЫ без малого три года в VBA - пора бы основы языка освоить.

Сообщение от Makroshka

откуда берутся переменные Mid$ и CStr

https://msdn.microsoft.com/ru-... d-function
https://msdn.microsoft.com/ru-... -functions

@Казанский · 03.07.2018, 12:09

Makroshka, Cstr в вашем коде было. Это функция, которая возвращает текстовое представление аргумента. Для словаря это необязательно, но если вдруг в разных строках NUM будет представлен как число 7 и текст "7", то с этой функцией это будет один и тот же ключ, а без нее - разные ключи.
Mid - функция, которая возвращает часть строки. Поставьте курсор в слово Mid и нажмите F1 - это вообще универсальный метод

@Hugo121 · 03.07.2018, 12:10

Сообщение от Makroshka

Правильно?

неправильно.
В массив можно (я говорю про "легко") взять только смежные столбцы, можете допустить пару/несколько лишних, но нет никакого смысла брать возможно десятки лишних правее.
Если нужные например второй и двадцать второй, то я обычно делаю два отдельных массива. Или можно делать массив массивов, что в общем только усложнит понимание кода

@Hugo121 · 03.07.2018, 12:12

Не по теме:

Я думал только у меня глючит - оказалось форум подглюкивает :)

@Makroshka · 03.07.2018, 12:54 **[ТС]**

Спасибо, все поняла)

@Казанский 15145 / 6418 / 1731 Регистрация: 24.09.2011 Сообщений: 9,999
	02.07.2018, 16:49	2
	Makroshka, файл-пример приложите 0

@Hugo121 6922 / 2832 / 543 Регистрация: 19.10.2012 Сообщений: 8,645
	02.07.2018, 19:37	6
	Да, на 200 тыс. строк конечно такую UDF применять нет смысла, долго... Но можно например написать массивную - только заносить её будет трудно P.S. не обратил внимания что там ячейки перебираются Но если там 200000 строк, то вся usedrange может не поместиться в память (вдруг там правее ещё есть данные), берите только нужные столбцы. И ещё - не всегда usedrange начинается с первой строки листа, и тут тоже в таком коде может ожидать подвох 0

~~Остап Бонд~~ Заблокирован
	03.07.2018, 12:02	8
	Makroshka, ВЫ без малого три года в VBA - пора бы основы языка освоить. Сообщение от Makroshka откуда берутся переменные Mid$ и CStr https://msdn.microsoft.com/ru-... d-function https://msdn.microsoft.com/ru-... -functions 0

@Казанский 15145 / 6418 / 1731 Регистрация: 24.09.2011 Сообщений: 9,999
	03.07.2018, 12:09	9
	Makroshka, Cstr в вашем коде было. Это функция, которая возвращает текстовое представление аргумента. Для словаря это необязательно, но если вдруг в разных строках NUM будет представлен как число 7 и текст "7", то с этой функцией это будет один и тот же ключ, а без нее - разные ключи. Mid - функция, которая возвращает часть строки. Поставьте курсор в слово Mid и нажмите F1 - это вообще универсальный метод 0

@Hugo121 6922 / 2832 / 543 Регистрация: 19.10.2012 Сообщений: 8,645
	03.07.2018, 12:10	10
	Сообщение от Makroshka Правильно? неправильно. В массив можно (я говорю про "легко") взять только смежные столбцы, можете допустить пару/несколько лишних, но нет никакого смысла брать возможно десятки лишних правее. Если нужные например второй и двадцать второй, то я обычно делаю два отдельных массива. Или можно делать массив массивов, что в общем только усложнит понимание кода 0

@Hugo121
	03.07.2018, 12:12 #11
	Не по теме: Я думал только у меня глючит - оказалось форум подглюкивает :) 0

@Makroshka 0 / 0 / 0 Регистрация: 26.09.2016 Сообщений: 163
	03.07.2018, 12:54 [ТС]	12
	Спасибо, все поняла) 0