Разработать программу генерации звуковых сигналов

.model tiny
.386
.code
.startup
 
  in al,60h
  mov cl,al  ; последний код
@@rep:
  call Clear  ; очищаем буфер клавы
  in al,60h
  cmp al,1  ; Esc?
  je @@exit
  cmp al,0E0h  ; не реагируем не него (спецкод), иначе будет треск
  je @@rep
  cmp cl,al
  je @@rep
  mov cl,al
  test al,80h
  jnz @@nosound
  cbw  ; ah=0
  shl ax,3
  add ax,20  ; ax=al*8+20 - частота      
@@sound:
  call Sound
  jmp @@rep
 
@@nosound:
  call NoSound
  jmp @@rep
 
@@exit:
  call Clear  ; очищаем буфер клавы
  call NoSound
  int 20h
 
Clear proc
  jmp @@chk
@@key:
  xor ah,ah
  int 16h
@@chk:
  mov ah,1
  int 16h
  jnz @@key
  ret
Clear endp
 
; Процедура Sound: генерация звука
; Вход: AX = частота звука (Гц)
Sound   proc    near
        xchg    bx,ax        ; Частота
        mov     dx,12h       ; (DX,AX)=1193181
        cmp     bx,dx        ; Если Bx <= 18Гц, то выход
        jbe     @@Done       ; Чтобы избежать переполнения
        in      al,61h       ; Порт РВ
        or      al,3         ; Установить биты 0-1
        out     61h,al
        mov     al,10110110b ; Управляющее слово таймера: канал 2, режим 3, двоичное слово
        out     43h,al       ; Вывод в регистр режима
        mov     ax,34DDh
        div     bx           ; AX=(DX:AX)/BX
        out     42h,al       ; Младший байт счетчика
        mov     al,ah
        out     42h,al       ; Старший байт счетчика
@@Done: ret
Sound   endp
 
; Процедура NoSound: выключение звука
NoSound proc    near
        in      al,61h    ; Порт РВ
        and     al,not 3  ; Сброс битов 0-1
        out     61h,al
        ret
NoSound endp
 
end