Составить программу, которая содержит текущую информацию о автошколах города

unit Unit1;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;
 
type
  TForm1 = class(TForm)
    edtName: TLabeledEdit;
    edtAdress: TLabeledEdit;
    edtContact: TLabeledEdit;
    edtURL: TLabeledEdit;
    edtPrice: TLabeledEdit;
    Label1: TLabel;
    ListBox1: TListBox;
    Button1: TButton;
    Button2: TButton;
    Label2: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure ListBox1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure edtPriceKeyPress(Sender: TObject; var Key: Char);
  private
    procedure ReadAllRecords;
    procedure ClearFields;
  end;
 
  TAvtoSchool = packed record
    Name: string[50];
    Adress: string[100];
    Contact: string[20];
    URL: string[255];
    Price: Currency;
  end;
 
const
  fName = 'data.rec';
var
  Form1: TForm1;
  DataBase: file of TAvtoSchool;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
var
  temp: TAvtoSchool;
  P: Currency;
begin
  // добавить новую запись
  if edtName.Text <> '' then
  // по крайней мере имя не должно быть пустым
  begin
    temp.Name:= edtName.Text;
    temp.Adress:= edtAdress.Text;
    temp.Contact:= edtContact.Text;
    temp.URL:= edtURL.Text;
    try
      P:= StrToFloat(edtPrice.Text);
    except
      P:= 0.0;
    end;
    temp.Price:= P;
    Reset(DataBase);
    Seek(DataBase,FileSize(DataBase));
    Write(DataBase,temp);
    CloseFile(DataBase);
    ReadAllRecords;
    ClearFields;
  end else ShowMessage('Название не может быть пустым!');
end;
 
procedure TForm1.Button2Click(Sender: TObject);
begin
  ClearFields;
end;
 
procedure TForm1.ClearFields;
begin
  edtName.Clear;
  edtAdress.Clear;
  edtContact.Clear;
  edtURL.Clear;
  edtPrice.Clear;
end;
 
procedure TForm1.edtPriceKeyPress(Sender: TObject; var Key: Char);
begin
  if Key in [',','.'] then Key:= DecimalSeparator;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  AssignFile(DataBase,fName);
  if not FileExists(fName) then
  // создаем пустой файл, если файла нет
  begin
    Rewrite(DataBase);
    CloseFile(DataBase);
  end
  else ReadAllRecords;
end;
 
procedure TForm1.ListBox1Click(Sender: TObject);
var
  temp: TAvtoSchool;
begin
  // щелчок по списку - вывод информации о выбранной школе
  if ListBox1.ItemIndex = -1 then Exit;
  Reset(DataBase);
  Seek(DataBase,ListBox1.ItemIndex);
  Read(DataBase,temp);
  CloseFile(DataBase);
  ClearFields;
  edtName.Text:= temp.Name;
  edtAdress.Text:= temp.Adress;
  edtContact.Text:= temp.Contact;
  edtURL.Text:= temp.URL;
  Label2.Caption:= FloatToStrF(temp.Price,ffCurrency,MAXBYTE,2);
end;
 
procedure TForm1.ReadAllRecords;
var
  temp: TAvtoSchool;
begin
  ListBox1.Clear;
  Reset(DataBase);
  while not Eof(DataBase) do
  begin
    Read(DataBase,temp);
    ListBox1.Items.Add(temp.Name);
  end;
  CloseFile(DataBase);
end;
 
end.