Написать командник для формирования списка определенного формата файлов с определенным диапазоном дат

@echo off
SetLocal EnableExtensions DisableDelayedExpansion
 
:: где ищем
set srcFolder=C:\Users\Alex\Desktop\ParseAVZ
 
:: какие расширения
set exts=exe txt
 
:: лог
set log=%~dp01.lst
 
PUSHD "%temp%"
echo.
if "%~1"=="" set dbeg=01.01.0001
if "%~2"=="" set dend=%date%
if "%~1"=="" if "%~2"=="" (set /p dbeg="Дата, начиная с: "& set /p dend="Дата, заврешая:  ")
::set dbeg=01.01.2014
::set dend=01.01.2017
cls
echo.
echo Период: %dbeg% - %dend%
echo.
del "%log%" 2>NUL
 
:: root
call :cmp "%srcFolder%"
:: subfolders
For /f "delims=" %%a in ('dir /s /b /ad-l "%srcFolder%\*" 2^>NUL') do call :cmp "%%a"
 
del $ $$
POPD
pause
goto :eof
 
:cmp [Folder]
 
set "fld=%~1"
Setlocal EnableDelayedExpansion
set "fld=!fld:%srcFolder%\=!"
EndLocal & set "fld=%fld%"
 
del $ 2>NUL
for %%a in (%exts%) do (
  forfiles /M "*.%%a" /P "%~1" /d +%dbeg% 2>NUL >>$
  forfiles /M "*.%%a" /P "%~1" /d -%dend% 2>NUL >>$
)
sort $ /o $$
 
:: find duplicate lines
set "old="
(for /f "delims=" %%a in ($$) do (
  set "new=%%~a"
  Setlocal EnableDelayedExpansion
  if "!new!" equ "!old!" (
    if not exist "%~1\%%~a" echo !fld!%%~a
    EndLocal
  ) else (
    EndLocal
    set "old=%%~a"
  )
)) >> "%log%"
exit /B