Драйвер для ик-передатчика 940nm (для мощного лазера-светодиода), управляемый Arduino

byte Lshift[] = {3,3,2,2};
uint32_t UartFreq = 0; //Переменная для задания нужной частоты
uint32_t compare = OCR1A;     //OCR1A - Регистры сравнения A выхода таймера/счетчика1
uint16_t divider = 1;         //переменная коэфф. деления прескалера
float freqency;
int set_a = 0;
const int BTN_PIN = 10;
const int IR_PIN = 9;  // Пин передатчика
uint8_t DATA = 0b10101010;
 
void setup() {
  Serial.begin(38400);
  Serial.setTimeout(10);     // Устанавливает (миллисекунды) таймаут ожидания приёма данных для следующих ниже функций. По умолчанию равен 1000 мс (1 секунда).
  pinMode (IR_PIN, OUTPUT);       // выход генератора
  pinMode (BTN_PIN, INPUT_PULLUP);
  setFrequency(38000);
  //start_gen();
}
 
void loop() {
 
  if (Serial.available() > 0) {
    char cmd = Serial.read();
    
    if (cmd == 'F' || cmd == 'f') {
      uint32_t UartFreq = Serial.parseInt();
      if (UartFreq > 0) {
        setFrequency(UartFreq);
        //Serial.print("Установка частоты генератора");
      }
    }
  }
 
  if (digitalRead(BTN_PIN) == HIGH) {
    sendByte(DATA);
    //Serial.print("Отправлен пакет, f: "); Serial.println(freqency);
    delay(150);
  }
 
}
// =======================================================================================
void stop_gen() {
  TCCR1A=0;  // Регистр управления А таймера/счетчика1
  TCCR1B=0;   // Регистр управления B таймера/счетчика1
}
 
void start_gen() {
  TCCR1A = 1 << COM1A0;              // Регистр управления А таймера/счетчика1
  TCCR1B = set_a | ( 1 << WGM12 );   // Регистр управления B таймера/счетчика1
}
 
void setFrequency(uint32_t Freq) {
 
  if (Freq <= 130 || Freq > 100000) {             //Проверяем допустимый диапазон значений частоты
    Serial.println("Ошибка: частота должна быть 130 Гц - 100 kHz");
    return; 
  }
  compare = (F_CPU / Freq / 2 / divider); //вычисляем нужное значение OCR
  set_a = 0;
  for (byte i = 0; i < 4; i++) {
    if (compare > 65536) {
      divider <<= Lshift[i];
      compare = F_CPU / Freq /2 /divider;
    } else {
      set_a = i + 1;
      //TCCR1B = (i + 1) | ( 1 << WGM12 );
      break;
    }
  }
  OCR1A = compare-1;
  //TCCR1A = 1 << COM1A0;
 
  freqency = F_CPU / 2 / (OCR1A + 1) / divider;
  if (freqency < 10000) {
    Serial.print("Частота на выходе= ");
    Serial.print(freqency, 0);
    Serial.println(" Hz ");
    Serial.print("OCR1A= ");
    Serial.println(OCR1A);
    Serial.print(" Вы ввели частоту= ");
    Serial.println(Freq);
  }
  if (freqency >= 10000) {
    Serial.print("Частота на выходе= ");
    Serial.print(freqency / 1000, 3);
    Serial.println(" kHz");
    Serial.print("OCR1A= ");
    Serial.println(OCR1A);
    Serial.print(" Вы ввели частоту= ");
    Serial.println(Freq);
 
  }
}
 
void sendBit(bool bitValue) {
  start_gen();
  delayMicroseconds(bitValue ? 1000 : 500); // например для 1 - 1000мкс для 0 - 600 мкс
  stop_gen();
  delayMicroseconds(500);
}
 
void sendByte (uint8_t data) {
  start_gen();
  delayMicroseconds(3000);
  stop_gen();
  delayMicroseconds(1000);
  //первый бит синхронизация
  for(int i = 0; i < 8; i++) {
    sendBit(data & 0x80);//берем старший бит из байта - первый 
    //если будет sendBit(data) - то это передается весь байт сразу
    data <<= 1;//сдвигаем байт влево на 1 бит чтобы на след итерации 
    //старший бит был следующий
  }
  start_gen();
  delayMicroseconds(2000);
  stop_gen();
}

const int RECV_PIN = 3;
const int LED_PIN = 13;
uint8_t DATA = 0b10101010;
 
uint8_t readByte() {
  uint8_t value = 0;//значение для результата
  // пока пин high ждем low
  while (digitalRead(RECV_PIN) == HIGH);
  unsigned long t = micros();  //создадим переменную t для замера low 
  while (digitalRead(RECV_PIN) == LOW);
  if (micros() - t < 2500) return 0;  // если сигнал стартового low < 2500 мкс возрващаем 0
 
 
 
  delayMicroseconds(1000);  // пауза после синхр
 
  for (int i = 0; i < 8; i++) {
    // ждём LOW
    while (digitalRead(RECV_PIN) == HIGH);
 
    t = micros();  //Засекаем время начала LOW
    while (digitalRead(RECV_PIN) == LOW);
 
    unsigned long pulse = micros() - t;  //Вычисляем длительность LOW в микросекундах
    value <<= 1;
 
    if (pulse > 750) value |= 1;  //больше 450мкс следует бит == 1 побитовое присваивание
  }
 
  return value;
}
 
void setup() {
  pinMode(RECV_PIN, INPUT);
  pinMode(LED_PIN, OUTPUT);
  Serial.begin(38400);
}
 
void loop() {
  if (digitalRead(RECV_PIN) == LOW) {
    uint8_t data = readByte();
    Serial.print("Принято: ");
    Serial.println(data, BIN);  //выводим в бинарном виде
    if (data == DATA) {
      digitalWrite(LED_PIN, HIGH);
      delay(100);
      digitalWrite(LED_PIN, LOW);
    } else {
      Serial.println("ошибка - не верно");
    }
  }
}