StringGrid вывод в Word

procedure TForm11.Word1Click(Sender: TObject);
const   wdWord9TableBehavior = 1;
var
  date: String;
  wdApp, wdDoc, wdRng, wdTable : Variant;
  i, R, C : Integer;
  Sg : TStringGrid;
begin
  Sg := StringGrid1;
  date:= Label2.Caption;
  wdApp := CreateOleObject('Word.Application');
  wdApp.Visible := True;
  wdDoc := wdApp.Documents.Add;
  wdRng := wdDoc.Range;
  wdRng.Font.Name := 'Times New Roman';
  wdRng.Font.Size := 12;
 
  
  i := wdRng.End div 2;
 
  wdRng := wdDoc.Range(i, i);
 //заголовок таблицы
  wdRng.Text := 'Ведомость посещаемости' + date+#13#10;
  
  wdTable := wdDoc.Tables.Add(wdRng.Characters.Last, Sg.RowCount, Sg.ColCount, wdWord9TableBehavior);
 
 
  for R := 0 to Sg.RowCount - 1 do
    for C := 0 to Sg.ColCount - 1 do
      wdTable.Cell(R + 1, C + 1).Range.Text := Sg.Cells[C, R];
      
 
 
end;

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  //Выравнивание параграфа.
  wdAlignParagraphCenter = 1;
  wdAlignParagraphLeft = 0;
  wdAlignParagraphRight = 2;
  //Стиль линий таблицы - одиночные линии.
  wdLineStyleSingle = 1;
  //Стиль оформления таблицы.
  wdWord9TableBehavior = 1;
var
  wdApp, wdDoc, wdRng, wdTable : OleVariant;
  R, C : Integer;
  SDate: String;
  Sg : TStringGrid;
begin
  Sg := StringGrid1;
  SDate := Label2.Caption;
  wdApp := CreateOleObject('Word.Application');
  wdApp.Visible := True;
  wdDoc := wdApp.Documents.Add;
  wdRng := wdDoc.Range;
 
  //Заголовок документа.
  wdRng.Start := wdRng.End; //Определяем пустой диапазон в конце прежнего диапазона.
  wdRng.InsertAfter('Отчёт'#13#10);
  wdRng.ParagraphFormat.Alignment := wdAlignParagraphCenter; //Выравнивание параграфа по центру.
  wdRng.Font.Name := 'Times New Roman';
  wdRng.Font.Size := 14;
  wdRng.Font.Bold := True;
 
  //Заголовок таблицы.
  wdRng.Start := wdRng.End; //Определяем пустой диапазон в конце прежнего диапазона.
  wdRng.InsertAfter(#13#10#13#10'Ведомость посещаемости ' + SDate + #13#10);
  wdRng.ParagraphFormat.Reset; //Сброс параметров параграфа.
  wdRng.Font.Reset;            //Сброс параметров шрифта.
  wdRng.Font.Size := 12;
 
  //Добавляем таблицу MS Word.
  wdRng.Start := wdRng.End; //Определяем пустой диапазон в конце прежнего диапазона.
  wdTable := wdDoc.Tables.Add(wdRng, Sg.RowCount, Sg.ColCount, wdWord9TableBehavior);
  //Запись данных в таблицу MS Word.
  for R := 0 to Sg.RowCount - 1 do
    for C := 0 to Sg.ColCount - 1 do
      wdTable.Cell(R + 1, C + 1).Range.Text := Sg.Cells[C, R];
  wdRng := wdTable.Range; //Диапазон, который занимает таблица.
  wdRng.Font.Reset;
  wdRng.Font.Size := 10;
 
  //Текст под таблицей (ниже таблицы).
  wdRng := wdTable.Range;   //Диапазон, который занимает таблица.
  wdRng.Start := wdRng.End; //Определяем пустой диапазон в конце прежнего диапазона.
  wdRng.InsertAfter(#13#10#13#10'Время создания отчёта: '
    + FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', Now));
  wdRng.Font.Reset;
  wdRng.Font.Size := 8;
  wdRng.Font.Bold := True;
end;