Ввести слово и вывести первый символ, всю строку и последний символ

mov ah,02h
mov dl,10
int 21h
 
mov ah,02h
mov dl,13
int 21h
 
mov AH,09h ; vivod sms
lea dx,msg
int 21h 
    
mov ah,0ah ;vvod 
lea dx,str1
int 21h
 
mov ah,02h
mov dl,10
int 21h
 
mov ah,02h
mov dl,13
int 21h
 
mov ah,02h     ;vivod 1
mov dl,str1[2]
int 21h 
 
mov ah,02h
mov dl,10
int 21h
mov ah,02h
mov dl,13
int 21h
 
mov ah,09h;vivod stroki
lea dx,str1
int 21h
 
mov ah,02h
mov dl,10
int 21
 
mov ah,02h
mov dl,13
int 21h
 
cld
mov ax,size str1
mov a,ax
lea di,str1
add di,a
sub di,1
mov ah,02h         ;vivod poslednego
mov dl,str1[di]
int 21h

;-------------------------------------------------------------------------------
 
       .model tiny
 
DOS_PRINT_CHAR          equ     2
DOS_PRINT_STRING        equ     9
DOS_INPUT_STRING        equ     0Ah
DOS_EXIT                equ     4C00h
 
MAX_STRING_SIZE         equ     80
 
crlf                    equ     13, 10
 
       .data
 
sInput                  db      crlf, "Введите строку   : ",    '$'
s1stCh                  db      crlf, "Первый символ    : ",    '$'
sAllStr                 db      crlf, "Вся строка       : ",    '$'
sFinCh                  db      crlf, "Последний символ : ",    '$'
sError                  db      crlf, "ОШИБКА: пустая строка.", '$'
 
max                     db      MAX_STRING_SIZE + 1
strlen                  db      ?
string                  db      MAX_STRING_SIZE + 1 dup (?)
 
       .code
        org 100h
start:
 
;----- Ввод строки
 
        lea     dx, sInput              ; Приглашаем ввести строку
        call    puts
 
        mov     ah, DOS_INPUT_STRING    ; Ввод строки с клавиатуры
        lea     dx, max
        int     21h
 
;----- Проверка на пустую строку
 
        xor     bx, bx
        mov     bl, strlen              ; bl <- длина введённой строки
 
        test    bl, bl                  ; Строка пустая?
        jnz     @@not_empty             ; Если нет, идём дальше
 
        lea     dx, sError              ; Иначе адресуем строку с ошибкой...
        call    puts
        jmp     short exit              ; ...и выходим
 
;----- Вывод первого символа
 
@@not_empty:
        lea     dx, s1stCh              ; Выводим сообщение "первый символ:"
        call    puts
        mov     dl, [string]            ; dl <- первый символ строки
        call    putch                   ; Выводим его на экран
 
;----- Вывод всей строки
 
        add     bx, offset string       ; bx <- длина строки + её начало
        mov     dl, [bx - 1]            ; dl <- последний символ строки
        push    dx                      ; Сохраняем его на потом
        mov     [bx], byte ptr '$'      ; Ставим вместо него "конец строки"
 
        lea     dx, sAllStr             ; Выводим сообщение "вся строка:"
        call    puts
        lea     dx, string              ; Выводим на экран введённую строку
        call    puts
 
;----- Вывод последнего символа
 
        lea     dx, sFinCh              ; Выводим сообшение "последний символ:"
        call    puts
        pop     dx                      ; Достаём сохранённый символ из стека
        call    putch                   ; Выводим его на экран
 
;----- Выход из программы
 
exit:
        mov     ax, DOS_EXIT
        int     21h
 
;///////////////////////////////////////////////////////////////////////////////
 
puts    proc                            ; Вывод на экран строки из DX
        mov     ah, DOS_PRINT_STRING
        int     21h
        ret
puts    endp
 
putch   proc                            ; Вывод на экран символа из DL
        mov     ah, DOS_PRINT_CHAR
        int     21h
        ret
putch   endp
 
;///////////////////////////////////////////////////////////////////////////////
 
        end     start