Как создать список файлов exe по определенному пути

@Ralik · Регистрация: 13.08.2010

Author24 — интернет-сервис помощи студентам

Помогите создать список файлов exe по определенному пути. То есть ищу функцию, чтобы

Delphi

1	GetFileList('D:\Downloads\', Memo1.Lines);

и в поле мемо создался список exe файлов?

@Mawrat · 09.12.2013, 01:17

Если надо искать только в заданной папке:

Delphi

uses
  FileCtrl;
 
//Поиск файлов по заданной маске в папке aPath.
//Если маска не задана, то будет использована маска = '*'.
procedure SearchFiles(const aPath, aMask : string; aSl : TStrings);
var
  Path, Mask : String;
  Sr : TSearchRec;
  Attr : Integer;
begin
  //Добавление в конец строки слеша, если его нет.
  Path := IncludeTrailingPathDelimiter(aPath);
  //Маска.
  if aMask <> '' then
    Mask := aMask
  else
    Mask := '*';
 
  //В текущей папке ищем файлы по заданной маске.
  Attr := faAnyFile - faVolumeID - faDirectory;
  try
    if FindFirst(Path + Mask, Attr, Sr) = 0 then
    repeat
      aSl.Add(Path + Sr.Name);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
end;
 
//Диалог поиска файлов.
procedure TForm1.Button1Click(Sender: TObject);
var
  Path : String;
begin
  Path := ExtractFilePath(ParamStr(0));
  //if not SelectDirectory('Выбор папки', '', Path) then
  //  Exit;
  if not SelectDirectory(Path, [sdAllowCreate, sdPerformCreate, sdPrompt], 0) then
    Exit;
  if not DirectoryExists(Path) then begin
    MessageBox(Handle, 'Заданная папка не найдена. Действие отменено.', 'Отмена!',
      MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
 
  //Поиск файлов по заданной маске в указанной папке.
  //Если маска не задана, то в процедуре SearchFiles() будет использована маска = '*'.
  //Маска читается из Edit1.Text.
  Memo1.Clear;
  SearchFiles(Path, Edit1.Text, Memo1.Lines);
end;

2. Если надо искать, начиная с заданной папки (в заданной папке и во всех вложенных папках).

Delphi

uses
  FileCtrl;
 
//Поиск файлов по заданной маске, начиная с папки aPath.
//Если маска не задана, то будет использована маска = '*'.
procedure SearchFiles(const aPath, aMask : string; aSl : TStrings);
var
  Path, Mask : String;
  Sr : TSearchRec;
  Attr : Integer;
begin
  //Добавление в конец строки слеша, если его нет.
  Path := IncludeTrailingPathDelimiter(aPath);
  //Маска.
  if aMask <> '' then
    Mask := aMask
  else
    Mask := '*';
 
  //В текущей папке ищем файлы по заданной маске.
  Attr := faAnyFile - faVolumeID - faDirectory;
  try
    if FindFirst(Path + Mask, Attr, Sr) = 0 then
    repeat
      aSl.Add(Path + Sr.Name);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
 
  //В текущей папке ищем все папки и для каждой из них выполняем рекурсивный вызов.
  Attr := faDirectory;
  try
    if FindFirst(Path + '*', Attr, Sr) = 0 then
    repeat
      if (Sr.Name <> '.') and (Sr.Name <> '..') then
        SearchFiles(Path + Sr.Name, Mask, aSl);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
end;
 
//Диалог поиска файлов.
procedure TForm1.Button1Click(Sender: TObject);
var
  Path : String;
begin
  Path := ExtractFilePath(ParamStr(0));
  //if not SelectDirectory('Выбор папки', '', Path) then
  //  Exit;
  if not SelectDirectory(Path, [sdAllowCreate, sdPerformCreate, sdPrompt], 0) then
    Exit;
  if not DirectoryExists(Path) then begin
    MessageBox(Handle, 'Заданная папка не найдена. Действие отменено.', 'Отмена!',
      MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
 
  //Поиск файлов по заданной маске, начиная с указанной папки.
  //Если маска не задана, то в процедуре SearchFiles() будет использована маска = '*'.
  //Маска читается из Edit1.Text.
  Memo1.Clear;
  SearchFiles(Path, Edit1.Text, Memo1.Lines);
end;

@cotseec · 09.12.2013, 01:19

Сообщение от Ralik

То есть ищу функцию, чтобы

если версия Delphi из XE, то System.IOUtils.TDirectory.GetFiles (пример)
для всех версий, чтобы "по быстрому" через TListBox или FindFirst FindNext и FindClose
пример для TListBox

Delphi

var
  d: string;
....
  d:= 'D:\Downloads\*.exe';
  ListBox1.Perform(LB_DIR,
                DDL_READWRITE,
                Integer(D));
....

@Ralik · 09.12.2013, 02:18 **[ТС]**

Спасибо господа за отклики! Сделал так:

Delphi

procedure GetFileList(const Path: String; List: TStrings);
var
 Rec: TSearchRec;
begin
 if FindFirst(Path + '*.*', faAnyFile, Rec) = 0 then
 
 repeat
   if (Rec.Name = '.') or (Rec.Name = '..') then Continue;
   if (Rec.Attr and faDirectory) <> 0 then
   begin
 
   GetFileList(Path + Rec.Name + '\', List);
   end else
 
    if ExtractFileExt(Rec.Name)='.exe' then List.Add(Path + Rec.Name);
 until FindNext(Rec) <> 0;
 FindClose(Rec);
end;

@Mawrat · 09.12.2013, 09:01

Решение с FindFirst()/FindNext()/FindClose(), в случае, если надо искать в папке файлы с заданным расширением.
Здесь особенность в том, что не смотря на то, что расширение уже задано в маске, тем не менее, надо выполнять дополнительную проверку расширения. Это нужно делать из-за того, что функции FindFirst()/FindNext() учитывают короткие имена файлов DOS. Например, если ищем по маске '*.exe', то по ней найдутся также файлы с расширением '.executable'. Т. к., такому расширению соответствует короткая версия = '.exe'. Это касается также других расширений.

1. Если надо искать только в заданной папке.

Delphi

uses
  FileCtrl;
 
//Поиск файлов по маске '*.exe' в папке aPath.
procedure SearchFiles(const aPath : String; aSl : TStrings);
var
  Path : String;
  Sr : TSearchRec;
  Attr : Integer;
begin
  //Добавление в конец строки слеша, если его нет.
  Path := IncludeTrailingPathDelimiter(aPath);
  
  //В текущей папке ищем файлы по маске '*.exe'.
  Attr := faAnyFile - faVolumeID - faDirectory;
  try
    if FindFirst(Path + '*.exe', Attr, Sr) = 0 then
    repeat
      //Дополнительная проверка расширения.
      if AnsiUpperCase(ExtractFileExt(Sr.Name)) = '.EXE' then
        aSl.Add(Path + Sr.Name);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
end;

Здесь ещё надо заметить, что при проверке расширения, следует приводить буквы к верхнему или нижнему регистру. Потому, что регистр букв в Sr.Name может быть разным - он точно такой, какой задан в имени файла на диске.

2. Если искать надо в заданной папке и во всех вложенных папках.

Delphi

uses
  FileCtrl;
 
//Поиск файлов по маске '*.exe', начиная с папки aPath.
procedure SearchFiles(const aPath : String; aSl : TStrings);
var
  Path : String;
  Sr : TSearchRec;
  Attr : Integer;
begin
  //Добавление в конец строки слеша, если его нет.
  Path := IncludeTrailingPathDelimiter(aPath);
 
  //В текущей папке ищем файлы по маске '*.exe'.
  Attr := faAnyFile - faVolumeID - faDirectory;
  try
    if FindFirst(Path + '*.exe', Attr, Sr) = 0 then
    repeat
      //Дополнительная проверка расширения.
      if AnsiUpperCase(ExtractFileExt(Sr.Name)) = '.EXE' then
        aSl.Add(Path + Sr.Name);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
    
  //В текущей папке ищем все папки и для каждой из них выполняем рекурсивный вызов.
  Attr := faDirectory;
  try
    if FindFirst(Path + '*', Attr, Sr) = 0 then
    repeat
      if (Sr.Name <> '.') and (Sr.Name <> '..') then
        SearchFiles(Path, aSl);
    until FindNext(Sr) <> 0;
  finally
    FindClose(Sr);
  end;
end;

	09.12.2013, 09:01

Опции темы