Форум программистов, компьютерный форум, киберфорум
Наши страницы

VBScript/JScript/WSH/WMI/HTA

Войти
Регистрация
Восстановить пароль
 
Рейтинг: Рейтинг темы: голосов - 9, средняя оценка - 4.56
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
#1

Мониторинг процесса по расширению - VBScript/JScript

24.02.2014, 01:29. Просмотров 1164. Ответов 13
Метки нет (Все метки)

Уважаемые форумчане помогите чайнику. Нужен скрипт постоянно отслеживающий хранитель экрана. При появлении процесса хранителя запустить скрипт 1 , при завершении процесса запустить скрипт 2.
Проблема в том что хранители экрана могут быть разные. Хотелось бы отслеживать процесс по расширению
scr.
0
Надоела реклама? Зарегистрируйтесь и она исчезнет полностью.
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
24.02.2014, 01:29
Здравствуйте! Я подобрал для вас темы с ответами на вопрос Мониторинг процесса по расширению (VBScript/JScript):

VBS Запуск RPD-клиента, мониторинг его процесса и очистка его истории подключений по его завершении - VBScript/JScript
Здравствуйте уважаемые форумчане. С VBS не знаком совершенно, просьба помочь реализовать следующий скрипт: 1. Запуск RDP-клиента...

Запрет записи файлов в папку, по расширению - Администрирование Windows
Добрый день. Прошу подсказать скрипт или bat выполняющий : запрет записи файлов в указанную папку с определенным расширением, ОС Win 7.

Мониторинг сервера (удаленно) - Администрирование Windows
Задача: вывести информацию о сервере (характеристики, состояние, место на жестком диске и тд) какие есть самый простые и оптимальные...

Мониторинг канала связи - Администрирование Windows
Кто-нибудь знает программы для мониторинга каналов связи? 1. Должна быть бесплатной. 2. На Windows 3. The Dude, Total network, total...

Мониторинг файлов по дате создания и расширению - CMD/BAT
Здравствуйте, есть задача мониторить папку на предмет наличия файлов с расширениями, допустим .txt, .doc, .jpg которые залежались дольше 5...

Мониторинг активности процесса - Delphi
Здравствуйте. Надо написать агента, чтобы он отслеживал активность определённого процесса и если он какое-то время не активен агент бы его...

13
Dmitrii
2596 / 529 / 104
Регистрация: 21.03.2012
Сообщений: 1,023
26.02.2014, 00:13 #2
Лучший ответ Сообщение было отмечено автором темы, экспертом или модератором как ответ
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Dim objWMI, objCollection, objEvent
Dim strComputer, strProcName
strComputer = "."
Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set objCollection = objWMI.ExecNotificationQuery("SELECT * FROM __InstanceOperationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'")
Do
    Set objEvent = objCollection.NextEvent
    strProcName = objEvent.TargetInstance.Name
    If LCase(Right(strProcName, 4)) = ".scr" Then
        Select Case objEvent.Path_.Class
            Case "__InstanceCreationEvent"
                'какие-то действия, выполняемые при запуске хранителя экрана
            Case "__InstanceDeletionEvent"
                'какие-то действия, выполняемые при прекращении работы хранителя экрана
        End Select
    End If
Loop
Set objEvent = Nothing: Set objCollection = Nothing: Set objWMI = Nothing
WScript.Quit 0
Данный пример содержит бесконечный цикл. Чтобы не снимать сценарий вручную, предусмотрите какое-либо условие выхода из этого цикла.
2
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
28.02.2014, 02:13  [ТС] #3
Огромное Спасибо буду пробовать.

Добавлено через 4 часа 59 минут
Да работает но есть проблема включился скринсейвер начала выполнятся (задача 1).

Прошло 10 мин управление питанием выключило монитор и судя по всему убило скринсейвер.

Пользователя за компом нет должна выполнятся (задача 1) а выполняется (задача 2 )
0
Dmitrii
2596 / 529 / 104
Регистрация: 21.03.2012
Сообщений: 1,023
01.03.2014, 19:53 #4
Roman1978, либо убирайте отключение монитора, либо ищите другой критерий управления задачами.
1
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
01.03.2014, 19:57  [ТС] #5
То есть отключение монитора скриптом отследить невозможно?
0
Dmitrii
2596 / 529 / 104
Регистрация: 21.03.2012
Сообщений: 1,023
02.03.2014, 18:02 #6
Лучший ответ Сообщение было отмечено автором темы, экспертом или модератором как ответ
В теории - возможно.
Например, у классов CIM_DesktopMonitor и Win32_DesktopMonitor есть свойство Availability, которое (судя по его описанию) позволяет получить нужную информацию. Однако у меня, например (на XP Home), это свойство всегда возвращает только одно значение - 0x3 (Running or Full Power).
Впрочем, можете провести эксперимент у себя с помощью подобного сценария:
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Set objWMI = GetObject("winmgmts:\\.\root\CIMV2") 
Set objFS = CreateObject("Scripting.FileSystemObject")
Set objCollection = objWMI.ExecNotificationQuery("SELECT * FROM __InstanceOperationEvent " _
        & "WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'")
