Скопировать определенную строчку из одного файла и вставить в определенную строчку другого файла

@leha_lev · Регистрация: 25.06.2013

Author24 — интернет-сервис помощи студентам

как можно скопировать первые несколько символов (букв) из определенной строки (например 5-ой) modems.txt, далее найти в parametr.txt слово "volume=", удалить все что находится после слова "volume=" на этой строке, и вставить (после слова "volume=") слово найденное в modems.txt.

Dragokas · 27.06.2013, 17:07

Не проверял.

Bash

@echo off
SetLocal EnableExtension EnableDelayedExpansion
 
::из файла
set src=modems.txt
::из определенной строки
set nLine=5
::первые несколько символов
set nChars=4
 
::куда
set dest=parametr.txt
::удалить все что находится после слова
set word=volume=
 
2>nul del "%dest%_"
 
::Получаем текст со строки с № nLine
For /f "delims=] tokens=1*" %%a in (
  'find /v /n "" ^< "%src%" ^| findstr /BC:"[%nLine%]"'
) do set str=%%b
 
::Урезаем до первых nChars символов
set str=!str:~0,%nChars%!
 
::Считаем общее кол-во строк в dest
for /f %%a in ('find /v /c "" ^<"%dest%"') do set Count=%%a
 
::Определяем номер строки с искомой фразой
For /f "delims=[] tokens=1" %%a in (
  'find /i /n "%word%" ^< "%dest%"'
) do set nWLine=%%a
 
set /A nLineFirstTo=nWLine - 1
 
::Создание маски Findstr для отсекания первых N строк (N = nWLine - 1)
For /L %%C in (1, 1, %nLineFirstTo%) do (
  set "txtmask=!txtmask!\[%%C\] "
)
 
::Отсекаем первые N строк и записываем в промежуточный файл
::Нумеруем строки, применяем маску фильтрации, отрабрасываем нумерацию циклом
for /f "delims=] tokens=1*" %%a in ('find /v /n "" ^<"%dest%" ^| findstr /B "%txtmask%" 2^>nul') do (
  Echo.%%b>>"%dest%_"
)
 
::Модифицируем найденную строку
echo %word%%str%>>"%dest%_"
 
::Дописываем последние строки. More ведет отсчет от нуля.
more +%nWLine% < "%dest%" > "%dest%_"
 
::Перемещаем сформированный файл на текущий
for %%a in ("%dest%") do move /y "%dest%_" "%%~nxa"

@leha_lev · 27.06.2013, 17:31 **[ТС]**

Что то тут не работает. Может так получится:
скопировать первое слово (например COM71) из определенной строки (например 5-ой) modems.txt, далее в parametr.txt на 5-ой (например) строке удалить все и вставить "volume=COM71".

Dragokas · 27.06.2013, 19:11

Я точно так и делаю (должно быть ясно из комментариев).

Выложите демо-файлы для тестирования.

@leha_lev · 27.06.2013, 19:31 **[ТС]**

например нужно из 3-ой строчки modems.txt взять первое слово и вставить его с добавлением к "volume=" в 5-ую строчку parametr.txt вместо "volume=COM25", чтобы поучилось "volume=COM71"

Dragokas · 27.06.2013, 19:44

Да, 2 опечатки допустил (строка 2 и строка 51).
Вот исправленный код:

Bash

::@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
::из файла
set src=modems.txt
::из определенной строки
set nLine=3
::первые несколько символов
set nChars=5
 
::куда
set dest=parametr.txt
::удалить все что находится после слова
set word=volume=
 
2>nul del "%dest%_"
 
::Получаем текст со строки с № nLine
For /f "delims=] tokens=1*" %%a in (
  'find /v /n "" ^< "%src%" ^| findstr /BC:"[%nLine%]"'
) do set str=%%b
 
::Урезаем до первых nChars символов
set str=!str:~0,%nChars%!
 
::Считаем общее кол-во строк в dest
for /f %%a in ('find /v /c "" ^<"%dest%"') do set Count=%%a
 
::Определяем номер строки с искомой фразой
For /f "delims=[] tokens=1" %%a in (
  'find /i /n "%word%" ^< "%dest%"'
) do set nWLine=%%a
 
set /A nLineFirstTo=nWLine - 1
 
::Создание маски Findstr для отсекания первых N строк (N = nWLine - 1)
For /L %%C in (1, 1, %nLineFirstTo%) do (
  set "txtmask=!txtmask!\[%%C\] "
)
 
