Как отследить открытие папки

// main form unit - Button1 starts the thread and button2 stops it:
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.DFM}
 
uses unit2;
 
var
  SpyThread: TSpyThread;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  SpyThread := TSpyThread.Create(true);
  SpyThread.FreeOnTerminate := true;
  SpyThread.Resume;
end;
 
procedure TForm1.Button2Click(Sender: TObject);
begin
  SpyThread.Terminate;
end;
 
end.
 
// the thread unit
unit Unit2;
 
interface
 
uses windows, classes, sysutils;
 
type
 
  TSpyThread = class(TThread)
    procedure Execute; override;
    procedure Oops;
  private
    c: integer;
  end;
 
implementation
 
uses unit1;
 
procedure TSpyThread.Oops;
begin
  Form1.Label1.Caption := 'Change occured '+IntToStr(c);
end;
 
procedure TSpyThread.Execute;
var
  h: THandle;
  dwWaitStatus: DWORD;
begin
  c := 0;
  // set a notification
  h := FindFirstChangeNotification('c:\test', // directory to watch
     false,                                 // do not watch the subtree
     FILE_NOTIFY_CHANGE_FILE_NAME);         // watch file name changes including new and deleted files
 
  if h = INVALID_HANDLE_VALUE then exit;      // exit if the returned handle is invalid
 
  try
    while (not terminated) do begin
      dwWaitStatus := WaitForSingleObject(h, 1000);
 
      if dwWaitStatus = WAIT_OBJECT_0 then begin // the object is signaled
        // do something here
        inc(c);
        Synchronize(Oops);
 
        // restart waiting
        if FindNextChangeNotification(h) = false then break; // exit loop on error
      end;
    end;
  finally
    FindCloseChangeNotification(h); // close the handle
  end;
end;
 
end.