Необходимо в MS Excel написать макрос, который бы формировал презентацию в Power Point

Sub Процедура1()
    'Подключаем библиотеку классов программы PowerPoint
    '(чтобы можно было работать из Excel в PowerPoint):
    'Tools - References... - Microsoft PowerPoint Object Library.
    'Подключение этой библиотеки упрощает написание кода,
    'т.к. после того, как будем ставить точки в коде -
    'будут появляться всплывающие подсказки.
    Dim objPowerPoint As New PowerPoint.Application
    'Делаем программу PowerPoint видимой на мониторе.
    objPowerPoint.Visible = msoTrue
    Dim objTemplate As PowerPoint.Presentation
    'Здесь нужно указать, где находится шаблон презентации и его имя.
    Const strTemplatePath As String = "C:\Documents and Settings\Пользователь\Рабочий стол\для макроса\ШАБЛОН.ppt"
    'Здесь нужно указать, куда "сохраняется как" шаблон-презентация.
    Const strSaveAs As String = "C:\Documents and Settings\Пользователь\Рабочий стол\ШАБЛОН.ppt"
    'Здесь нужно указать папку, в которой находятся мини-презентации.
    Const strWorkFolder As String = "C:\Documents and Settings\Пользователь\Рабочий стол\для макроса\"
    Dim i As Long
    'Открываем шаблон-презентацию и говорим, что будем обращаться
    'к ней с помощью переменной objTemplate.
    'Использование переменной objTemplate даёт следующие преимущества:
    '1) кода меньше писать;
    '2) не промахнётесь - не станете случайно работать с другой презентацией.
    Set objTemplate = objPowerPoint.Presentations.Open(Filename:=strTemplatePath)
    '"Сохраняем как" шаблон-презентацию. Я сохраню на Рабочий стол.
    objTemplate.SaveAs Filename:=strSaveAs
    'Добавление в шаблон-презентацию мини-презентаций в соответствии с плюсиками в Excel.
    'Просматриваем строки со 2 по 6 (согласно вашему файлу).
    For i = 2 To 6 Step 1
        If Cells(i, "C").Value = "+" Then
            objTemplate.Slides.InsertFromFile _
                Filename:=strWorkFolder & Cells(i, "A").Value, Index:=objTemplate.Slides.Count
        End If
    Next i
    'Сообщение, что работа выполнена.
    MsgBox "Презентация сформирована!", vbInformation
End Sub

Dim objPowerPoint As Object
Dim objTemplate As Object
Set objPowerPoint = CreateObject(Class:="PowerPoint.Application")

    objTemplate.SaveAs Filename:=strSaveAs
    objTemplate.Close

objPowerPoint.Quit

objTemplate.SaveAs Filename:=strSaveAs
    objTemplate.Close
    objPowerPoint.Quit
     
    'Сообщение, что работа выполнена.
    MsgBox "Презентация сформирована!", vbInformation

objTemplate.Save
objTemplate.Close
Set objTemplate= Nothing
objPowerPoint.Quit
Set objPowerPoint= Nothing