Название и содержимое регистров

.686P
.model flat,stdcall
include \masm32\include\windows.inc
includelib \masm32\lib\user32.lib
extern _imp__MessageBoxA@16:dword
extern _imp__wsprintfA:dword
.code
start: pushad;сохраняем в стеке содержимое всех регистров
mov ebp,esp
pushfd;сохраняем в стеке содержимое eflags
call $+5;передаем в стек содержимое eip
pop ebx;eip->ebx
sub ebx,5+1+2+1;поправка на длины предыдущих команд
;"call $+5"=5 байт,"pushfd"=1 байт,
;"mov ebp,esp"=2 байта,"pushad"=1 байт
push ebx;в стек скорректированное значение eip
xor eax,eax
mov ax,gs
push eax
mov ax,fs
push eax
mov ax,ss
push eax
mov ax,es
push eax
mov ax,ds
push eax
mov ax,cs
push eax
push dword ptr [ebp+0Ch];esp
push dword ptr [ebp+8];ebp
push dword ptr [ebp];edi
push dword ptr [ebp+4];esi
push dword ptr [ebp+14h];edx
push dword ptr [ebp+18h];ecx
push dword ptr [ebp+10h];ebx
push dword ptr [ebp+1Ch];eax
push offset format
push offset buffer
call _imp__wsprintfA
add esp,26*4
push 0
push offset Caption
push offset buffer
push 0
call _imp__MessageBoxA@16
ret
format db 'содержание регистров',0Ah
db 'при старте программы',0Ah
113
db 'eax=%08lXh',0Ah,'ebx=%08lXh',0Ah
db 'ecx=%08lXh',0Ah,'edx=%08lXh',0Ah
db 'esi=%08lXh',0Ah,'edi=%08lXh',0Ah
db 'ebp=%08lXh',0Ah,'esp=%08lXh',0Ah
db 'cs=%04lXh ds=%04lXh',0Ah,'es=%04lXh ss=%04lXh',0Ah
db 'fs=%04lXh gs=%04lXh',0Ah
db 'точка входа в программу',0Ah,'eip=%08lXh',0Ah
db 'eflags=%08lXh',0
buffer db 266 dup (0)
Caption db 'Mini-debugger',0
end start