Сравнить две таблицы

Sub Procedure_1()
    
    'Для работы кода нужно подключить библиотеку:
    'Tools - References... - Microsoft Scripting Runtime.
    
    Dim myArray() As Variant
    Dim myDictionary As New Scripting.Dictionary
    Dim myLastRow As Long
    Dim myDictionaryNumber As Long
    Dim i As Long, j As Long
    
    '1. Берём данные из первого Excel-листа в массив "myArray"
        '(в некоторых случаях быстрее работать с VBA-массивом,
        'чем с Excel-ячейками).
    '1.1. Определяем, сколько данных взять. Для этого определяем
        'последнюю строку с данными на Excel-листе. Определять
        'последнюю строку с данными буду по столбцу "A".
        'Код сделает действие как в программе "Excel",
        'если перейти в последнюю ячейку столбца "A" и
        'нажать сочетание клавиш "Ctrl + Стрелка вверх".
    myLastRow = Worksheets(1).Range("A" & Rows.Count).End(xlUp).Row
    '1.2. Берём данные в массив.
    myArray() = Worksheets(1).Range("A1:A" & myLastRow).Value
 
    '2. Берём данные из второго Excel-листа в словарь "myDictionary"
        '(в некоторых случаях быстрее работать со словарём, чем с VBA-массивом).
    '2.1. Определяем, сколько данных взять.
    myLastRow = Worksheets(2).Range("A" & Rows.Count).End(xlUp).Row
    '2.2. Берём данные в словарь.
        'В "Item" формируем порядковые номера, которые понадобятся, чтобы
        'брать данные из Excel-листа из нужных строк.
    For i = 1 To myLastRow Step 1
        myDictionary.Add Key:=Worksheets(2).Cells(i, "A").Value, Item:=i
    Next i
    
    '3. Дальше переменную "myLastRow" буду использовать, чтобы
        'заносить данные на третий Excel-лист.
    myLastRow = 2
    
    '4. Проходимся по всем элементам массива "myArray" и смотрим,
        'встречаются ли в словаре такие же данные.
    '"Ubound" - в данном случае это количество строк в VBA-массиве.
    For i = 1 To UBound(myArray) Step 1
        'Смотрим, есть ли такие же данные в словаре.
        If myDictionary.Exists(Key:=myArray(i, 1)) = True Then
        
            'Для удобства написания кода, берём порядковый номер
                'в переменную.
            myDictionaryNumber = myDictionary.Item(Key:=myArray(i, 1))
        
            'Если есть, то переносим данные на третий Excel-лист.
            
                Worksheets(3).Range("A" & myLastRow & ":D" & myLastRow).Value = _
                    Worksheets(1).Range("A" & i & ":D" & i).Value
            
                Worksheets(3).Range("E" & myLastRow & ":G" & myLastRow).Value = _
                    Worksheets(2).Range("B" & myDictionaryNumber & ":D" & myDictionaryNumber).Value
                
            'Переход к следующей строке на третьем листе.
            myLastRow = myLastRow + 1
            
        End If
    Next i
    
End Sub

Sub Procedure_1()
    
    'Для работы кода нужно подключить библиотеку:
    'Tools - References... - Microsoft Scripting Runtime.
    
    Dim myArray() As Variant
    Dim myDictionary As New Scripting.Dictionary
    Dim myLastRow As Long
    Dim myDictionaryNumber As Long
    Dim i As Long, j As Long
    
    '1. Берём данные из первого Excel-листа в массив "myArray"
        '(в некоторых случаях быстрее работать с VBA-массивом,
        'чем с Excel-ячейками).
    '1.1. Определяем, сколько данных взять. Для этого определяем
        'последнюю строку с данными на Excel-листе. Определять
        'последнюю строку с данными буду по столбцу "A".
        'Код сделает действие как в программе "Excel",
        'если перейти в последнюю ячейку столбца "A" и
        'нажать сочетание клавиш "Ctrl + Стрелка вверх".
    myLastRow = Worksheets(1).Range("A" & Rows.Count).End(xlUp).Row
    '1.2. Берём данные в массив.
    myArray() = Worksheets(1).Range("A1:A" & myLastRow).Value
 
    '2. Берём данные из второго Excel-листа в словарь "myDictionary"
        '(в некоторых случаях быстрее работать со словарём, чем с VBA-массивом).
    '2.1. Определяем, сколько данных взять.
    myLastRow = Worksheets(2).Range("A" & Rows.Count).End(xlUp).Row
    '2.2. Берём данные в словарь.
        'В "Item" формируем порядковые номера, которые понадобятся, чтобы
        'брать данные из Excel-листа из нужных строк.
    For i = 1 To myLastRow Step 1
        myDictionary.Add Key:=Worksheets(2).Cells(i, "A").Value, Item:=i
    Next i
    
    '3. Дальше переменную "myLastRow" буду использовать, чтобы
        'заносить данные на третий Excel-лист.
    myLastRow = 1
    
    '4. Проходимся по всем элементам массива "myArray" и смотрим,
        'встречаются ли в словаре такие же данные.
    '"Ubound" - в данном случае это количество строк в VBA-массиве.
    For i = 1 To UBound(myArray) Step 1
    
        '4.1. Переносим данные из первого листа на третий лист.
        Worksheets(3).Range("A" & myLastRow & ":D" & myLastRow).Value = _
            Worksheets(1).Range("A" & i & ":D" & i).Value
            
        '4.2. Смотрим, есть ли такие же данные в словаре.
        If myDictionary.Exists(Key:=myArray(i, 1)) = True Then
        
            '4.2. Для удобства написания кода, берём порядковый номер
                'в переменную.
            myDictionaryNumber = myDictionary.Item(Key:=myArray(i, 1))
        
            '4.3. Если есть, то переносим данные на третий Excel-лист.
                Worksheets(3).Range("E" & myLastRow & ":G" & myLastRow).Value = _
                    Worksheets(2).Range("B" & myDictionaryNumber & ":D" & myDictionaryNumber).Value
                    
            '4.4. Удаляем обработанный элемент словаря.
                'Затем оставшиеся элементы просто перенесём на третий лист.
            myDictionary.Remove Key:=myArray(i, 1)
                
        End If
                
        '5. Переход к следующей строке на третьем листе.
        myLastRow = myLastRow + 1
            
    Next i
    
    '6. Переносим данные из словаря.
    For i = 0 To myDictionary.Count - 1 Step 1
        
        '6.1. Для удобства написания кода, берём порядковый номер
            'в переменную.
        myDictionaryNumber = myDictionary.Items(i)
        
        '6.2. Переносим данные.
        'Обратите внимание, что доступ по порядковому номеру можно получить
            'только через объект "Keys", а не "Key".
        Worksheets(3).Range("A" & myLastRow).Value = myDictionary.Keys(i)
        
        'Обратите внимание, что доступ по порядковому номеру можно получить
            'только через объект "Items", а не "Item".
        Worksheets(3).Range("E" & myLastRow & ":G" & myLastRow).Value = _
            Worksheets(2).Range("B" & myDictionaryNumber & ":D" & myDictionaryNumber).Value
            
        '6.3. Переход к следующей строке.
        myLastRow = myLastRow + 1
        
    Next i
    
End Sub