Erase для массива, являющегося элементом коллекции

Private Sub Proba()
  Dim Collect As New Collection
  ReDim Arr(1 To 3) As Integer
  Arr(1) = 3: Arr(2) = 4: Arr(3) = 5
  Collect.Add Arr
  Erase Collect.Item(1) '//////////////////////
  Dim B As Integer: B = Collect.Item(1)(2): MsgBox "B = " & VBA.CStr(B)   ' Выводит на экран окно с текстом "B = 4"
End Sub

' код модуля класса MyArr
 
Dim arr() As Integer
 
Public Sub EraseArr() 'метод для стирания массива
Erase arr
End Sub
 
Public Sub ArrWrite(indx&, value) 'метод для записи элемента массива
arr(indx) = value
End Sub
 
Public Function ArrRead(indx&) 'свойство, возвращающее элемент массива
ArrRead = arr(indx)
End Function
 
Public Sub ArrRedim(lb&, ub&, Optional pres As Boolean = False) 'метод переопределения размерности массива
If pres Then ReDim Preserve arr(lb To ub) Else ReDim arr(lb To ub)
End Sub
 
'код модуля
 
Sub test()
With New Collection
    .Add New ArrClass 'создание экземпляра класса
    .Item(1).ArrRedim 1, 3
    .Item(1).ArrWrite 2, 34
    MsgBox .Item(1).ArrRead(2) '34
    .Item(1).ArrRedim 1, 5, True
    .Item(1).ArrWrite 5, -3
    MsgBox .Item(1).ArrRead(5) '-3
    .Item(1).EraseArr
End With
End Sub

Private Sub Proba()
Dim Col As New Collection
Dim Arr(3), Empt(3)
Arr(1) = 3: Arr(2) = 4: Arr(3) = 5
Col.Add ("1")
Col.Add Arr
Col.Add ("3")
Col.Remove (2)
Col.Add Empt, , 2
MsgBox Col.Item(2)(1)
End Sub

Type MyType
    i() As Integer
End Type
 
Sub dd()
Dim v(), x, y() As MyType
ReDim v(1 To 2)
ReDim x(1 To 3, 1 To 4)
v(1) = x
v(1)(1, 1) = 5
v(1)(2, 3) = 7
ReDim x(2, 2, 2)
v(2) = x
v(2)(1, 1, 1) = 9
Erase v(1)          'v(1) становится пустым массивом, v(2) остается
 
ReDim y(0 To 1)
ReDim y(0).i(1 To 2, 0 To 1, 0 To 2)
y(0).i(1, 1, 1) = 19
ReDim y(1).i(1 To 5, 0 To 1)
y(1).i(4, 1) = 119
Erase y(1).i           'y(0) остается
End Sub

Dim y() As MyType
...
ReDim y(0).i(1 To 2, 0 To 1, 0 To 2)
с учетом, что тип MyType:
Type MyType
    i() As Integer
End Type

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
END
Attribute VB_Name = "MyArr"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Explicit
 
Dim arr() As Long
 
Property Let Elem(i&, x&)
arr(i) = x
End Property
 
Property Get Elem&(i&)
Attribute Elem.VB_UserMemId = 0
'http://www.cpearson.com/excel/DefaultMember.aspx - член класса по умолчанию
Elem = arr(i)
End Property
 
Public Sub EraseArr() 'метод для стирания массива
Erase arr
End Sub
 
Public Sub RedimArr(lb&, ub&, Optional pres As Boolean = False) 'метод переопределения размерности массива
If pres Then ReDim Preserve arr(lb To ub) Else ReDim arr(lb To ub)
End Sub
 
Property Get Ubnd()
Ubnd = UBound(arr)
End Property
 
Property Get Lbnd()
Lbnd = LBound(arr)
End Property

Sub test()
Dim cl As Collection, i&, x
Set cl = New Collection
cl.Add New MyArr            'создание экземпляра класса
cl(1).RedimArr 1, 3
For i = 1 To 3
    cl(1)(i) = i * 10       'cl(1)(i) это cl(1).Elem(i), Elem - член класса по умолчанию
Next
 
cl.Add New MyArr, Before:=1 'создание еще одного экземпляра класса
cl(1).RedimArr -1, 2
For i = -1 To 2
    cl(1)(i) = i * 100
Next
GoSub print_collection
 
With cl(2)                      'добавление элемента в массив
    .RedimArr 1, .Ubnd + 1, True
    .Elem(.Ubnd) = 77           'здесь Elem приходится указывать
End With
GoSub print_collection
 
cl(1).EraseArr                  'стирание массива
cl(1).RedimArr 0, 3, True
GoSub print_collection
 
Exit Sub
 
print_collection:
    For Each x In cl
        For i = x.Lbnd To x.Ubnd
            Debug.Print x(i),
        Next
        Debug.Print
    Next
Debug.Print
Return
End Sub