Резидент, который при нажатии комбинации клавиш выводит на экран сообщение и выгружается из памяти

cseg segment  ;чтобы работало в реальном режиме
     assume cs:cseg, ds:cseg
     org 100h
main proc
     jmp init       ; переход на начало инициализации резидента
main endp
 
old_2fh dd 0       ; адрес мультиплексного прерывания
old_09h dd 0       ; адрес системного клавиатурного прерывания
flag db 0          ; флаг для проверки режима смены текста
 
msg1 db 'setup resident$'
msg2 db 'resident already in memory!$'
msg3 db 'sucsessful upload$'
text db 'Hello World!$'
tail db 'off'
 
 
 
 
;Обработчик клавиатуры 09h
new_09h proc
    push ax                 ; сохранение используемых регистров
    push bx
    push dx
    push es
    push di
    push si
    push ds
    push cs
    pop ds
 
    
    in al,60h               ; читаем scan-код  из порта 60h(порт клавиатуры)
    cmp al,1Eh              ; клавиша A
    jne check
    xor bx,bx               ; загрузка байта
    mov ds,bx               ; состояния
    mov al,ds:[0417H]       ; клавиатуры
    test al,4               ; проверка 3 бита, нажата ли клавиша Ctrl
    jz check                ; не нажата
    xor byte ptr cs:flag,1  ; переключим флаг
    
    check: 
    cmp byte ptr cs:flag,0  ; 
    je ex2                  ; 
 
    mov cs:flag, 0          ; обнуляем флаг для следующего вызова
    call typemsg            ; вывод текста
    mov ax,0c801h           ; пошлем команду на выгрузку в наш обработчик мультиплексорного прерывания
    int 2fh
ex2: 
    pop ds                  ; очистка стека
    pop si
    pop di
    pop es
    pop dx
    pop bx
    pop ax
    jmp Dword ptr cs:[old_09h] ;Переход на старый обработчик
endp new_09h
 
;Процедура вывода сообщения и выгрузки резидента из памяти
typemsg proc
    push ax                 ; сохранение используемых регистров
    push bx
    push dx
    push es
    push di
    push si
    push ds
    push cs
    pop ds
    
    
 
    
; --- настройки ---
    sti                     ; установка флага прерывания if в единицу.(разрешение аппаратных прерываний)
    cld                     ; сброс в ноль флага направления df.(команды обработки строк автоинкрементируются, т. е. выполняют операции с адресами от младших адресов к старшим.)
    
    mov ax,0B800h           ; настройка AX на сегмент видеопамяти
    mov es,ax               ; запись в ES значения сегмента видеопамяти
    xor di,di               ; настройка DI на начало сегмента видеопамяти
    mov ah,0Bh              ; атрибут выводимых символов
    
    
; --- вывод сообщения ---
    xor bx, bx              ; BX будет индексировать строку
pr: mov al, text[bx]        ; текущий обрабатываемый символ, BX-1 - индекс
    stosw                   ; переписывает содержимое АХ в ячейку памяти с адресом ES: (E)DI, после чего прибавляет 2 к (E)DI, если флаг D опущен, и вычитает 2, если D поднят. 
    inc bx                  ; понижение счётчика, т.к. счёт происходит от последнего
    cmp text[bx],'$'
    jne pr
    
    pop ds                  ; очистка стека
    pop si
    pop di
    pop es
    pop dx
    pop bx
    pop ax
    ret
typemsg endp
 
;Процедура выгрузки из памяти
uninst proc
 
uninst endp
 
;Обработчик повторной загрузки с возможностью выгрузки 2fh
new_2fh proc        ; резидентный обработчик мультиплексного прерывания
     cmp ah,0c8h    ; наша функция?
     jne out_2fh    ; не наша, назад по цепочке (старый обработчик)
     cmp al,00h     ; наша функция, смотрим команда 00h
     je live        ; да, сообщим что уже в памяти
     cmp al,01h     ; пришла команда на выгрузку?
     je uninstLB
out_2fh: jmp cs:old_2fh
live: mov al,0ffh
      iret
 
uninstLB: ;call uninst;выгрузка из памяти
     push ds
     push es
     push dx
     ;восстановим старые прерывания
     mov ax,2509h   ; для клавиатуры
     lds dx,cs:old_09h
     int 21h
     
     mov ax,252fh ; для мультиплексного прерывания
     lds dx,cs:old_2fh
     int 21h
 
     mov es,cs:[2ch] ;сегмент окружения из PSP
     mov ah,49h ;функция освобождения блока памяти 
     int 21h
 
     push cs ; скопируем cs в es
     pop es  ; es указывает на начало программы
 
     mov ah,49h ; освобождение памяти (ES = сегментный адрес (параграф) освобождаемого блока памяти)
     int 21h
 
     pop dx
     pop es
     pop ds
     ;ret
     
     iret
 
new_2fh endp
 
 
 
;Инициализация резидентной программы
init proc ;инициализация
     mov ax,0c800h  ; проверка на наличие в памяти
     int 2fh        ; первого экземпляра программы
     cmp al,0ffh    ; вернулся код ffh
     jne first      ; нет экземпляр первый
     mov cl,es:80h  ; получим длину хвоста команды
     cmp cl,0       ; длина хвоста =0?
     je second
     xor ch,ch      ; в cx длина хвоста
     mov di,81h     ; es:di->хвост в PSP
     mov si,offset tail ; ds:di ->поле tail
     mov al,' '     ; уберем пробелы из начала хвоста
repe scasb          ; сканируем хвост, пока пробелы
     dec di         ; di -> первый символ после пробелов
     mov cx,3       ; ожидаемая длина параметра
repe cmpsb          ; сравниваем введенный параметр с ожидаемым     
     jne second     ; введена ошибочная команда
     mov ax,0c801h  ; пошлем в резидентную программу команду на выгрузку
     int 2fh
     mov dx,offset msg3     ; выведем сообщение о выгрузке
     jmp exit
     
; не первый вызов программы
second: mov dx,offset msg2  ; выведем сообщение, что резидент уже в памяти
exit:   mov ah,09h
        int 21h
        mov ax,4c00h        ; завершим программу без оставления в памяти
        int 21h
        
; первый вызов программы - совершение установки      
first:   
     mov ax,352fh   ; чтение и сохранение вектора 2fh
     int 21h
     mov word ptr cs:old_2fh,bx
     mov word ptr cs:old_2fh+2,es    
     mov ax,3509h   ; чтение и сохранение вектора 09h
     int 21h
     mov word ptr cs:old_09h,bx
     mov word ptr cs:old_09h+2,es    
     mov ax,252fh   ; установка обработчика 2fh
     mov dx,offset new_2fh 
     int 21h     
     mov ax,2509h   ; установка обработчика 09h
     mov dx,offset new_09h 
     int 21h     
     mov ah,09h     ; вывод сообщения об установке резидента
     mov dx,offset msg1
     int 21h     
     mov ax,3100h   ; завершим и оставим в памяти
     mov dx, (init-main+10fh)/16 ;з апрос в параграфах
     int 21h
init endp
 
 
 
 
cseg ends
 
end main