Копирование файлов и сортировка по датам в папки

@echo off&set "r=>nul reg add HKCU\Control" "Panel\International /v sShortDate /f /t REG_SZ /d "
for /f "skip=2 tokens=3" %%d in ('reg query HKCU\Control" "Panel\International /v sShortDate') do ^
if %%d neq yyyy-MM-dd %r%yyyy-MM-dd&&set p=%%d
 
set odir=F:\ARCHIV
cd/d D:\PRIVATE\M4ROOT\CLIP
for /f "tokens=1,3*" %%i in ('dir/a-d/-c/tc *.mp4^|find "p4"') do 2>nul md %odir%\%%i&>nul move/y "%%k" %odir%\%%i\
2>nul del/a/f/q *.xml&if defined p %r%%p%

chcp 1251 >nul
:: Скрипт копирования файлов рекурсивно из заданной директории в каталоги, имя которых будет = дате модификации файлов
@echo off
:: В скрипт включена поддержка файлов-папок с буквами украинского алфавита
setlocal EnableDelayedExpansion EnableExtensions
 
::Искомое расширение файлов
set Ext=*.mp4 *.wmv *.MPG *.MOV *.WMV *.AVI
 
::Откуда копировать
::set /p "x=Выберите исходную папку" < nul
::call :GetFolder From
::if not defined From exit /B
::echo : %From%
 
::Куда копировать
::set /p "x=Выберите целевую папку" < nul
::call :GetFolder To
::if not defined To exit /B
::echo : %To%
 
::Откуда копировать
set From=%CD%
::Куда копировать
set To=%CD%
 
:: Если целевой папки нет - создаем ее
if not exist "%To%" md "%To%"
 
:: Поддержка символов кодовой страницы 1251
chcp 1251>nul& set LanguageFlag=true
 
rem Сформируем специальную строку быстрого обхода нескольких расширений файлов - путь вида c:\path\*.1,c:\path\*.2, ...
call set St="!From!\%%ext: =","!From!\%%"
 
for /F "delims=" %%A in ('dir /B /S /A-D %St%') do (
  rem Восстанавливаем кодовую страницу 866, чтобы получать вывод консоли в читабельном виде.
  if defined LanguageFlag (chcp 866>nul& Set LanguageFlag=)
  rem Индикация текущей копируемой папки
  if "!curFolder!" neq "%%~dpA" (echo Читаю %%~dpA& set curFolder=%%~dpA)
  rem Получаем конечный путь с датой текущего файла (выделяю с формата дата-время только дату)
  for /F %%D in ("%%~tA") do (
  rem echo %%D
    for /f "tokens=1-7 delims=/-:., " %%a in ("%%~tA") do (
      rem echo %%c%%b%%a_%%d%%e
      set ToReal=%%c.%%b
    )
  )
  rem Обход ошибки в имени файла, если в настройках стандарта системы установлен формат даты через знаки /
  set ToReal=%To%\!ToReal:/=.!
  rem Создаем конечную папку, если ее нет
  if not exist "!ToReal!" md "!ToReal!"
  rem Проверяем не занят ли полный путь. Если занят, получаем свободное имя с добавкой цифры в скобках +1
  call :GetEmptyNameMod "!ToReal!" "%%A" NewName
  rem Копируем файл
  if not errorlevel 1 copy /Y "%%A" "!ToReal!\!NewName!" >nul
)
chcp 866 >nul
:: Ожидаем действия пользователя
pause
:: Выход из пакетного файла
goto :eof
 
:GetEmptyNameMod %1-Folder %2-FullFileName %3-Var.Return %4-Optional.System.Num
:: Рекурсивная функция для получения сбободного имени файла по заданной директории
:: Модификация: если файл совпадает по содержимому с одним из одноименных файлов,
:: новый индекс не выдается (предотвращение дубликатов).
if "%~4"=="" (
    Set "NewFileName=%~nx2"
  ) else (
    Set "NewFileName=%~n2(%~4)%~x2"
)
if exist "%~1\%NewFileName%" (
    FC /B "%~1\%NewFileName%" "%~2" >nul && (
      Set "%~3=%NewFileName%"
      Exit /B 1
    ) || (
      Set Num=%~4
      Set /A Num+=1
      Call :GetEmptyNameMod "%~1" "%~2" "%~3" "!Num!"
    )
  ) else (
    Set "%~3=%NewFileName%"
    Exit /B 0
)
Exit /B 0
 
:GetFolder %1-var.Where.Save.FolderName
chcp 1251 >nul
for /f "usebackq delims=" %%i in (
    `@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
    1^|more`
) do set %~1=%%i
chcp 866 >nul
Exit /B

@echo off
setlocal enabledelayedexpansion
pushd "D:\PRIVATE\M4ROOT\CLIP"
del *.xml /f /q
for /f "tokens=1,2,3* delims= " %%a in ('dir /a-d/tc *.exe') do (
    if not %%a==Том (
        if not %%a==Серийный (
            if not %%a==Содержимое (
                if not %%b==файлов (
                    if not %%b==папок (
                        set "file=%%d"
                        set "date_modify=%%a"
                        for /f "tokens=1-3 delims=." %%a in ("!date_modify!") do (
                            if not exist F:\ARHIV\%%c-%%b-%%a (
                                mkdir F:\ARHIV\%%c-%%b-%%a
                                move "!file!" "F:\ARHIV\%%c-%%b-%%a"
                            ) else (
                                move "!file!" "F:\ARHIV\%%c-%%b-%%a"
                            )
                        )
                    )
                )
            )
        )
    )
)
pause

@echo off
setlocal enabledelayedexpansion
pushd "D:\PRIVATE\M4ROOT\CLIP"
del *.xml /f /q
for /f "tokens=1,2,3* delims= " %%a in ('dir /a-d/tc *.mp4') do (
    if not %%a==Том (
        if not %%a==Серийный (
            if not %%a==Содержимое (
                if not %%b==файлов (
                    if not %%b==папок (
                        set "file=%%d"
                        set "date_modify=%%a"
                        for /f "tokens=1-3 delims=." %%a in ("!date_modify!") do (
                            if not exist F:\ARHIV\%%c-%%b-%%a (
                                mkdir F:\ARHIV\%%c-%%b-%%a
                                move "!file!" "F:\ARHIV\%%c-%%b-%%a"
                            ) else (
                                move "!file!" "F:\ARHIV\%%c-%%b-%%a"
                            )
                        )
                    )
                )
            )
        )
    )
)
pause

for /F "tokens=1-4 delims=. " %%i in ('date /t') do (
set Day=%%i
set Month=%%j
set Year=%%k
)
 
for /F "tokens=1-4 delims=: " %%i in ('time /t') do (
set Hour=%%i
set Minute=%%j
set Second=%%k
)
 
 
md \ARCHIV\%Year%-%Month%-%Day%

dir /a-d/tc D:\PRIVATE\M4ROOT\CLIP\*.mp4