Форум программистов, компьютерный форум, киберфорум
Batch (CMD/BAT)
Войти
Регистрация
Восстановить пароль
 
 
Рейтинг 4.64/25: Рейтинг темы: голосов - 25, средняя оценка - 4.64
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
1

Создание папок по цифровому названию файлов и перенос этих файлов в созданные папки

21.09.2016, 11:33. Показов 4984. Ответов 23
Метки нет (Все метки)

Доброго времени суток.
Необходим БАТ файл.
Что имеем:
Общую папку с файлами типа (A0010061609.DBF, A0010061609.PRN, A0010061609.SB, A0010061609.TTL, а так же файлы с такими же цифровыми названиями только впереди стоит AF: AF0141061606.DBF), как видно в папке лежат по 4 файла с названием А0123456789 и АФ023456789 (цифры разные), цифровые названия разные не только те которые я указал. Их более 140.
Необходимо, что бы батник находил файлы (в не зависимости от расширения) именно по цифровому коду и создавал папку с именем это года (он 10тизначный) и туда копировал, а лучше перемещал файлы в названии которых будут эти цифры (первые буквы в названии в расчет не брать).
Таким образом получаться папки с названием 0010031609 и в ней файлы A0010061609.DBF, A0010061609.PRN, A0010061609.SB, A0010061609.TTL, AF0010061609.DBF, AF0010061609.PRN, AF0010061609.SB, AF0010061609.TTL

Вот что требуется. Если сто то не понятно пишите, разъясню более подробно.
Всем заранее спасибо.
0
Programming
Эксперт
94731 / 64177 / 26122
Регистрация: 12.04.2006
Сообщений: 116,782
21.09.2016, 11:33
Ответы с готовыми решениями:

Создание папок по имени файлов и перемещение этих файлов в созданные папки
Господа, прошу помощи. В батниках полный ноль Имеется папка с множеством файлов, скриншот во...

Создание папок с именами заданных файлов и перемещение этих файлов в созданные папки
Подскажите пожалуйста как по названиям файлов txt создать папки и положить в каждую из папок файл с...

