1 / 1 / 0
Регистрация: 05.07.2021
Сообщений: 8
|
|
|
1
|
Простой будильник на компьютер CMD/BAT
05.07.2021, 14:59. Показов 2435. Ответов 1
Простой будильник из bat-ника
Описание
● В момент запуске просит ввод целочисленного значения от 0 до 9, это будет триггер часа в котором сработает будильник согласуя с системным временем. На ввод дается 7 секунд, после чего устанавливает дефолтное значение на "7" то есть 7:00am.
● При срабатывании будильника проверяется интернет соединениями доменов радиостанций в этом примере их тут 2
● Если интернет отсутствует или соединение не устанавливается, запускает ряд альтернативных сигналов протяжением в 1 минуту - при желании можно установить свое звуковое сопровождение или запуск какого либо компонента или приложения.
● Если интернет соединение доступно, запускается одна из двух в данном случае интернет радиостанций через javascript, интервал звучания по умолчанию в параметре WScript.Sleep (10000000); в секундах.
| Windows Batch file | 1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
| @set @echo=0 /*
@echo off
::------------alarm choice--------------
choice /n /C 1234567890 /t 7 /d 7 /m "what hour to set alarm -"
set hour=%errorlevel%&cls
::------------start alarm trigger--------------
:alarm
title alarm 0%hour%:00, current time %time:~0,5%
time/t | find /I "0%hour%:00">Nul && goto :buzz || ping localhost /n 2 >nul
goto :alarm
::-------------alarm change---------------
:buzz
ping ic6.101.ru /n 1 >nul
set n=%errorlevel%
ping ep128.hostingradio.ru /n 1 >nul
set n=%n%%errorlevel%
if %n%==11 goto :buzzOffline
goto :buzzOnline
::-------------offline alarm----------------
:buzzOffline
:: --two methods--
::powershell -windowstyle hidden foreach($i in 1..4){[System.Console]::Beep(4000,100)}
set os=:%os:~0,2%&<Nul set /p str=""&pathping -p 100 -q 1 localhost>Nul&if %os% neq ::: (goto buzzOffline)else set os=Windows_NT
goto :alarm
::-------------online alarm: run WSH script from current bat---------------
:buzzOnline
cscript //nologo //e:javascript "%~f0"
goto :alarm
::-------------WSH script---------------
*/
var Network = WScript.CreateObject("Wmplayer.OCX");
Network.settings.volume = 0;
if(Math.random()>=0.5)
{Network.Url = "http://ic6.101.ru:8000/stream/air/aac/64/99";}
else
{Network.Url = "http://ep128.hostingradio.ru:8030/ep128"}
Network.controls.play();
WScript.Sleep (6000);
while (Network.settings.volume <= 15)
{Network.settings.volume++;WScript.Sleep (500);}
WScript.Sleep (10000000); |
|
1
|
(