Do
    Set objItem = objCollection.NextEvent
    strProcess = LCase(objItem.TargetInstance.Name)
    If Right(strProcess, 4) = ".scr" Then
        Select Case objItem.Path_.Class
            Case "__InstanceCreationEvent"
                Set objFile = objFS.CreateTextFile("C:\Temp\Create_" & Left(strProcess, Len (strProcess) - 4) & ".txt", True)
                objFile.Close
            Case "__InstanceDeletionEvent"
                Set objFile = objFS.CreateTextFile("C:\Temp\Delete_" & Left(strProcess, Len (strProcess) - 4) & ".txt", True)
                Set objCollection2 = objWMI.ExecQuery("SELECT Availability FROM Win32_DesktopMonitor")
                For Each objItem In objCollection2 
                    objFile.WriteLine Now & vbNewLine & objItem.Availability
                Next
                objFile.Close
                Exit Do
        End Select
    End If
Loop
WScript.Quit 0
1
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
05.03.2014, 23:23  [ТС] #7
Огромное спасибо! Но еще раз напомню что я чайник ).
Можно как то так ?
1)скринсейвер запущен ИЛИ монитор выключен: Выполнить задача1
2)скринсейвер не запущен И монитор включен: Выполнить задача2
Еще раз спасибо за ответы.
0
Dmitrii
2596 / 529 / 104
Регистрация: 21.03.2012
Сообщений: 1,023
06.03.2014, 20:21 #8
Цитата Сообщение от Roman1978 Посмотреть сообщение
Можно как то так ?
Чтобы ответить на этот вопрос, нужно знать результат работы предложенного тестового сценария, а именно: какое значение вернёт свойство Availability класса Win32_DesktopMonitor.
Проверьте у себя.
1
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
06.03.2014, 22:42  [ТС] #9
При отключении монитора в папке с:\temp\ было создано 2 файла:
Create_scrnsave.txt- пустой
Delete_scrnsave.txt - с текстом (06.03.2014 21:34:39
8)

Windows 8.0 x 64
0
Dmitrii
2596 / 529 / 104
Регистрация: 21.03.2012
Сообщений: 1,023
09.03.2014, 15:14 #10
Roman1978, нужна ещё одна проба. Проверьте у себя работу приведённого ниже сценария-заготовки при исходных условиях (включается хранитель экрана, затем отключается монитор) и выложите содержимое создаваемого сценарием файла DISPLAY.TXT.
Кликните здесь для просмотра всего текста
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Dim objWMI, objCollection, objCollection2, objItem
Dim objFS, objFile, strProcess, intTemp
 
Set objFS = CreateObject("Scripting.FileSystemObject")
Set objWMI = GetObject("winmgmts:\\.\root\CIMV2")
Set objCollection = objWMI.ExecNotificationQuery("SELECT * FROM __InstanceOperationEvent " _
        & "WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'")
Do
    Set objItem = objCollection.NextEvent
    strProcess = LCase(objItem.TargetInstance.Name)
    If Right(strProcess, 4) = ".scr" Then
        Select Case objItem.Path_.Class
            Case "__InstanceCreationEvent"
                Set objFile = objFS.OpenTextFile("C:\Temp\Display.txt", 8, True)
                Set objCollection2 = objWMI.ExecQuery("SELECT Availability FROM Win32_DesktopMonitor")
                For Each objItem In objCollection2
                    objFile.WriteLine Now & " = Win32_Process,CreationEvent;" & objItem.Availability
                Next
                objFile.Close
            Case "__InstanceDeletionEvent"
                Set objFile = objFS.OpenTextFile("C:\Temp\Display.txt", 8, True)
                Set objCollection2 = objWMI.ExecQuery("SELECT Availability FROM Win32_DesktopMonitor")
                For Each objItem In objCollection2
                    intTemp = objItem.Availability: Exit For
                Next
                If intTemp = 3 Then
                    objFile.WriteLine Now & " = Win32_Process,DeletionEvent;3"
                    objFile.Close
                    Exit Do
                Else
                    objFile.WriteLine Now & " = Win32_Process,DeletionEvent;" & intTemp & ";ExitDo"
                    objFile.Close
                    Exit Do
                End If
        End Select
    End If