Преобразование файлов и перенос их в папки(названия папок содержится в именах файлов)
Доброй ночи! Тяжело быть глупой, помогите автоматизировать (пишу полную задачу, но если это...

Перенос файлов из папки в новые созданные папки
Добрый день, уважаемые форумчане. Прошу помощи с написанием bat-файла. Значит задача такая. ...

23
Любознательный
1769 / 789 / 218
Регистрация: 10.03.2016
Сообщений: 1,852
21.09.2016, 14:02 2
Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
@echo off
rem Перемещение файлов со снятием атрибутов "скрытый" и "системный" и с возвратом 
rem их после перемещения. Пути лучше указать абсолютные и запускать батник из 
rem любого места
rem Исходный каталог:
set "src=c:\TEMP\1"
rem Целевой каталог:
set "dst=c:\TEMP\2"
rem Проверка каталогов:
if not exist "%src%\" echo Error. Not exist %src%&&pause&&exit
if not exist "%dst%\" md "%dst%"
if errorlevel 1 echo Error. Create the folder %dst% can not be&&pause&&exit
rem Получаем список файлов для перемещения:
for /f "delims=" %%i in ('dir /b/a-d "%src%"') do (
    set "file=%%~i"
    set "f_name=%%~ni"
    call :mov
)
pause&&exit
 
:mov
if /i "%f_name:~1,1%"=="f" (set "fld=%f_name:~2%") else (set "fld=%f_name:~1%")
if not exist "%dst%\%fld%" md "%dst%\%fld%"
for /f "delims=" %%a in ('attrib "%src%\%file%"') do set "atrb=%%a"
attrib -s -h "%src%\%file%"
>nul move /y "%src%\%file%" "%dst%\%fld%\"
set "atrb=%atrb:~3,2%"
set "atrb=%atrb:S=+S %"
set "atrb=%atrb:H=+H %"
if "%atrb%" neq "  " attrib "%dst%\%fld%\%file%" %atrb%
exit /b
1
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
21.09.2016, 15:35  [ТС] 3
СПАСИБО ОГРОМЕННОЕ за быстрый ответ YuS_2,
Проставил нужные папки и все прошло идеально.
Можно тогда еще вот такой вопрос.
Коды в названии файлов это коды предприятий, можно ли после данного скрипта переименовать папки по названиям, файл с кодом и названиями предприятий прикреплю к сообщению.
Единственное в названии файлов: например A0010061609.DBF код предприятия это первые 4 цифры, а именно 0010, остальное это дата выгрузки файлов с базы данных. Что является не существенной инфой.
Спасибо за скрипт еще раз.
0
Вложения
Тип файла: rar организации.rar (6.7 Кб, 9 просмотров)
Любознательный
1769 / 789 / 218
Регистрация: 10.03.2016
Сообщений: 1,852
21.09.2016, 21:20 4
Лучший ответ Сообщение было отмечено vfhadj как решение

Решение

Цитата Сообщение от vfhadj Посмотреть сообщение
код предприятия это первые 4 цифры, а именно 0010
Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
@echo off
rem Перемещение файлов со снятием атрибутов "скрытый" и "системный" и с возвратом 
rem их после перемещения, с последующим переименованием каталогов. Пути лучше  
rem указать абсолютные и запускать батник из любого места
rem Файл-список с наименованиями (конечные пробельные символы необходимо удалить):
set "t_in=text.txt"
rem Исходный каталог:
set "src=d:\TEMP\1"
rem Целевой каталог:
set "dst=d:\TEMP\2"
rem Проверка каталогов:
if not exist "%src%\" echo Error. Not exist %src%&&pause&&exit
if not exist "%dst%\" md "%dst%"
if errorlevel 1 echo Error. Create the folder %dst% can not be&&pause&&exit
choice /c yn /m "Переместить файлы "
goto answ%errorlevel%
:answ1
rem Получаем список файлов для перемещения:
for /f "delims=" %%i in ('dir /b/a-d "%src%"') do (
    set "file=%%~i"
    set "f_name=%%~ni"
    call :mov
)
:answ2
choice /c yn /m "Преобразовать список и переименовать каталоги "
goto wrk%errorlevel%
:wrk1
rem Преобразование файл-списка предприятий
for /f "tokens=1*" %%b in ('type "%t_in%"') do (
    set "var1=000%%~b"&set "var2=%%~c"
    cmd /v/c echo !var1:~-4! !var2:^"=!>>$
)
rem Переименование каталогов
for /f "delims=" %%m in ('dir /b/ad "%dst%"') do (
    set "fold=%%~m"
    cmd /v/c "for /f "tokens=1*" %%n in ('findstr /bc:"!fold:~0,4!" "$"') do move /y "%dst%\%%~m" "%dst%\%%~o""
)
del $
:wrk2
pause&&exit
 
:mov
if /i "%f_name:~1,1%"=="f" (set "fld=%f_name:~2%") else (set "fld=%f_name:~1%")
if not exist "%dst%\%fld%" md "%dst%\%fld%"
for /f "delims=" %%a in ('attrib "%src%\%file%"') do set "atrb=%%a"
attrib -s -h "%src%\%file%"
>nul move /y "%src%\%file%" "%dst%\%fld%\"
set "atrb=%atrb:~3,2%"
set "atrb=%atrb:S=+S %"
set "atrb=%atrb:H=+H %"
if "%atrb%" neq "  " attrib "%dst%\%fld%\%file%" %atrb%
:answ0
:answ255
:wrk0
:wrk255
exit /b
- Файл-список из формата Excel, необходимо сохранить как текст DOS, затем удалить конечные пробелы...
1
Вложения
Тип файла: rar text.rar (1.7 Кб, 9 просмотров)
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
22.09.2016, 14:47  [ТС] 5
И снова СПАСИБО.
Единственное не переименовуются 2 папки с кодами 0251061609 и 0348061609. Проверил в тхт-файле вроде все нормально (думал что это из-за того что название начинается с ковычек). Остальные папки переименовались нормально (переделаю названия в кирилицу).
И еще при запуске скрипта в начале идет запрос с подтверждением Y/N, вот там "кракозябры", но это скорее всего из-за кодировки шрифта. (это не суть важно).
Буду еще раз посмотреть .
Еще раз спасибо.

Добавлено через 25 минут
И Еще вопрос, если надумаю внести изменения в перечень предприятий, то как я понял, структуру текстового файла не менять. то есть количество пробелов между кодом и названием должно совпадать?
И спасибо еще раз БОЛЬШОЕ.
Рэспект и уважуха

Добавлено через 13 минут
Ну вроде все, разобрался! Причина была в / и \ (слэшах)!!!
0
Любознательный
1769 / 789 / 218
Регистрация: 10.03.2016
Сообщений: 1,852
22.09.2016, 20:43 6
Цитата Сообщение от vfhadj Посмотреть сообщение
количество пробелов между кодом и названием должно совпадать?
Количество пробелов не имеет значения. Главное, чтобы не было конечных пробелов, после наименования.

Цитата Сообщение от vfhadj Посмотреть сообщение
Причина была в / и \ (слэшах)!!!
В наименовании такие символы, конечно, использовать нельзя. Если их немного, то лучше заменить, а если их много и они формируются не вручную, то можно организовать их удаление прямо в сценарии...
0
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
23.09.2016, 09:35  [ТС] 7
Слэши я удалю в Базе данных и они больше не будут выгружаться в перечень (текстовый файл), так что все решаемо.
Уже чера поставил скрип спецу, довольная как слон. Единственное на хрюше скрип пришлось корректировать, убрать запросы, то есть функцию choice. Так как ругался на него, хоть и добавлял чойс в систем32. не помогло.
Но в общем моя просьба Вами удовлетворена полностью.
Большое спасибо за скрипт и за оперативный ответ.
0
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
26.10.2016, 13:20  [ТС] 8
YuS_2,
Доброго времени суток.
У меня есть к Вам просьба создать еще скрипт, а именно.
Есть определенное кол-во файлов, только их названия теперь только цифровые и с разными расширениями.
пример: 03971016.DBF, 03971016.JEO, 03971016.PRN и 03971016.TTL, а также 00321016.DBF, 00321016.JEO, 00321016.PRN, 00321016.TTL. КАК видно файлы это код предприятия (0397) + месяц и год за какой они выгружаются (10.16)
Мне необходимо что бы скрипт эти файлы сортировал в папки по названию (например 00321016) и после этого переименовывал полученные папки согласно файла тхт, который я ранее отсылал.
За ранее благодарю.
ПыСы: попробовал применить Ваш скрипт, но переименовать папки не получается. Сам не разобрался как показать что надо брать первые 4 цифры в начале названия файла и сверять со списком.
0
Любознательный
1769 / 789 / 218
Регистрация: 10.03.2016
Сообщений: 1,852
27.10.2016, 09:27 9
Цитата Сообщение от vfhadj Посмотреть сообщение
Мне необходимо что бы скрипт эти файлы сортировал в папки по названию
Т.е. если я правильно понял:
1. Файлы с определенным кодом предприятия (определяется по первым четырем символам любого файла), в итоге должны находиться в одной папке с именем предприятия.
2. Остальная часть имени файлов, т.е. дата ни на что не влияет.
3. Промежуточные создания папок с именем равным части имени файлов (т.е. папок с цифрами в имени) необязательны.
Так?
0
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
27.10.2016, 10:16  [ТС] 10
И снова здравствуйте.
Немного изменилось конечное требование к наименованию папок, а именно.
Необходимо не только сгрупировать файлы по папкам созданным по цифровому названию файлов, переименовать их согласно списка тхт, но, И ЭТО ГЛАВНОЕ, необходимо (так как список большой, а на самом деле предприятий меньше) сгруппировать папки в несколько по предприятию, например РЭСу.
Может мне сразу переделать список в такой вид:
32, 74, 78, 81, и т. д. - переименовать общую папку в Волн. РЭС
10, 122 и т. д. - переименовать общую папку в Волн. Водоканал
73, 77 и т. д. - переименовать общую папку в УГГ
ну и так далее.
То есть что получается, сначала скрипт раскидывает файлы с одним названием по папкам которые сам создает, потом с этих папок формирует общие по основному предприятию согласно списка.
Вот как то так.
Очень надеюсь на скорый ответ.

Добавлено через 47 минут
Да Вы правильно поняли. Название будет брать за 4 первые цифры, то есть 0010 это 10 в списке.
0
3862 / 1950 / 622
Регистрация: 26.04.2015
Сообщений: 6,349
27.10.2016, 12:41 11
vfhadj,
Вообще-то
Цитата Сообщение от vfhadj Посмотреть сообщение
И ЭТО ГЛАВНОЕ, необходимо
в вашем текстовом файле во второй колонке (будущее название папок) убрать запрещенные для имени символы, а именно: \/:*?"<>|
0
Любознательный
1769 / 789 / 218
Регистрация: 10.03.2016
Сообщений: 1,852
27.10.2016, 12:51 12
Цитата Сообщение от vfhadj Посмотреть сообщение
То есть что получается, сначала скрипт раскидывает файлы с одним названием по папкам которые сам создает, потом с этих папок формирует общие по основному предприятию согласно списка.
Не совсем понимаю, зачем перемещать файлы сначала в одну папку, чтобы потом в итоге эти файлы опять перемещать в другие папки?
начальное условие понятно. Непонятно, что в итоге требуется получить...
Если все промежуточные результаты перемещений не требуются, то в итоге, можно список предприятий привести к общему знаменателю, для простоты перемещений файлов. Только не папки надо переименовывать:
Цитата Сообщение от vfhadj Посмотреть сообщение
32, 74, 78, 81, и т. д. - переименовать общую папку в Волн. РЭС
а в самом списке предприятий, переименовать их соответственно так, как требуется расположить файлы в дереве папок, т.е.:
Например, если требуется, чтобы файлы с кодами предприятий в имени 0032*.*, 0074*.*, 0078*.*, 0084*.* находились, в итоге, в одной папке "Волн. РЭС", то список надо переработать так:
Код
32 Волн. РЭС
...
74 Волн. РЭС
...
78 Волн. РЭС
...
81 Волн. РЭС
Если, конечно, это то, что требуется получить, учитывая новые вводные... либо я их не совсем понял. Уточните, а лучше с примерами: несколько наименований файлов и конечный результат.
0
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
27.10.2016, 13:18  [ТС] 13
1. Насчет перемещения, я у Вас просил совета, так как не знаю сам. Вот и спрашивал, или делать как первій скрипт (по моему мнению слишком сложно), или просто исправить список по типу:
10 Новотроицкое райводоканал
24 Волновахский у с
32 Волн. РЭС
50 Кировское Волн. РЭС
73 Никольское Докуч. УГГ
74 Никольское Докуч. РЭС
76 Бугас Волн.РЭС
77 Николаевка Докуч УГГ
78 Николаевка Докуч. РЭС
81 Свободное Волн. РЭС
87 Прохоровка Волн. РЭС
89 Златоустовка Волн.РЭС
101 Калинино Волн.РЭС
105 Новотроицкое Докуч. РЭС
111 Ольгинка Теплосеть
119 Ольгинка Докуч.УГГ
и соответственно сразу брать из списка коды предприятий и раскидывать файлы в папки с названием корневого предприятия.
0
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
27.10.2016, 13:35  [ТС] 14
Или даже проще сделать вот так, если это возможно, как писал я ранее:
50, 81, 87, 89 и т. д. Волн. РЭС - (основное предприятия, а Кировское, Свободное.... - это подразделение)
Таких "основных" предприятий не много: Волн. РЭС, Докуч. УГГ, райводоканал..... список исправил.

В списке видно, что филиалы имеют окончания из названий "Основных" предприятий, но я думаю сложно будет извлечь похожие названия из списка, вычленить их и поскидывать файлы в папку "основного предприятия".
Пример: в архиве било. рар исходная парка, в архиве стало.рар как должно получиться.
Опишите вопросы которые у Вас возникнут.
0
Вложения
Тип файла: txt text.txt (4.1 Кб, 4 просмотров)
Тип файла: rar било.rar (73 байт, 2 просмотров)
Тип файла: rar стало.rar (288.8 Кб, 3 просмотров)
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
27.10.2016, 13:46  [ТС] 15
Кстати исправил список как Вы писали.
Я думаю с ним будет проще.
0
Вложения
Тип файла: txt text1.txt (2.9 Кб, 3 просмотров)
Любознательный
1769 / 789 / 218
Регистрация: 10.03.2016
Сообщений: 1,852
27.10.2016, 18:18 16
Лучший ответ Сообщение было отмечено vavun как решение

Решение

Цитата Сообщение от vfhadj Посмотреть сообщение
Кстати исправил список как Вы писали.
Наименования предприятий в списке должны совпадать полностью - от первого пробельного символа (между цифровым кодом и наименованием) и до конца строки, иначе будут создаваться разные каталоги. В Вашем списке были ошибки - в аттаче поправленный список:
text1.txt

Модифицированный код:
Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
@echo off
rem Перемещение файлов со снятием атрибутов "скрытый" и "системный" и с возвратом 
rem их после перемещения. Файлы перемещаются в каталоги, создаваемые по списку
rem предприятий (цифровой код). Пути лучше указать абсолютные и запускать батник
rem  из любого места
 
rem Файл-список с наименованиями (конечные пробельные символы необходимо удалить):
set "t_in=text1.txt"
rem Исходный каталог:
set "src=c:\test1"
rem Целевой каталог:
set "dst=c:\test2"
rem Проверка каталогов:
if not exist "%src%\" echo Error. Not exist %src%&&pause&&exit
if not exist "%dst%\" md "%dst%"
if errorlevel 1 echo Error. Create the folder %dst% can not be&&pause&&exit
rem Преобразование файл-списка предприятий
for /f "tokens=1*" %%b in ('type "%t_in%"') do (
    set "var1=000%%~b"&set "var2=%%~c"
    cmd /v/c echo !var1:~-4! !var2:^"=!>>$
)
rem Получаем список файлов для перемещения:
for /f "delims=" %%i in ('dir /b/a-d "%src%"') do (
    set "file=%%~i"
    set "f_name=%%~ni"
    call :mov
)
del $
pause&exit
 
:mov
for /f "tokens=1*" %%n in ('findstr /bc:"%f_name:~0,4%" "$"') do set "fld=%%o"
if not exist "%dst%\%fld%" md "%dst%\%fld%"
for /f "delims=" %%a in ('attrib "%src%\%file%"') do set "atrb=%%a"
attrib -s -h "%src%\%file%"
>nul move /y "%src%\%file%" "%dst%\%fld%\"
set "atrb=%atrb:~3,2%"
set "atrb=%atrb:S=+S %"
set "atrb=%atrb:H=+H %"
if "%atrb%" neq "  " attrib "%dst%\%fld%\%file%" %atrb%
exit /b
1
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
28.10.2016, 08:50  [ТС] 17
Доброе время суток.
ТО ЧТО НАДО!!!!
СПЕЦИАЛИСТЫ ДОВОЛЬНЫ.
СПАСИБО ВАМ БОЛЬШОЕ!
0
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
26.12.2018, 15:12  [ТС] 18
YuS_2,

Доброго времени суток.
я в продолжении ветки: Создание папок по цифровому названию файлов и перенос этих файлов в созданные папки

Я беспокою Вас так как необходимо внести некоторые коррективы в скрипт. Если Вас, конечно же не затруднит.
Раньше список предприятий состоял из простого 3х-значного кода (10, 397 и т. д.) сейчас мне пришлось проставлять кода ЕДРПОУ этих предприятий и получился вот такой список.(прилагаю).
Я добавил в искомый файл названия, но файлы с большими кодами , и как видно кода начинаются уже без 0 в начале. может в этом и проблема.
В общем такая задача. Добавлены предприятия в список. Не формируются папки. Что делать?
Спасибо!
0
Вложения
Тип файла: txt text1.txt (4.1 Кб, 1 просмотров)
Тип файла: rar swapping.rar (2.2 Кб, 1 просмотров)
Любознательный
1769 / 789 / 218
Регистрация: 10.03.2016
Сообщений: 1,852
26.12.2018, 18:22 19
Цитата Сообщение от vfhadj Посмотреть сообщение
Не формируются папки. Что делать?
Ранее были не более чем трехзначные коды предприятий, которые в батнике использовались уже как четырехзначные с ведущим нулем... четырехзначные коды предприятий соответствовали наименованиям файлов (первые четыре символа)...
А что требуется сейчас? Коды предприятий, вижу восьмизначные - какое соответствие с наименованиями файлов у них теперь?
В общем, опишите подробности того, что в итоге требуется получить.

Ну, а предварительно, если конечно я правильно понял соответствие, то вот поправленный код:
Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
@echo off
rem Перемещение файлов со снятием атрибутов "скрытый" и "системный" и с возвратом 
rem их после перемещения. Файлы перемещаются в каталоги, создаваемые по списку
rem предприятий (цифровой код). Пути лучше указать абсолютные и запускать батник
rem  из любого места
 
rem Файл-список с наименованиями (конечные пробельные символы необходимо удалить):
set "t_in=text1.txt"
rem Исходный каталог:
set "src=c:\test1"
rem Целевой каталог:
set "dst=c:\test2"
rem Проверка каталогов:
if not exist "%src%\" echo Error. Not exist %src%&&pause&&exit
if not exist "%dst%\" md "%dst%"
if errorlevel 1 echo Error. Create the folder %dst% can not be&&pause&&exit
rem Преобразование файл-списка предприятий
for /f "tokens=1*" %%b in ('type "%t_in%"') do (
    set "var1=0000000%%~b"&set "var2=%%~c"
    cmd /v/c echo !var1:~-8! !var2:^"=!>>$
)
rem Получаем список файлов для перемещения:
for /f "delims=" %%i in ('dir /b/a-d "%src%"') do (
    set "file=%%~i"
    set "f_name=%%~ni"
    call :mov
)
del $
pause&exit
 
:mov
set "f_name=0000000%f_name%"
set "f_name=%f_name:~-12%"
for /f "tokens=1*" %%n in ('findstr /bc:"%f_name:~0,8%" "$"') do set "fld=%%o"
if not exist "%dst%\%fld%" md "%dst%\%fld%"
for /f "delims=" %%a in ('attrib "%src%\%file%"') do set "atrb=%%a"
attrib -s -h "%src%\%file%"
>nul move /y "%src%\%file%" "%dst%\%fld%\"
set "atrb=%atrb:~3,2%"
set "atrb=%atrb:S=+S %"
set "atrb=%atrb:H=+H %"
if "%atrb%" neq "  " attrib "%dst%\%fld%\%file%" %atrb%
exit /b
Предварительно сделайте резервную копию и если что-то пойдет не так, постарайтесь описать подробнее соответствие кодов предприятий наименованиям файлов.
0
0 / 0 / 0
Регистрация: 21.09.2016
Сообщений: 14
27.12.2018, 16:50  [ТС] 20
Спасибо. Вроде все работает как надо.
Если я правильно понял то за кол-во знаков в названии отвечает блок: 19 строка set "var1=0000000%%~b"&set "var2=%%~c"
То есть если мне надо будет ставить не 3-7 знаков в названии файла (а другие файлы будут называться примерно так 1234567890, то есть 10 цифр, то я просто добавлю нули в set "var1=0000000000%%~b"&set "var2=%%~c".
На этом пока все.
Еще раз большое спасибо!
0
IT_Exp
Эксперт
87844 / 49110 / 22898
Регистрация: 17.06.2006
Сообщений: 92,604
27.12.2018, 16:50

Заказываю контрольные, курсовые, дипломные работы и диссертации здесь.

Создание папок по названию файлов
Есть директория с файлами. Есть ли функция позволяющая создавать папки по названию этих файлов?

Переименование файлов в папках с добавлением к именам этих файлов имён этих папок
Есть 4 папки с архивом записей с камеры видеонаблюдения с именами 13 14 15 16. В каждой папке...

Архивирование файлов из каждой папки в архивы с именами этих папок
Всем привет! Подскажите, пожалуйста, как написать bat для архивирования файлов в папках и...

Мониторинг папки на создание новых папок/файлов
Доброго времени суток! Хочу попытаться написать мониторинг для определенной папки на появление...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
20
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2021, vBulletin Solutions, Inc.