Word: заменить текст в названиях на ссылки

Sub Макрос3()
 
    Dim rngVirtualBookmark As Word.Range
    Dim myFind As Word.Find
    
    
    '1. Для ускорения работы кода, можно перейти в режим "Черновик"
        'и можно отключить проверку правописания с помощью кода.
        'Затем всё это с помощью кода включить.
    
    
    '2. Создаём виртуальную закладку, с помощью которой
        'будем перемещаться по документу в поисках искомого.
        '- 1, т.к. нельзя вставить закладку за последний символ абзаца
    Set rngVirtualBookmark = _
        ActiveDocument.Range(Start:=ActiveDocument.Range.End - 1, End:=ActiveDocument.Range.End - 1)
    
    
    '3. Создаём объект поиска.
    Set myFind = rngVirtualBookmark.Find
    
    
    '4. Настраиваем объект поиска.
    '4.1. Ищем текст: Таблица #.#
    'Шаблон поиска читается так:
    'Найти слово "Таблица" с пробелом, одну или несколько
        'любых цифр, точку, одну или несколько цифр и пробел.
    myFind.Text = "Таблица [0-9]@.[0-9]@ "
 
     '4.2. Флажок "Подстановочные знаки".
    myFind.MatchWildcards = True
    
     '4.3. Двигаемся с конца документа в начало.
        'Так удобнее будет передвигать виртуальную закладку,
        'т.к. после вставки названия будет сложно передвинуть
        'закладку в нужное место вперёд.
    myFind.Forward = False
        
    
    '5. Продолжать поиск, пока находится искомое.
    Do While myFind.Execute = True
        
        'Если будет найдено искомое, то закладка "rngVirtualBookmark"
            'окружит найденный текст.
        '6. Удаляем найденный текст.
        'Закладка "rngVirtualBookmark" превратится в точку вставки.
        rngVirtualBookmark.Delete
        
        
        '7. Вставляем надпись. Надпись встанет после закладки "rngVirtualBookmark"
            
        'Соответствие Word-окну "Название" и просто описание некоторых параметров
            'команды "InsertCaption":
            'Label - "подпись".
            'TitleAutoText - вставка автотекста после названия.
            'Title - вставка текста после названия.
            'Position - "положение".
            'ExcludeLabel - флажок "Исключить подпись из названия".
        'Сначала вставим пробел, т.к. я и пробел удалю.
        rngVirtualBookmark.InsertAfter Text:=Chr(32)
        'Перемещаем закладку влево от пробела.
        rngVirtualBookmark.Collapse Direction:=wdCollapseStart
        'Вставка названия.
        rngVirtualBookmark.InsertCaption Label:="Таблица", ExcludeLabel:=False
    
    Loop
    
End Sub