Loop
Set objCollection2 = Nothing
If intTemp <> 3 Then
    Set objCollection = objWMI.ExecNotificationQuery("SELECT * FROM __InstanceModificationEvent " _
                    & "WITHIN 1 WHERE TargetInstance ISA 'Win32_DesktopMonitor'")
    Do
        Set objItem = objCollection.NextEvent
        Set objFile = objFS.OpenTextFile("C:\Temp\Display.txt", 8, True)
        objFile.WriteLine Now & " = Win32_DesktopMonitor,ModificationEvent;" & objItem.TargetInstance.Availability
        objFile.Close
        Exit Do
    Loop
End If
Set objFile = Nothing: Set objFS = Nothing
Set objItem = Nothing: Set objCollection = Nothing: Set objWMI = Nothing
WScript.Quit 0
1
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
10.03.2014, 20:21  [ТС] #11
Содержимое Файла
10.03.2014 18:10:15 = Win32_Process,CreationEvent;8
10.03.2014 18:10:19 = Win32_Process,DeletionEvent;8;ExitDo
Скринсейвер настроен на срабатывание через 1 мин простоя. Отключение монитора через 3 мин простоя
0
Dmitrii
2596 / 529 / 104
Регистрация: 21.03.2012
Сообщений: 1,023
11.03.2014, 22:29 #12
Roman1978, похоже, что пока я не смогу Вам предложить полноценного решения обсуждаемой задачи. Рекомендация остаётся прежней - отказаться от отключения монитора.
Однако странное значение возвращает у Вас свойство Availability (8 - Off Line; как будто монитор отсутствует вообще).
Каким будет результат работы сценария:
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
Dim objWMI, objCollection, objItem, strList
Set objWMI = GetObject("winmgmts:\\.\root\CIMV2")
Set objCollection = objWMI.ExecQuery("SELECT * FROM Win32_DesktopMonitor")
For Each objItem In objCollection
    strList = strList & objItem.Name & ";" & objItem.Availability & ";" & TypeName(objItem.PowerManagementCapabilities) & vbNewLine
Next
strList = strList & "------" & vbNewLine
Set objCollection = objWMI.ExecQuery("SELECT * FROM CIM_FlatPanel")
For Each objItem In objCollection
    strList = strList & objItem.Name & ";" & objItem.Availability & ";" & TypeName(objItem.PowerManagementCapabilities) & vbNewLine
Next
WScript.Echo strList
WScript.Quit 0
1
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
12.03.2014, 22:31  [ТС] #13
Пока не могу дать результатов теста скрипта. Хочу сначала проверить пред идущий скрипт на нескольких машинах и выложить сравнительные результаты последнего и пред идущего скрипта. Возможно свойство Availability 8 - Off Line связано с нестандартным контролером монитора на не совсем современном ноутбуке.
Еще раз спасибо за активное участие в решении моей проблемы.
0
Roman1978
1 / 1 / 0
Регистрация: 24.02.2014
Сообщений: 18
15.03.2014, 21:24  [ТС] #14
На windows 7 x32/x64
Display.txt (10.03.2014 18:10:15 = Win32_Process,CreationEvent;3
10.03.2014 18:10:19 = Win32_Process,DeletionEvent;3;ExitDo)

На windows 8/8.1 x32/x64
Display.txt (10.03.2014 18:10:15 = Win32_Process,CreationEvent;8
10.03.2014 18:10:19 = Win32_Process,DeletionEvent;8;ExitDo)
Пред идущий скрипт соответственно тоже выдал (3) на win7 и (8) на win 8/8.1 тест проходил на 3 разных ноутбуках и 2 стационарных системных блоках. Железо не виновато)
0
15.03.2014, 21:24
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
15.03.2014, 21:24
Привет! Вот еще темы с ответами:

мониторинг ресурсов процесса - Perl
Здравствуйте. Задача стоит следующая: имея id процесса вытягивать и собирать в бд статистику по нему т.е. допустим средняя загрузка цп...

Мониторинг запуска процесса - Программирование драйверов
Добрый день уважаемые программисты. Необходимо написать драйвер, который будет по .exe блокировать запуск приложений(что то типа, черного...

Мониторинг DLL процесса - Программирование драйверов
подскажите с помощью каких функций можно отследить загрузку сторонних DLL в мой процесс?

Мониторинг состояния созданного процесса - C++ WinAPI
подскажите, как реализовать... создаю процесс ZeroMemory(&amp;si, sizeof(si)); si.cb = sizeof(si); ZeroMemory(&amp;pi,...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
14
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2017, vBulletin Solutions, Inc.
Рейтинг@Mail.ru