Получить в файле ж все компоненты файла ф

//Определяет, составляют ли цифры целого числа арифметическую прогрессию.
//TRUE - да, FALSE - нет.
//Если число состоит менее, чем из 3 цифр - вернёт TRUE.
function IsArPr(const aNum : Integer) : Boolean;
var
  //Номер разряда, исходное число, переменная для промежуточных вычислений.
  i, Num, NumTmp : Longword;
  //Старший и следующий младший разряды.
  D1, D2 : Integer;
  //Коэффициенты арифм. прогрессии в смежных итерациях цикла.
  A1, A2 : Integer;
begin
  //Исходное число без знака.
  Num := Abs(aNum);
 
  Result := True;
  NumTmp := Num;
  i := 1;
  D1 := 0;
  A1 := 0;
  //Движемся по разрядам числа справа - налево (от младших - к старшим).
  repeat
    //Цифра в младшем разряде.
    D2 := D1;
    //Цифра в очередном разряде (старшем).
    D1 := NumTmp mod 10;
    //Коэффициент на предыдущем шаге.
    A2 := A1;
    //Коэффициент на текущем шаге.
    A1 := D2 - D1;
 
    if ( i > 2 ) and ( A1 <> A2 ) then begin
      Result := False;
      Break;
    end;
 
    NumTmp := NumTmp div 10;
    //Номер следующего разряда.
    Inc(i);
  until NumTmp = 0;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  FileName1 = 'data.txt';
  FileName2 = 'res.txt';
var
  F1, F2 : TextFile;
  Num : Integer;
begin
  AssignFile(F1, FileName1);
  Reset(F1);
  AssignFile(F2, FileName2);
  Rewrite(F2);
 
  while not Eof(F1) do begin
    Readln(F1, Num);
    if IsArPr(Num) then begin
      Write(F2, Num);
      if not Eof(F1) then Writeln(F2);
    end;
  end;
 
  CloseFile(F1);
  CloseFile(F2);
end;