Перевод кода с СИ на Delphi

// Приведение вещественной матрицы
// к ступенчатому виду методом Гаусса с выбором
// максимального разрешающего элемента в столбце.
// Функция возвращает ранг матрицы
function gaussMethod(
    m: integer;                // Число строк матрицы
    n: integer;                // Число столбцов матрицы
    eps: double;              // Точность вычислений
    var a: array of double   // Адрес массива элементов матрицы
) : integer;
var
    i, j, k, l: integer;
    r: double;
begin
    i := 0; j := 0;
    while (i < m) and (j < n) do begin
        // Инвариант: минор матрицы в столбцах 0..j-1
        //   уже приведен к ступенчатому виду, и строка
        //   с индексом i-1 содержит ненулевой эл-т
        //   в столбце с номером, меньшим чем j
 
        // Ищем максимальный элемент в j-м столбце,
        // начиная с i-й строки
        r := 0.0;
        for k := i to m - 1 do begin
            if (abs(a[k*n + j]) > r) then begin
                l := k;      // Запомним номер строки
                r := abs(a[k*n + j]); // и макс. эл-т
            end;
        end;
        if (r <= eps) then begin
            // Все элементы j-го столбца по абсолютной
            // величине не превосходят eps.
            // Обнулим столбец, начиная с i-й строки
            for k := i to m - 1 do begin
                a[k*n + j] := 0.0;
            end;
            inc(j);      // Увеличим индекс столбца
            continue; // Переходим к следующей итерации
        end;
 
        if l <> i then begin
            // Меняем местами i-ю и l-ю строки
            for k := j to n - 1 do begin
                r := a[i*n + k];
                a[i*n + k] := a[l*n + k];
                a[l*n + k] := (-r); // Меняем знак строки
            end;
        end;
 
        // Утверждение: abs(a[i*n + k]) > eps
 
        // Обнуляем j-й столбец, начиная со строки i+1,
        // применяя элем. преобразования второго рода
        for k := i+1 to m - 1 do begin
            r := (-a[k*n + j] / a[i*n + j]);
 
            // К k-й строке прибавляем i-ю, умноженную на r
            a[k*n + j] := 0.0;
            for l := j+1 to n-1 do begin
                a[k*n + l] := a[k*n + l] + r * a[i*n + l];
            end;
        end;
 
        inc(i); inc(j);   // Переходим к следующему минору
    end;
 
    Result := i; // Возвращаем число ненулевых строк
end;