::Отсекаем первые N строк и записываем в промежуточный файл
::Нумеруем строки, применяем маску фильтрации, отрабрасываем нумерацию циклом
for /f "delims=] tokens=1*" %%a in ('find /v /n "" ^<"%dest%" ^| findstr /B "%txtmask%" 2^>nul') do (
  Echo.%%b>>"%dest%_"
)
 
::Модифицируем найденную строку
echo %word%%str%>>"%dest%_"
 
::Дописываем последние строки. More ведет отсчет от нуля.
more +%nWLine% < "%dest%" >> "%dest%_"
 
::Перемещаем сформированный файл на текущий
for %%a in ("%dest%") do move /y "%dest%_" "%%~nxa"

@leha_lev · 27.06.2013, 20:15 **[ТС]**

Там есть еще строка "AudioComport=", так этот код перезаписывает не "Comport=", а в место "AudioComport="

Dragokas · 27.06.2013, 20:49

Да, оно сравнивает полностью во всей строке.
Это будет чуть по-сложнее.
Пробуйте:

Bash

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
::из файла
set src=modems.txt
::из определенной строки
set nLine=3
::первые несколько символов
set nChars=5
 
::куда
set dest=parametr.txt
::удалить все что находится после слова
set word=volume=
 
2>nul del "%dest%_"
 
::Получаем текст со строки с № nLine
For /f "delims=] tokens=1*" %%a in (
  'find /v /n "" ^< "%src%" ^| findstr /BC:"[%nLine%]"'
) do set str=%%b
 
::Урезаем до первых nChars символов
set str=!str:~0,%nChars%!
 
::Определяем номер строки с искомой фразой
::Определяем длину искомого текста
call :var_count "%word%" WordLen
::Сравниваем только ту часть первых символов, которая соответствует длине искомого слова
set Count=0
For /f "UseBackQ delims=" %%a in ("%dest%") do (
  set /A Count+=1
  set tLine=%%a
  if /i "!tLine:~0,%WordLen%!"=="%word%" set nWLine=!Count!
)
 
set /A nLineFirstTo=nWLine - 1
 
::Создание маски Findstr для отсекания первых N строк (N = nWLine - 1)
For /L %%C in (1, 1, %nLineFirstTo%) do (
  set "txtmask=!txtmask!\[%%C\] "
)
 
::Отсекаем первые N строк и записываем в промежуточный файл
::Нумеруем строки, применяем маску фильтрации, отрабрасываем нумерацию циклом
for /f "delims=] tokens=1*" %%a in ('find /v /n "" ^<"%dest%" ^| findstr /B "%txtmask%" 2^>nul') do (
  Echo.%%b>>"%dest%_"
)
 
::Модифицируем найденную строку
echo %word%%str%>>"%dest%_"
 
::Дописываем последние строки. More ведет отсчет от нуля.
more +%nWLine% < "%dest%" >> "%dest%_"
 
::Перемещаем сформированный файл на текущий
for %%a in ("%dest%") do move /y "%dest%_" "%%~nxa"
 
goto :eof
 
:var_count %1-in.Text %2.out.Len.of.Text
  set _var=%~1& set _count=0
  :count--
  set _var=%_var:~1%
  set /a _count+=1
  if not defined _var (set %~2=%_count%& exit /b) else (goto :count--)
Exit /B

Добавлено через 2 минуты
Кстати, это может означать, что Вы задаете неверную фразу:
а именно:
set word=Comport
вместо
set word=Comport=

@leha_lev · 27.06.2013, 21:06 **[ТС]**

нет, я задаю set word=Comport=, в прочем я пробовал так итак

Dragokas · 27.06.2013, 21:11

Не могёт такого быть.
Ему дали четкую команду - искать в файле конкретное слово или вхождение:

Bash

1	find /i /n "%word%" < "%dest%"

Если что скидывайте текстовики.
Ну а с последним кодом что? - Работает?

@leha_lev · 27.06.2013, 21:17 **[ТС]**

modems.txt тот же

@leha_lev · 27.06.2013, 21:45 **[ТС]**

Простите Стас, это я запарился!!!

Вам ОГРОМНОЕ человеческое СПАСИБО, всех благ Вам!!!!

Dragokas · 27.06.2013, 21:55

Не по теме:

Спасибо. Да я тоже запарился. У нас в Днепре до сих пор 31 держится.

@Eva Rosalene · 27.06.2013, 22:06

Не по теме:

А ты что, не Алекс? О_о
P.S. А у нас +36°

@leha_lev · 27.06.2013, 22:17 **[ТС]**

