Сравнить данные на двух листах и недостающие во втором перенести на третий

' Макрос проверяет список с ячейки A2 и ниже до первой пустой строки на листе "Лист1"
' на наличие в спике начиная с ячейки A2 и ниже до первой пустой строки на листе "Лист2"
' при отсутствии на листе "Лист2" значение переносится на лист "проверка"
Sub CompareColumns()
    Dim i As Long, j As Long, k As Long, s1 As String, s2 As String, b As Boolean
    Dim src As Worksheet, dst As Worksheet, chk As Worksheet
    
    Set src = ThisWorkbook.Worksheets("Лист1")
    Set dst = ThisWorkbook.Worksheets("Лист2")
    Set chk = ThisWorkbook.Worksheets("проверка")
    
    i = 2
    k = 2
    s1 = src.Cells(i, 1).Value
    Do While Not s1 = ""
        
        b = True
        j = 2
        s2 = dst.Cells(j, 1).Value
        Do While s2 <> ""
            
            If s1 = s2 Then
                b = False
                Exit Do
            End If
            
            j = j + 1
            s2 = dst.Cells(j, 1).Value
        Loop
        
        If b Then
            chk.Cells(k, 1).Value = s1
            k = k + 1
        End If
        
        i = i + 1
        s1 = src.Cells(i, 1).Value
    Loop
    
    Set src = Nothing
    Set dst = Nothing
    Set chk = Nothing
End Sub

Sub bb()
Dim a(), b(), c(), x, i&
a = Sheets("Лист2").UsedRange.Columns(1).Value
b = Sheets("Лист1").UsedRange.Columns(1).Value
ReDim c(1 To UBound(b), 1 To 1)
For Each x In b
    If IsError(Application.Match(x, a, 0)) Then i = i + 1: c(i, 1) = x
Next
Sheets("Проверка").Range("A1:A" & i).Value = c
End Sub

a = Intersect(Sheets("Лист2").UsedRange, Sheets("Лист2").Columns(3)).Value