Ошибка в результатах при подсчете суммы n-1 членов прогрессии

.model small
.data
str1 db 13,10,'Программа вычисляет сумму арифметической прогрессии'
     db 13,10,'Введите шаг прогрессии(d): $'
str2 db 13,10,'Введите начальное число прогрессии(a1): $'
a1 dd 0                  ;начальный элемент прогрессии
d  dd 0                  ;шаг прогрессии
n  dd 1                  ;минимальное количество слагаемых для переполнения
str3 db 13,10,'Минимальное число слагаемых для переполнения: '
d1   db 10 dup (' '),'$'
str5 db 13,10,'Сумма n-1 первых членов прогрессии равна: '
d2   db 10 dup (' '),'$'
buf  db 11, 13 dup(0)    ;принимает строку, введенную с клавиатуры
 
 
.stack 256
.code
start:
.386
  mov ax,@data           ;настраиваем сегментные регистры
  mov ds,ax
  mov es,ax
vvd: mov dx, offset str1 ;выводим приглашение
 call InputNumber        ;вводим шаг прогрессии
  mov d,eax              ;сохраняем d
  test eax,eax           ;если введено число меньше 1, то попросим ввести снова
 jng vvd
vva1: mov dx, offset str2;выводим приглашение
 call InputNumber        ;вводим начальное число прогрессии
  mov a1,eax             ;сохраняем d
  test eax,eax           ;если введено число меньше 1, то попросим ввести снова
 jng vva1
 
  mov ebx,0              ;сумма (sum:=0)
  mov ecx,1              ;n:=1
lp1: 
  mov eax,ecx            ;передаем n в eax
  dec eax                ;n-1
  mov edx,d
  mul edx                ;(n-1)*d
  mov edx,a1
  add eax,edx            ;(n-1)*d+a1
  inc ecx   ;n:=n+1
  add ebx,eax            ;sum:=sum+a1+(n-1)*d;
 jns lp1                 ;Если не произошло переполнения в бит знака (как в паскале), то продолжаем
                         ;Если jns заменить на jnc, то вместо знакового переполнения будет отслеживаться
                         ;переполнение в признак переноса, т.е. сумма будет представлена как беззнаковое
                         ;число (2-й режим)
  dec ecx                ;поскольку приращение n перед проверкой на переполнение, то после цикла в ecx буде на 1 больше, чем надо. Вот и корректируем его.
  mov n,ecx              ;сохраняем минимальное количество слагаемых для переполнения
  mov eax,ecx            ;преобразовываем минимальное количество слагаемых для переполнения в текст
  mov edi,offset d1
 call printdec32
  mov dx,offset str3     ;выводим результат на экран
  mov ah,9
  int 21h
  mov esi,n              ;кол-во слагаемых
  mov ebx,0              ;сумма (sum:=0)
  mov ecx,1              ;n:=1
lp2:
  mov eax,ecx            ;передаем n в eax
  dec eax                ;n-1
  mov edx,d
  mul edx                ;(n-1)*d
  mov edx,a1
  add eax,edx            ;(n-1)*d+a1
  add ebx,eax            ;sum:=sum+a1+(n-1)*d
  inc ecx                ;n:=n+1
  cmp ecx,esi  ;n<=n1
 jle lp2                 ;если да, то продолжаем суммировать
  mov eax,ebx            ;преобразовываем сумму в текст
  mov edi,offset d2
 call printdec32
  mov dx,offset str5     ;выводим результат на экран
  mov ah,9
  int 21h
  
  mov ah,1               ;ожидаем нажатия любой клавиши
  int 21h
 
ex:
  mov ax,4c00h           ;выход из программы
  int 21h
 
 
str2dw proc
                         ;Преобразование строки в число
                         ;на входе ds:si ссылается на ASCIIZ строку, которую нужно преобразовать
                         ; на выходе в eax - число.
  push edx
  push esi
  xor edx,edx            ;сумма
@lp1: 
  xor eax,eax
  lodsb                  ;берем символ
  test al,al             ;если это нулевой байт, то заканчиваем
  jz @ex
  cmp al,'9'             ;Если это не цифра, то пропускаем
  jnbe @lp1
  cmp al,'0'             ;Если это не цифра, то пропускаем
  jb @lp1
  sub eax,'0'            ;получаем цифровое значение
  shl edx,1              ;умножаем сумму на 10
  add eax, edx
  shl edx,2
  add edx, eax           ;прибавляем текущее значение
  jmp @lp1
 
@ex: 
  mov eax,edx
  pop esi
  pop edx
  ret
str2dw endp
 
InputNumber proc         ; функция выводит на экран сообщение и ожидает ввода числа
                         ; ds:dx - сообщение, которое следует вывести
                         ; возвращает:
                         ; eax - введенное число
  push dx                ; сохраняем регистры
  push si
  push di
  mov ah,9
  int 21h
 
  mov ah,0ah
  mov dx,offset buf
  int 21h                ;пользователь вводит в текстовом виде в buf значение элемента массива
 
  mov di,offset buf+1
  mov al,[di]            ;берем длину введенной строки
  mov ah,0               ;ах=длине
  inc di                 ;начало введенной строки в памяти
  mov si,di              ;сохраняем это значение
  add di,ax              ;конец введенной строки в памяти
  mov [di],byte ptr 0    ;ставим нулевой байт за последним символом строки
 call str2dw             ;преобразовываем строку в значение
  pop di                 ;восстанавливаем регистры
  pop si
  pop dx
  ret
InputNumber endp
 
printdec32 proc          ;преобразование числа из ах в десятичную строку по адресу es:di
                         ;eax - число
                         ;es:di - адрес буфера приемника
  push ecx               ;сохраняем регистры
  push edx
  push ebx
  mov ebx,10             ;основание системы
  XOR ecx,ecx            ;в сх будет количество цифр в десятичном числе
 
@@m1: 
  XOR edx,edx
  DIV ebx                ;делим число на степени 10
  PUSH edx               ;и сохраняем остаток от деления(коэффициенты при степенях) в стек
  INC ecx
  TEST eax,eax
  JNZ @@m1
 
@@m2: 
  POP eax
  ADD AL,'0'             ;преобразовываем число в ASCII символ
 STOSb                   ;сохраняем в буфер
  LOOP @@m2              ;все цифры
  mov al,'$'             ;добавляем метку конца строки
 stosb
  POP ebx                 ;восстанавливаем регистры
  POP edx
  POP ecx
  RET
printdec32 endp
 
 
end start