ошибка при подсчете матриц

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids;
 
type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    Label1: TLabel;
    StringGrid2: TStringGrid;
    Label2: TLabel;
    Button1: TButton;
    Button2: TButton;
    StringGrid3: TStringGrid;
    Label3: TLabel;
    procedure Button2Click(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
i,j,f,m,n,l,x,y,q:integer;
a,b,c,d:array[1..20,1..20] of real;
 
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
begin
l:=2;
for i:=1 to n do
for j:=1 to m do
a[i,j]:=StrToFloat(StringGrid1.Cells[i-1,j-1]);
for i:=1 to n do
for j:=1 to m do
b[i,j]:=a[i,j]*l;
for i:=1 to n do
for j:=1 to m do
begin
for x:=0 to StringGrid2.RowCount-1 do
for y:=0 to StringGrid2.ColCount-1 do
begin
q:=StrToInt(StringGrid2.Cells[x,y]);
c[i,j]:=(q*i);
begin
d[i,j]:=b[i,j]+c[i,j];
StringGrid3.Cells[i-1,j-1]:=FloatToStr(d[i,j]);
end;end;end;end;
 
procedure TForm1.Button2Click(Sender: TObject);
begin
m:=3;
n:=3;
stringgrid1.RowCount:=m;
stringgrid1.ColCount:=n;
for i:=0 to 10 do begin
for j:=0 to 10 do begin
a[i+1,j+1]:= random (70)-random (70);
StringGrid1.Cells[j,i]:= FormatFloat('0',a[i+1,j+1]);
StringGrid2.Cells[j,i]:= FormatFloat('0',a[i+1,j+1]);
end;
end;
end;
 
end.

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids, Math;
 
const L = 2; //Размер матрицы - 1
 
type
  TMatrix = array[0..L, 0..L] of Integer;
  TForm1 = class(TForm)
    sg_A: TStringGrid; sg_B: TStringGrid; sg_2A: TStringGrid; sg_B2: TStringGrid; sg_C: TStringGrid;
    btn_Load: TButton; btn_Rez: TButton;
    Label1: TLabel; Label2: TLabel; Label3: TLabel; Label4: TLabel; Label5: TLabel; Label6: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure btn_RezClick(Sender: TObject);
    procedure btn_LoadClick(Sender: TObject);
  private { Private declarations }
    A, B, C : TMatrix;
  public { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
 Randomize;
end;
 
procedure TForm1.btn_LoadClick(Sender: TObject);
var i, j : integer;
begin
//Заполняем исходные массивы А и В и выводим на экран
 for i := 0 to L do
  for j := 0 to L do
   begin
    A[i, j] := RandomRange(-99, 100);
    B[i, j] := RandomRange(-99, 100);
    sg_A.Cells[j, i] := IntToStr(A[i, j]);
    sg_B.Cells[j, i] := IntToStr(B[i, j]);
   end;
 btn_Rez.Enabled := true;
end;
 
procedure TForm1.btn_RezClick(Sender: TObject);
var
 i, j, k : integer;
 A1, B1  : TMatrix;
begin
//Обнуляем временные и результирующий массивы
 FillChar(A1, SizeOf(A1), 0);
 FillChar(B1, SizeOf(B1), 0);
 FillChar(C, SizeOf(C), 0);
//Считаем и выводим А1 = А * 2
 for i := 0 to L do
  for j := 0 to L do
   begin
    A1[i, j] := 2 * A[i, j];
    sg_2A.Cells[j, i] := IntToStr(A1[i, j]);
   end;
//Считаем и выводим B1 = B^2
 for i := 0 to L do
  for j := 0 to L do
   for k := 0 to L do
    begin
     B1[i, j] := B1[i, j] + B[i, k] * B[k, j];
     sg_B2.Cells[j, i] := IntToStr(B1[i, j]);
    end;
//Считаем и выводим результирующую матрицу С
 for i := 0 to L do
  for j := 0 to L do
   begin
    C[i, j] := A1[i, j] + B1[i, j];
    sg_C.Cells[j, i] := IntToStr(C[i, j]);
   end;
end;
 
end.