В локальной сети статические IP адреса, каким образом можно узнать какие IP заняты?

Dim objWShell, objExec, objOutStream
Dim objDictComputers, strKey, strTemp
Dim objFS, objFile, strList, strLog
 
strLog = "IP.log"
Set objDictComputers = CreateObject("Scripting.Dictionary")
objDictComputers.CompareMode = 1
Call Computers_List(objDictComputers)
Set objWShell = CreateObject("WScript.Shell")
For Each strKey In objDictComputers.Keys
    strTemp = vbNullString
    Set objExec = objWShell.Exec("ping -n 1 -w 130 " & strKey)
    Set objOutStream = objExec.StdOut
    While Not objOutStream.AtEndOfStream
        strTemp = strTemp & objOutStream.ReadLine
    Wend
    If InStr(strTemp, "]") > 0 Then
        strTemp = Split(Split(strTemp, "[")(1), "]")(0)
    Else
        strTemp = "адрес не определён"
    End If
    strList = strList & strKey & " = " & strTemp & vbNewLine
    WScript.Echo strKey & " = " & strTemp
Next
Set objWShell = Nothing
Set objDictComputers = Nothing
Set objFS = CreateObject("Scripting.FileSystemObject")
Set objFile = objFS.CreateTextFile(objFS.BuildPath(objFS.GetParentFolderName(WScript.ScriptFullName), strLog), True)
objFile.Write strList
objFile.Close
Set objFile = Nothing
Set objFS = Nothing
WScript.Quit 0
 
'=====
 
Function Computers_List(objDictionary)
Dim objRoot, strDomain
Dim objConnection, objCommand, objRSet, strCommandText
Const ADS_SCOPE_SUBTREE = 2
Const ADS_UF_ACCOUNTDISABLE = 2
 
Set objRoot = GetObject("LDAP://RootDSE")
strDomain = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand = CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection
strCommandText = "SELECT cn,userAccountControl FROM 'LDAP://" & strDomain & "' WHERE objectCategory='Computer'"
objCommand.CommandText = strCommandText
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Timeout") = 30
objCommand.Properties("Sort On") = "cn"
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRSet = objCommand.Execute
objRSet.MoveFirst
Do
    If Not CBool(objRSet.Fields("userAccountControl").Value And ADS_UF_ACCOUNTDISABLE) Then
        objDictionary.Add objRSet.Fields("cn").Value, vbNullString
    End If
    objRSet.MoveNext
Loop While Not objRSet.EOF
Set objRSet = Nothing
Set objCommand = Nothing
objConnection.Close
Set objConnection = Nothing
End Function