Автозапуск слайда в PowerPoint

@YOKODZUMA · Регистрация: 10.06.2011

Author24 — интернет-сервис помощи студентам

Господа, подскажите как сделать макрос в PowerPoint, чтобы он запускался при показе слайда?

@~~Busine2009~~ · 16.08.2011, 09:29

YOKODZUMA,
полной автоматизации достичь не получится, т.к. после закрытия презентации и последующем её открытии нужно вручную запускать код.

Инструкция:

перейдите в VBA;
создайте модуль класса (Insert - Class Module);
назовите этот модуль класса вот так: EventsClass;

поместите в этот модуль класса вот этот код:

Visual Basic

Option Explicit
 
Public WithEvents Программа As PowerPoint.Application
 
Private Sub Программа_SlideShowBegin(ByVal Wn As SlideShowWindow)
MsgBox "begin"
End Sub

создайте модуль (Insert - Module);

поместите в него вот этот код:

Visual Basic

Option Explicit
 
Dim Переменная As New EventsClass
 
Sub Процедура1()
Set Переменная.Программа = PowerPoint.Application
End Sub

поставьте курсор мыши в любое место этого кода между Sub и End Sub и нажмите зелёную стрелку на панели инструментов;
событие готово к работе.

@YOKODZUMA · 17.08.2011, 03:47 **[ТС]**

Невесело... Ладно придумаю что нибудь
А как макросом таблицу из Excel в поверпойнт скопировать?

@~~Busine2009~~ · 17.08.2011, 07:24

Сообщение от YOKODZUMA

Ладно придумаю что нибудь

напишите, пожалуйста, что придумаете.

Код надо запускать из Excel.
Книга Excel и лист, с которого копируем таблицу, должны быть активными.

1. Вариант. Презентация, в которую надо скопировать таблицу, закрыта.

Visual Basic

Sub Процедура1()
'Для удобства написания кода (чтобы появлялись
'всплывающие подсказки после того, как ставим точку)
'подключим библиотеку объектов программы PowerPoint:
'Tools - References... - Microsoft PowerPoint Object Library.
'Обращаться к PowerPoint будем через переменные.
Dim Программа As New PowerPoint.Application
Dim Презентация As PowerPoint.Presentation
'Обращаться к листу Excel, из которого берём таблицу,
'будем через переменную Лист (так кода меньше писать и удобнее).
Dim Лист As Excel.Worksheet
'Делаем программу PowerPoint видимой на мониторе
'(иначе ошибка какая-то выскакивает).
Программа.Visible = msoTrue
'Открываем презентацию и связываем её с переменной Презентация.
'Здесь надо указать путь и имя презентации.
Set Презентация = _
    Программа.Presentations.Open(Filename:="C:\Documents and Settings\Пользователь\Рабочий стол\Презентация1.ppt")
Set Лист = ActiveWorkbook.ActiveSheet
'Копируем таблицу из Excel из активной книги из активного листа.
Лист.Range(Лист.Cells(1, 1), Лист.Cells(5, 5)).Copy
'Вставка таблицы на первый слайд презентации.
Презентация.Slides(1).Shapes.Paste
'Сохранение и закрытие презентации.
Презентация.Save
Презентация.Close
End Sub

2. Вариант. Презентация, в которую надо скопировать таблицу, открыта.

Visual Basic

Sub Процедура2()
'Программа PowerPoint должна быть запущена и презентация,
'в которую надо скопировать таблицу, должна быть открыта.
Dim Презентация As Object
Dim Лист As Excel.Worksheet
'Получаем доступ к открытой презентации и связываем её с переменной Презентация.
'Здесь указываем путь и имя презентации.
Set Презентация = GetObject(PathName:="C:\Documents and Settings\Пользователь\Рабочий стол\Презентация1.ppt")
Set Лист = ActiveWorkbook.ActiveSheet
'Копируем таблицу из Excel из активной книги из активного листа.
Лист.Range(Лист.Cells(1, 1), Лист.Cells(5, 5)).Copy
'Вставка таблицы на первый слайд презентации.
Презентация.Slides(1).Shapes.Paste
End Sub

@YOKODZUMA 0 / 0 / 0 Регистрация: 10.06.2011 Сообщений: 4
		1
	Автозапуск слайда в PowerPoint 16.08.2011, 06:34. Показов 5632. Ответов 3 Метки нет (Все метки) Господа, подскажите как сделать макрос в PowerPoint, чтобы он запускался при показе слайда? 0

@YOKODZUMA 0 / 0 / 0 Регистрация: 10.06.2011 Сообщений: 4
	17.08.2011, 03:47 [ТС]	3
	Невесело... Ладно придумаю что нибудь А как макросом таблицу из Excel в поверпойнт скопировать? 0

	17.08.2011, 07:24