Выполнить LOGOFF для всех пользователей, кроме себя

@echo off
 
Setlocal EnableDelayedExpansion
SetLocal EnableExtensions
 
chcp 866>nul
set user= & set ID= & set status= 
set admin=username
set pass=password
set sysID=65536
set mt=%time%
set dt=30
 
for /f "tokens=1-2 delims=:" %%a in ("%mt: =0%") do set /a "t=(1%%a-100)*60+(1%%b-100)+(dt %% 1440)", "t+=(t>>31) & 1440", "hh=(t/60 %% 24)+100", "mm=(t %% 60)+100"
set offtime=%hh:~-2%:%mm:~-2%
set t=%offtime::=.%
 
for /f "skip=3 tokens=1-4" %%a in ('query session')  do (
call :FindToken %%c
if /i Errorlevel 1 (
 
      set user=%%b
      set ID=%%c
      set status=%%d
      
    ) else (
    
      set user=%%a
      set ID=%%b
      set status=%%c)
    
  if "!user!" neq "" (
  if "!ID!" lss "!sysID!" (     
  if "!status!" neq "Активно" (
  if "!user!" neq "!admin!" (
  
  echo !user! !ID! >> C:\Windows\Scripts\ulogoff-!t!
  set user= & set ID= & set status= 
  
  ))))
  
)
 
 if exist C:\Windows\Scripts\ulogoff-%t% (
 schtasks /create /ru "domain\%admin%" /rp %pass% /sc once /tn "ulogoff-%t%" /tr "C:\Windows\scripts\logoff.bat %t%" /st "%offtime%" /rl highest >> C:\Windows\Logs\userlogoff.log
 )
 
exit /b
 
:FindToken
echo %~1 | >nul 2>&1 findstr /r [^0-9] && exit /b 1
exit /b 0

@echo off
Setlocal EnableDelayedExpansion
chcp 866>nul
 
set name=ulogoff-%~1
 
if exist C:\Windows\Scripts\%name% (
for /f "tokens=1,2" %%a in (c:\windows\scripts\%name%)  do (
set user=%%a
set ID=%%b
 
for /f "skip=1 tokens=1-4" %%a in ('query session %user%')  do (
 
call :FindToken %%c
if /i Errorlevel 1 (
      set status=%%d
    ) else (
      set status=%%c)
 
  if "!ID!" neq "" (      
  if "!status!" neq "Активно" (
  logoff !ID!
  echo !date! !time! user=!user! ID=!ID! status=non-active was log off >> C:\Windows\Logs\userlogoff.log
  set user= & set ID= & set status= 
  ))
))
 
del C:\Windows\Scripts\%name%
schtasks /delete /tn "%name%" /f
)
 
exit /b
 
:FindToken
echo %~1 | >nul 2>&1 findstr /r [^0-9] && exit /b 1
exit /b 0

for /f "skip=1 tokens=1,2,3" %%a in ('query user') DO if "%%a" neq ">administrator" logoff %%c

for /f "skip=1 tokens=1-3 delims=> " %%a in ('query user') do if /i "%%a" neq "%Username%" echo logoff %%c

for /f "skip=1 tokens=1-3" %%a in ('query user') do if /i "%%a" neq ">%Username%" echo logoff %%b

for /f "skip=1 tokens=1-3 delims=> " %%a in ('query user') do if /i "%%a" neq "%Username%" echo logoff %%b