Авторские программы, библиотеки, надстройки и шаблоны

Public Function SpecCharCls( _
        ByVal strSearchIn As String, _
        Optional ByVal blnTrim As Boolean = False, _
        Optional ByVal blnSpaseDelete As Boolean = False _
        ) As String             '=== функция: очистка строки от спец. символов
    ' strSearchIn       - исходная строка
    ' blnTrim           - флаг: удалить начальные и конечные пробелы из итоговой строки
    ' blnSpaseDelete    - флаг: удалить все пробелы
    Dim i As Integer
    Dim siMid As String * 1     ' выделенный символ
    'Dim strNew As String        ' "очищенная" строка
    'Dim siAsc As Integer        ' ANCI код символа
    'Dim siLen As Integer        ' длинна очищаемой строки
    
    SpecCharCls = strSearchIn    ' перадаём строку локальной переменной
    ' удаляем все пробелы из строки
    ' если удаляем все пробелы, лучше это сделать сразу - цикл будет короче
 
'    If blnSpaseDelete = True Then SpecCharCls = Replace(SpecCharCls, " ", "")
    If blnSpaseDelete Then SpecCharCls = Replace(SpecCharCls, " ", "") 'зачем лишние сравнения для булевой переменной
    'siLen = Len(SpecCharCls)     ' считаем длинну строки
    For i = 1 To Len(SpecCharCls)      ' перебераем все символы строки по циклу
        siMid = Mid(strSearchIn, i, 1)  ' получаем символ из строки
        'siAsc = Asc(siMid)              ' преобразовываем полученный символ в ANCII код
        If siMid < " " Then SpecCharCls = Replace(SpecCharCls, siMid, "")  ' удаляем спец.символ
    Next i
    ' удаляем пробелы в начале и в конце строки. Это лучше делать в конце цикла,
    ' т.к. в исходной строке могут быть пробелы "экранированные" спец. символами
 
'    If blnTrim = True Then SpecCharCls = Trim(SpecCharCls)
    If blnTrim Then SpecCharCls = Trim(SpecCharCls) 'зачем лишние сравнения с True?
    'SpecCharCls = SpecCharCls             ' возвращаем результат
End Function

Public Function SpecCharCls3( _
        ByVal strSearchIn As String, _
        Optional ByVal blnTrim As Boolean = False, _
        Optional ByVal blnSpaseDelete As Boolean = False _
        ) As String             '=== функция: очистка строки от спец. символов
    ' strSearchIn       - исходная строка
    ' blnTrim           - флаг: удалить начальные и конечные пробелы из итоговой строки
    ' blnSpaseDelete    - флаг: удалить все пробелы
    Dim b() As Byte, a() As Byte
    b = strSearchIn
    ReDim a(UBound(b))
    Dim i As Long, J As Long
    For i = 0 To UBound(b) Step 2
      If b(i) >= 32 - blnSpaseDelete Or b(i + 1) > 0 Then
        a(J) = b(i)
        a(J + 1) = b(i + 1)
        J = J + 2
      End If
    Next i
    ReDim Preserve a(J - 1)
    If blnTrim Then SpecCharCls3 = Trim$(a) Else SpecCharCls3 = a
End Function

Option Explicit
Private Type TSafeArray
    Dims As Integer
    Features As Integer
    ElementSize As Integer
    Locks As Integer
    Handle As Long
    DataPtr As Long
    Length As Long
    LBound As Long
End Type
 
Private Declare Sub SetCharArray Lib "msvbvm60" Alias "GetMem4" (ByRef SafeArrayPtr As Long, ByRef CharArray() As String * 1)
 
Dim sa As TSafeArray, a() As String * 1
 
Public Function SpecCharCls4(ByVal strSearchIn As String) '
SetCharArray VarPtr(sa), a
With sa
    .Dims = 1
    .Features = 128
    .ElementSize = 2
    .Locks = 0
    .Handle = 0
    .LBound = 0
    .DataPtr = StrPtr(strSearchIn)
    .Length = Len(strSearchIn)
End With
 
Dim I As Long
For I = 0 To UBound(a)
  If a(I) < " " Then a(I) = Chr$(0)
Next I
SpecCharCls4 = Trim$(Replace(strSearchIn, Chr$(0), ""))
SetCharArray 0&, a
End Function