Стас, подскажите пожалуйста последний момент. У меня несколько файлов parametr.txt, как перестроить Ваш код, так чтоб из modems.txt брались разные строчки для разных parametr.txt которые находятся в разных директориях?

Dragokas · 27.06.2013, 23:41

Не по теме:

@FraidZZ, и Алекс тоже -). Лучше: Алекс. ;)

Разные * разные * разные =)))

Сейчас попробую переварить в алгоритм.

На ум приходит только создать еще один бат-файл, например Range.cmd.
А вот этот главный пусть называется main.cmd

В main.cmd подставляете там, где Вам нужно будет менять значение номер параметра извне:
например:

set nLine=%~1
set word=%~2
set dest=%~3

А в другом Range.cmd будете вызывать главный бат. Код будет, например, таков:

Bash

1 2	main 3 "volume=" "c:\temp\parametr.txt" main 3 "volume=" "c:\temp2\parametr.txt"

@leha_lev · 28.06.2013, 00:41 **[ТС]**

вносит правильные изменения в parametr.txt, но сохраняет parametr.txt в директорию от куда запускался Range.cmd.
в Range.cmd такой же код:

Bash

1 2	main 3 "volume=" "c:\temp\parametr.txt" main 4 "volume=" "c:\temp2\parametr.txt"

Dragokas · 28.06.2013, 01:13

Упс, перепутал синтаксис move с ren. Вот уж точно - жара.
Эта страшная конструкция в строке 57 не нужна. Вместо нее просто:

Bash

1	move /y "%dest%_" "%dest%"

@leha_lev · 28.06.2013, 08:44 **[ТС]**

Почему то выполняется только первая строчка в Range.cmd, т.е.
main 3 "volume=" "c:\temp\parametr.txt" а main 4 "volume=" "c:\temp2\parametr.txt" не выполняется.
В чем может быть проблема?

Dragokas · 28.06.2013, 18:21

Странно.
Попробуйте заменить строку 59 (goto :eof)
на:

Bash

Exit /B

И напишите о результатах.

@leha_lev 0 / 0 / 0 Регистрация: 25.06.2013 Сообщений: 56
	27.06.2013, 21:45 [ТС]	12
	Простите Стас, это я запарился!!! Вам ОГРОМНОЕ человеческое СПАСИБО, всех благ Вам!!!! 0

@leha_lev 0 / 0 / 0 Регистрация: 25.06.2013 Сообщений: 56
	27.06.2013, 17:31 [ТС]	3
	Что то тут не работает. Может так получится: скопировать первое слово (например COM71) из определенной строки (например 5-ой) modems.txt, далее в parametr.txt на 5-ой (например) строке удалить все и вставить "volume=COM71". 0

Dragokas 17996 / 7697 / 892 Регистрация: 25.12.2011 Сообщений: 11,470 Записей в блоге: 16
	27.06.2013, 19:11	4
	Я точно так и делаю (должно быть ясно из комментариев). Выложите демо-файлы для тестирования. 0

@leha_lev 0 / 0 / 0 Регистрация: 25.06.2013 Сообщений: 56
	27.06.2013, 20:15 [ТС]	7
	Там есть еще строка "AudioComport=", так этот код перезаписывает не "Comport=", а в место "AudioComport=" 0

@leha_lev 0 / 0 / 0 Регистрация: 25.06.2013 Сообщений: 56
	27.06.2013, 21:06 [ТС]	9
	нет, я задаю set word=Comport=, в прочем я пробовал так итак 0

Dragokas
	27.06.2013, 21:55 #13
	Не по теме: Спасибо. Да я тоже запарился. У нас в Днепре до сих пор 31 держится. 1

@Eva Rosalene
	27.06.2013, 22:06 #14
	Не по теме: А ты что, не Алекс? О_о P.S. А у нас +36° 0

@leha_lev 0 / 0 / 0 Регистрация: 25.06.2013 Сообщений: 56
	27.06.2013, 22:17 [ТС]	15
	Стас, подскажите пожалуйста последний момент. У меня несколько файлов parametr.txt, как перестроить Ваш код, так чтоб из modems.txt брались разные строчки для разных parametr.txt которые находятся в разных директориях? 0

@leha_lev 0 / 0 / 0 Регистрация: 25.06.2013 Сообщений: 56
	28.06.2013, 08:44 [ТС]	19
	Почему то выполняется только первая строчка в Range.cmd, т.е. main 3 "volume=" "c:\temp\parametr.txt" а main 4 "volume=" "c:\temp2\parametr.txt" не выполняется. В чем может быть проблема? 0