Undo/Redo или CTRL+Z – CTRL+Y »» не работает для личных макросов

Sub CellColor()
Call CellColor_Do(0)
End Sub
 
Private Sub CellColor_Do(Undo As Integer)
Static xBook As Workbook, xSheet As Worksheet, xSelection As Range, xColor As Long
Const sName As String = "CellColor"
Const sUndo As String = "Undo Color in "
Const sRedo As String = "Redo Color in "
If Undo = 0 Then
    Set xBook = ActiveWorkbook
    Set xSheet = ActiveSheet
    Set xSelection = Selection
    xColor = Selection.Cells(1).Interior.Color
    xSelection.Show
    xSelection.Interior.Color = RGB(227, 38, 54)
    Application.OnUndo (sUndo + xSelection.Address(False, False)), (ThisWorkbook.Name + "!" + sName + "_Undo")
ElseIf xSelection Is Nothing Then
    Beep
Else
    xBook.Activate
    xSheet.Activate
    xSelection.Select
    xSelection.Show
    If Undo < 0 Then
        xSelection.Interior.Color = xColor
        Application.OnRepeat (sRedo + xSelection.Address(False, False)), (ThisWorkbook.Name + "!" + sName + "_Redo")
    Else
        xSelection.Interior.Color = RGB(227, 38, 54)
        Set xSelection = Nothing
    End If
End If
End Sub
 
Private Sub CellColor_Undo()
    Call CellColor_Do(-1)
End Sub
 
Private Sub CellColor_Redo()
    Call CellColor_Do(1)
End Sub

Sub Note_FillColor_White()
Dim myComm As Comment
  If Not ActiveCell.Comment Is Nothing Then
    If MsgBox("Ячейка уже содержит примечание, удалить?", 4) - 7 Then
      ActiveCell.Comment.Delete
    Else: Exit Sub
    End If
  End If
 
Set myComm = ActiveCell.AddComment
    With myComm.Shape
      .Height = 110
      .Width = 200
      .Top = 55
      .AutoShapeType = 1             'форма
      .Fill.ForeColor.SchemeColor = 1 'заливка » Белый
      .Line.ForeColor.RGB = RGB(255, 0, 0)
      .DrawingObject.Font.Name = "Consolas"
      .DrawingObject.Font.FontStyle = "normal"
      .DrawingObject.Font.Size = 8
     End With
      'Эмулируем выбор пункта "Изменить `Заметку`"
       SendKeys "+{F2}"
End Sub

Sub CoverCommentIndicator(control As IRibbonControl)
    'www.contextures.com/xlcomments03.html
    Dim ws As Worksheet
    Dim cmt As Comment
    Dim lCmt As Long
    Dim rngCmt As Range
    Dim shpCmt As Shape
    Dim shpW As Double 'ширина формы
    Dim shpH As Double 'высота формы
    
    Set ws = ActiveSheet
    shpW = 8
    shpH = 6
    lCmt = 1
    
    For Each cmt In ws.Comments
      Set rngCmt = cmt.Parent
      With rngCmt
        Set shpCmt = ws.Shapes.AddShape(msoShapeRectangle, _
          rngCmt.Offset(0, 1).Left - shpW, .Top, shpW, shpH)
      End With
      With shpCmt
        .Name = "CmtNum" & .Name
        With .Fill
          .ForeColor.SchemeColor = 9 'Цвет заливки
          .Visible = msoTrue
          .Solid
        End With
        With .Line
          .Visible = msoTrue
          .ForeColor.SchemeColor = 64 'Цвет обводки, задаётся автоматически для всех индикаторов!
          .Weight = 0.25 'Толщина обводки, задаётся автоматически для всех индикаторов!
        End With
        With .TextFrame
          .Characters.Text = lCmt
          .Characters.Font.Size = 5 'Размер текста
          .Characters.Font.ColorIndex = xlAutomatic
          .MarginLeft = 0#
          .MarginRight = 0#
          .MarginTop = 0#
          .MarginBottom = 0#
          .HorizontalAlignment = xlCenter 'Расположение текста (в данном случае в центре).
        End With
        .Top = .Top + 0.001 'Расположение рамки (в данном случае справа).
      End With
      lCmt = lCmt + 1
    Next cmt
End Sub