Как называется такая фигура и как ее нарисовать?

;;;CADALYST 06/05 Tip2036:  slot.lsp    Slot Drawing Utility    (c) Thomas Christman

;;; GENERATES A SLOTTED HOLE FROM DIAMETER AND OVERALL or CENTER-CENTER LENGTH

(defun C:SLOT (/ osm plwid cl tl dm p1 p2 p3 p4)

(defun sloterr (s)
  (if (/= s "Function cancelled")
	(princ)
	(princ (STRCAT "\nError: " s))
  )
  (setvar "OSMODE" osm)
  (setvar "PLINEWID" plwid)
  (setq *error* olderr) 
  (princ)
)

(defun beginslot ()
  (setq dm (getreal "\nSlot Diameter: "))
  (initget 7 "Centers")
  (setq tl (getreal "\nTotal Slot Length ? (or Centers) "))
  (while (= nil (NUMBERP tl))
	(progn
	  (if (= tl "Centers")
		(progn
			(initget 7 "Length")
			(setq cl (getreal "\nLength Between Centers ? (or Length) "))
			(if	(/= (NUMBERP cl) nil)
				(setq tl (+ cl dm))
			)
		)
	  )
	  (if (= cl "Length")
		(progn
			(initget 7 "Centers")
			(setq tl (getreal "\nTotal Slot Length ? (or Centers) "))
		)
	  )
	)
  )
  (setq cnr (GETPOINT "\nCenter of Slotted Hole ? "))
  (setq ra (GETANGLE cnr "\nRotation Angle ? (Hor=0,Ver=90) "))
  (if (= ra nil)
	(setq ra 0)
  )
  (setq rt (* 180 (/ ra PI)))
)

(defun calcslot ()
;;;   _______
;;; A/       \
;;;  |       |
;;; B\_______/
;;;   D     C
  (setq
	x (CAR cnr)
	y (CADR cnr)
	a (- y (/ dm 2))
	b (+ y (/ dm 2))
	c (+ x (- (/ tl 2) (/ dm 2)))
	d (- x (- (/ tl 2) (/ dm 2)))
  )
)


  (setq
	olderr	*error*
	*error* sloterr
	osm (getvar "OSMODE")
	plwid (getvar "PLINEWID")
  )
  (setvar "OSMODE" 0)
  (setvar "PLINEWID" 0)
  (beginslot)
  (calcslot)
  (setq
	p1 (list c a)
	p2 (list d a)
	p3 (list d b)
	p4 (list c b)
  )
  (command "_.PLINE" p1 p2 "_A" p3 "_L" p4 "_A" "_CL") ; drawslot
  (command "_.ROTATE" "_LAST" "" cnr rt)
  (setvar "OSMODE" osm)
  (setvar "PLINEWID" plwid)
  (setq *error* olderr)
  (princ)
)