Необходимо узнать какой decimal separator установлен в системе?

Option Explicit
Private Const LOCALE_SDECIMAL = &HE
Private Const LOCALE_STHOUSAND = &HF
Private Declare Function GetLocaleInfo Lib "kernel32" Alias "GetLocaleInfoA" (ByVal Locale As Long, ByVal lCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long
Private Declare Function GetUserDefaultLCID Lib "kernel32" () As Long
Private Function LoadLocaleValue(ByVal plngType As Long) As String
    Dim lngLocaleReturn As Long
    Dim lngLocale As Long
    Dim strCData As String
    Dim lngChData As Long
    Dim strReturn As String
    
    lngLocale = GetUserDefaultLCID
    strCData = String(100, " ")
    lngChData = Len(strCData)
        
    lngLocaleReturn = GetLocaleInfo(lngLocale, plngType, strCData, lngChData)
    If InStr(strCData, Chr(0)) Then
        strReturn = Trim(Left(strCData, InStr(strCData, Chr(0)) - 1))
    Else
        strReturn = Trim(strCData)
    End If
    
    LoadLocaleValue = strReturn
    
End Function
Private Sub Command1_Click()
    MsgBox "Decimal separator is: " & LoadLocaleValue(LOCALE_SDECIMAL)
    MsgBox "Thousand separator is: " & LoadLocaleValue(LOCALE_STHOUSAND)
End Sub