Atmel Studio

loop:
ser r16
out PORTB,r16
rcall delay
clr r16
out PORTB,r16
rcall delay
rjmp loop
delay:
;пишем нужную задержку
ret

.include    "tn2313def.inc"
 
.equ    F_CPU               = 1000000           ;внутренняя частота tiny2323 с делителем на 8
 
.equ    CTCNT1              = (F_CPU/64)        ;константа для формирования интервала времени 1 сек
 
;----------------------
.equ    PORT_LIGHTS         = PORTB
.equ    DDR_LIGHTS          = DDRB
.equ    PIN_LIGHTS          = PINB
.equ    b_Red               = PB0
.equ    b_Yellow            = PB1
.equ    b_Green             = PB2
 
;----------------------
.equ    RED_COUNT           = 15                ;15 sec - время красного
.equ    YELLOW_COUNT        = 5                 ;5 sec - желтого
.equ    GREEN_COUNT         = 15                ;15 sec - зеленого
 
.equ    GREEN_WINK          = 6                 ;для моргания зеленого на последних секундах
 
;----------------------
.def    CR0                 = r2                ;регистр для хранения нуля
.def    mode                = r16               ;режим работы
.def    temp                = r17               ;временный регистр
 
.def    count               = r18               ;счетчик секунд
 
.CSEG
    .org    0
rjmp    begin
    .org    INT0addr    ;External Interrupt Request 0
    reti
    .org    INT1addr    ;External Interrupt Request 1
    reti
    .org    ICP1addr    ;Input Capture1 Interrupt
    reti
    .org    OC1Aaddr    ;Timer/Counter1 Compare Match A
rjmp    OV1A_routine                            ;вся работа в таймере 1
    .org    OVF1addr    ;Overflow1 Interrupt
    reti
    .org    OVF0addr    ;Overflow0 Interrupt
    reti
    .org    URXC0addr   ;USORT0 Receive Complete Interrupt
    reti
    .org    UDRE0addr   ;USORT0 Data Register Empty Interrupt
    reti
    .org    UTXC0addr   ;USORT0 Transmit Complete Interrupt
    reti
    .org    ACIaddr     ;Analog Comparator Interrupt
    reti
    .org    PCIaddr     ;Pin Change Interrupt
    reti
    .org    OC1Baddr    ;Timer/Counter1 Compare Match B
    reti
    .org    OC0Aaddr    ;Timer/Counter0 Compare Match A
    reti
    .org    OC0Baddr    ;Timer/Counter0 Compare Match B
    reti
    .org    USI_STARTaddr   ;USI start interrupt
    reti
    .org    USI_OVFaddr ;USI overflow interrupt
    reti
    .org    ERDYaddr    ;EEPROM write complete
    reti
    .org    WDTaddr     ;Watchdog Timer Interrupt
    reti
 
begin:
    ldi     temp, low(RAMEND)
    out     SPL, temp                       ;вершина стека
 
    rcall   Init                            ;настройка параметров
 
    sei                                     ;глобальное разрешение прерываний
 
main_loop:                                  ;основной цикл
    wdr                                     ;он пустой, только сбрасываем watchdog
    rjmp    main_loop
 
;---------------------
Init:                                       ;настройка параметров
    clr     CR0                             ;обнулим регистр
 
    ldi     temp, (1<<b_Red)|(1<<b_Yellow)|(1<<b_Green)
    out     DDR_LIGHTS, temp                ;управление цетами настраиваем на выход
    out     PORT_LIGHTS, CR0                ;тушим все
 
; Timer1, CTC mode, делитель 1/64
    ldi     temp, (1<<WGM12)|(1<<CS11)|(1<<CS10)
    out     TCCR1B, temp                    ;делитель на 1/64, режим CTC
    ldi     temp, high(CTCNT1)
    out     OCR1AH, temp                    ;настраиваем регистры OCR1A
    ldi     temp, low(CTCNT1)
    out     OCR1AL, temp
 
    ldi     temp, (1<<OCIE1A)               ;разрешаем прерывание от сравнения А таймера 1
    out     TIMSK, temp
 
    clr     mode                            ;режим = 0 (начинаем с красного цвета)
    ldi     count, RED_COUNT                ;счетчик красного
    ret
 
;---------------------
OV1A_routine:                               ;вся работа здесь, в прерывании
                                            ;т.к. основной цикл пустой, то используемые регистры
                                            ;мы не будем сохранять. Они используются только здесь!
    ldi     ZL, low(mode_routines)
    ldi     ZH, high(mode_routines)         ;адрес тавлицы подпрограмм
    add     ZL, mode                        ;режим
    adc     ZH, CR0
    icall                                   ;косвенный вызов по адресу [Z]
    reti                                    ;выход из прерывания
 
mode_routines:                              ;таблица отработки режимов
    rjmp    red_routine
    rjmp    yellow1_routine
    rjmp    green_routine
    rjmp    yellow2_routine
 
red_routine:                                ;красный цвет
    dec     count                           ;уменьшаем счетчик
 
    ldi     temp, (1<<b_Red)
    out     PORT_LIGHTS, temp               ;включаем красный, остальные гасим
 
    brne    red_routine_ret                 ;счетчик не 0 - выходим
 
    inc     mode                            ;дошли до 0, меняем режим на 1 - желтый (засветится через 1 сек)
    ldi     count, YELLOW_COUNT             ;новый счетчик
red_routine_ret:
    ret
 
yellow1_routine:                            ;желтый - аналогично красному
    dec     count
 
    ldi     temp, (1<<b_Yellow)             ;включаем желтый
    out     PORT_LIGHTS, temp
 
    brne    yellow1_routine_ret
 
    inc     mode                            ;переходим на зеленый
    ldi     count, GREEN_COUNT
yellow1_routine_ret:
    ret
 
green_routine:                              ;зеленый. последние секунды поморгаем фонарем!
    dec     count                           ;уменьшаем счетчик
 
    cpi     count, GREEN_WINK               ;если больше или равно 6, то просто на зажигание зеленого фонаря
    brge    green_set
 
    sbi     PIN_LIGHTS, b_Green             ;начиная с этого момента и до 0, меняем portB.Green на противоподожный!
                                            ;это можно сделать указанной командой!!!
    tst     count                           ;дошли до конца?
    brne    green_routine_ret               ;нет - продолжаем
 
    inc     mode                            ;да - меняем режим на второго желтого
    ldi     count, YELLOW_COUNT
green_routine_ret:
    ret
 
green_set:                                  ;включение зеленого фонаря
    ldi     temp, (1<<b_Green)
    out     PORT_LIGHTS, temp
    ret
 
yellow2_routine:                            ;желтый между зеленым и красным - аналогично красному и первому желтому 
    dec     count
 
    ldi     temp, (1<<b_Yellow)
    out     PORT_LIGHTS, temp
 
    brne    yellow2_routine_ret
 
    clr     mode
    ldi     count, RED_COUNT
yellow2_routine_ret:
    ret